Display and for loop

Programming Questions

sillyfrog

in Programming Questions • 2 years ago

I have made a pentagon. When I draw it on its own, I can see it. When I put it inside a for loop it disappears. Anything I have not understood ? I have tried to translate the sketch in different ways, and still nothing shows.

Can anyone help ?

Here is the code :

float cos18 = cos(radians(18));

float cos36 = cos(radians(36));

float cos54 = cos(radians(54));

float cos72 = cos(radians(72));

void setup()

{

size(800,600);

smooth();

noLoop();

background(255);

translate(width/2, height/2);

}

void draw() {

translate(300,200);

for (int i = 0; i > 6; i = i + 1)

{

fill(255,0,0);

pentagone(80);

rotate(radians(72));

}

void pentagone(int longueur)

{

beginShape();

rotate(radians(180));

vertex(0,0);

vertex(longueur * cos36, longueur * cos54);

vertex((longueur * cos36) - (longueur * cos72), (longueur * cos54) + (longueur * cos18));

vertex((longueur * cos36) - (longueur * cos72) - longueur, (longueur * cos54) + (longueur * cos18));

vertex(-longueur * cos36, longueur * cos54);

endShape(CLOSE);

}

BTW no final answer to my other problem after I posted the code as you suggested:

https://forum.processing.org/topic/use-of-the-translate-function#25080000000989698

Thanks for you help.

Replies(6)

amnon.owed

Re: Display and for loop

2 years ago

For starters...

for (int i = 0; i > 6; i = i + 1)

..should be...

for (int i = 0; i < 6; i = i + 1)

Here are a few other suggestions...

float cos18 = cos(radians(18));
float cos36 = cos(radians(36));
float cos54 = cos(radians(54));
float cos72 = cos(radians(72));
void setup() {
size(800, 600);
smooth();
noStroke();
}
void draw() {
background(255);
translate(width/2, height/2);
for (int i=0; i<6; i++) {
pushMatrix();
fill(((i+frameCount*0.1)*50) % 255, 0, 0);
rotate(radians(72*i));
float longuer = 100 + sin(frameCount*0.01) * 25;
pentagone(longuer);
popMatrix();
}
}
void pentagone(float longueur) {
beginShape();
vertex(0, 0);
vertex(longueur * cos36, longueur * cos54);
vertex((longueur * cos36) - (longueur * cos72), (longueur * cos54) + (longueur * cos18));
vertex((longueur * cos36) - (longueur * cos72) - longueur, (longueur * cos54) + (longueur * cos18));
vertex(-longueur * cos36, longueur * cos54);
endShape(CLOSE);
}

sillyfrog

Re: Re: Display and for loop

2 years ago

mistyping!! Shame on me !!

amnon.owed

Re: Display and for loop

2 years ago

Just playing around with the code some more...

float x,y;
void setup() {
size(1280,720);
smooth();
noStroke();
}
void draw() {
background(255);
translate(width/2, height/2);
x = x*0.99 + mouseX * 0.01;
y = y*0.99 + mouseY * 0.01;
for (int i=0; i<16; i++) {
pushMatrix();
fill(((i+frameCount*0.1)*50) % 255, 0, 0);
translate((x-width/2) * 0.1 * i,(y-height/2) * 0.1 * i);
rotate(radians(72*(i+frameCount*0.005)));
float longuer = width/1.3 - 65*i + sin(frameCount*0.01) * 25;
pentagone(longuer,5+i);
popMatrix();
}
}
void pentagone(float longueur, int numpoints) {
beginShape();
for(int i=0; i<numpoints+1; i++) {
vertex(sin(radians(i*360/numpoints))*longueur, cos(radians(i*360/numpoints))*longueur);
}
endShape(CLOSE);
}

sillyfrog

Re: Re: Display and for loop

2 years ago

Cool!!

What I am actually trying to do is draw a six-pointed star with 6 pentagons, and so far, I have failed !!

Help !! :) And thanks for your answers.

amnon.owed

Re: Display and for loop

2 years ago

Like this?

int numPentagons = 6;
void setup() {
size(1280,720);
smooth();
noStroke();
}
void draw() {
background(255);
translate(width/2, height/2);
for (int i=0; i<numPentagons; i++) {
pushMatrix();
fill(((i+frameCount*0.1)*50) % 255, 0, 0);
rotate(radians(360/numPentagons*i));
translate(0,60);
pentagone(80,5);
popMatrix();
}
}
void pentagone(float longueur, int numpoints) {
beginShape();
for(int i=0; i<numpoints+1; i++) {
vertex(sin(radians(i*360/numpoints))*longueur, cos(radians(i*360/numpoints))*longueur);
}
endShape(CLOSE);
}

sillyfrog

Re: Re: Display and for loop

2 years ago

Thanks ever so much.

Had finally done it, differently :

Here is the code:

float cos18 = cos(radians(18));

float cos36 = cos(radians(36));

float cos54 = cos(radians(54));

float cos72 = cos(radians(72));

float longueur = 80;

void setup()

{

size(1500,1200);

smooth();

//noStroke();

}

void draw() {

background(255);

translate(width/2, height/2);

translate(-200,-200);

figure1(longueur);

}

void pentagone(float longueur)

{

beginShape();

vertex(0,0);

vertex(longueur * cos36, longueur * cos54);

vertex((longueur * cos36) - (longueur * cos72), (longueur * cos54) + (longueur * cos18));

vertex((longueur * cos36) - (longueur * cos72) - longueur, (longueur * cos54) + (longueur * cos18));

vertex(-longueur * cos36, longueur * cos54);

endShape(CLOSE);

}

void figure1(float longueur)

{

for (int i = 0; i < 6; i = i + 1)

{

pushMatrix();

rotate(radians(180));

pentagone(longueur);

translate(0,10);

pentagone(70);

popMatrix();

translate(55,36);

rotate(radians(60));

}

Top Reply