Delayed interation with an object

Programming Questions

danprince

Delayed interation with an object

in Programming Questions • 2 years ago

I am trying to write a program that remembers the past mouseX and mouseY values that the user inputs for a defined number of milliseconds in order to create a trail of objects behind the mouse's current position. I have this code so far that has no such function, but renders a rotating cube that follows the mouse:

import processing.opengl.*;
Cube cube1;
float angleCounter = 0.0;
float angleSteps = 300.0;

void setup(){
size(500, 500, OPENGL);
frameRate(60);
smooth();
cube1 = new Cube(100, #FFAAAA); //Size, color (hex)
}

void draw() {
angleCounter += TWO_PI/angleSteps;
background(#FFFFFF);
cube1.display();
}
class Cube {
int cubeSize;
int cubeColor;
int frames;

Cube(int tmpCubeSize, int tmpCubeColor) {
    cubeSize = tmpCubeSize;
    cubeColor = tmpCubeColor;
}

void display(){
    translate(mouseX, mouseY);
    rotateX(angleCounter);
    rotateY(2*angleCounter);
    fill(cubeColor);
    box(cubeSize);
}
}

I want to be able to set the number of ms to delay more instances of Cube behind the mouse, but I cannot figure out how to do so. I believe that something involving two arrays, one for each mouse axis, would have to be set up that have the same number of points as the time that the "tail" objects are being delayed, and every entry in both arrays after an initial period would be shifted over and then the last ones would be used for the object's position. I tried to implement this myself, but I was unable to do so.

Sorry if my description was not coherent, I am a beginner to computer programming. It is also very possible that I am overlooking a very simple solution to my problem. Thank you in advance for your help. :)

Replies(2)

blindfish

Re: Delayed interation with an object

2 years ago

It is also very possible that I am overlooking a very simple solution to my problem.

It's really a matter of using the appropriate variable type for the given situation. You could use separate arrays, but arrays don't come with methods to add and remove entries; whereas ArrayLists do. But ArrayLists store objects and not primitive data types like ints or floats... As it happens this isn't a problem as rather than creating two separate ArrayLists you're better off using just one and storing the coordinates in a PVector object.

As for using a defined number of milliseconds to determine the length of the trail - that's certainly a possibility and there may be a reason why you want to be that specific; but in practice it's hard to be that accurate and you may get the result you need simply by setting the maximum size of the ArrayList. Here's a quick demo:

ArrayList storage;
int trailLength = 13;
void setup() {
size(400,400);
storage = new ArrayList();
noCursor();
noStroke();
}
void draw() {
background(0);
int len = storage.size();
// draw the trail
for(int i=0; i < len; i++) {
// retrieving values from an ArrayList is a little more tricky than with an array
PVector pmouse = (PVector) storage.get(i);
fill(255/len * (i+1));
ellipse(pmouse.x, pmouse.y, i, i);
}
// store current mouse position
PVector currentMouse = new PVector(mouseX, mouseY);
storage.add(currentMouse);
if(storage.size() >= trailLength) {
storage.remove(0);
}
}

danprince

Re: Re: Delayed interation with an object

2 years ago

That's exactly the effect I was looking for! It isn't that important that I measure the trail length in milliseconds, it was just what seemed logical to me. Thanks for your help.

Top Reply