Delay for strings

General Discussion Other

milesking..

in General Discussion • Other • 4 months ago

Hello all.

So recently, Ive been loading strings into my program, using loadString().

What Im wondering is if theres a way to load a line of the string, wait for like half a second, and then load the next line.

For example, if I have an csv file. I have 3 coordinates.

700, 578

349, 547

120, 700

What I want to do is first load the first coordinate, wait like 1 second, and then load the next line. How would I go about doing that?

Replies(4)

tfguy44

Re: Delay for strings

4 months ago

You wouldn't. You would load the whole file as an array of strings, and then wait a certain amount of time (by checking millis()) before you used the next string.

Example:

String[] myStrings;
int time;
int i;
void setup(){
size(220,220);
myStrings = loadStrings( "someFile.txt" );
time = millis() + 1000;
i = 0;
}
void draw(){
background(255);
text( myStrings[i], 20, 20);
if( millis() > time ){
i++;
i%=myStrings.length;
time=millis() + 1000;
}
}

(This example is untested, meaning I wrote it without trying it... Fingers crossed!)

milesking..

Re: Delay for strings

4 months ago

Yes, it works. Thanks

GoToLoop

Re: Delay for strings

4 months ago

An alternative which uses a separate thread() + delay() to determine the frequency of index update:

final static short  FREQ = 1000;
final static String FILE_NAME = "Coords.txt";

String[] myStrings;
int idx;
boolean isActive = true;

void setup() {
  size(100, 50);
  noLoop();
  fill(0);

  myStrings = loadStrings(FILE_NAME);

  thread("indexCounter");
}

void draw() {
  background(-1);
  text("Index: #" + idx + '\n' + myStrings[idx], 20, 20);
}

void indexCounter() {
  while (isActive) {
    delay(FREQ);
    idx = (idx+1) % myStrings.length;
    redraw();
  }
}

GoToLoop

Re: Delay for strings

4 months ago

A more complex 1, in which coordinates are already numbers inside a 2D array:

// http://forum.processing.org/topic/delay-for-strings

final static short  FREQ = 1000;
final static String FILE_NAME = "Coords.txt";

int idx, myCoords[][];
boolean isActive = true;

void setup() {
  size(800, 800);
  noLoop();

  fill(0);
  stroke(#F0A0A0);
  strokeWeight(0100);
  textSize(040);

  final String[] rows = loadStrings(FILE_NAME);
  myCoords = new int[rows.length][2];

  for ( int i = 0; i != rows.length;
    myCoords[i] = int(split(rows[i++], ", ")) );

  thread("indexCounter");
}

void draw() {
  background(0350);

  final int x = myCoords[idx][0], y = myCoords[idx][1];
  final String str = "Index: #" + idx + "\n(" + x + ", " + y + ")";

  text(str, 050, 050);
  point(x, y);
}

void indexCounter() {
  while (isActive) {
    delay(FREQ);
    idx = (idx+1) % myCoords.length;
    redraw();
  }
}