declare neighbors in 3D Game Of Life

Programming Questions

eiswolf

declare neighbors in 3D Game Of Life

in Programming Questions • 1 year ago

I'm kinda stuck with my three dimensional implementation of the game of life. I get very confusing results when trying to figure out the neighbors of each cell. They all end up with a different number of neighbors and none of them has all expected 26. The part in question is the knock() method inside the Cell class. Here's my code so far:

import processing.opengl.*;
boolean pressed = false;
Cell cells[][][];
int dim = 6, space = 25; //dimension of the cube and spacing between the cells
void setup() {
size(600, 600, OPENGL);
background(200, 100, 0);
smooth();
frameRate(24);
text("created by ChristianGeick 2011", width-200, height-50);
cells = new Cell[dim][dim][dim];
for(int x=0; x<dim; x++) {
for(int y=0; y<dim; y++) {
for(int z=0; z<dim; z++) {
cells[x][y][z] = new Cell(x, y, z);
}
}
}
}
void mousePressed() {
pressed = true;
}
void draw() {
if(pressed) {
background(54, 63, 69);
translate(width/2, height/2);
rotateY(radians(frameCount));
for(int x=0; x<dim; x++) {
for(int y=0; y<dim; y++) {
for(int z=0; z<dim; z++) {
if(cells[x][y][z] != null) {
cells[x][y][z].live();
cells[x][y][z].paint();
}
}
}
}
}
}
class Cell {
PVector loc;
int x, y, z;
boolean alive;
Cell neighbors[];
Cell(int a, int b, int c) {
x = a;
y = b;
z = c;
loc = new PVector((x-dim/2)*space, (y-dim/2)*space, (z-dim/2)*space);
if(random(1)>0.5) {
alive = true;
} else {
alive = false;
}
neighbors = new Cell[27];
knock();
}
//!! this is the part that doesn't seem to work properly !!
//get all the 26 neighbors
void knock() {
int count = 0;
int xx, yy, zz; //variables for declaring the neighbor
for(int a=-1; a<=1; a++) {
for(int b=-1; b<=1; b++) {
for(int c=-1; c<=1; c++) {
if(!(a==0 && b==0 && c==0)) { // leave out the actual cell itself
xx = x+a;
yy = y+b;
zz = z+c;
//cells at the edges reach over to the other side of the grid
if(x == 0) {
xx = dim-1;
}
if(y == 0) {
yy = dim-1;
}
if(z == 0) {
zz = dim-1;
}
if(x == dim-1) {
xx = 0;
}
if(y == dim-1) {
yy = 0;
}
if(z == dim-1) {
zz = 0;
}
neighbors[count] = cells[xx][yy][zz];
count++;
}
}
}
}
}
//display cell
void paint() {
if(alive) {
pushMatrix();
translate(loc.x, loc.y, loc.z);
int trans = x*10 + y*10 + z*10;
fill(254, 180, 28, trans);
noStroke();
sphereDetail(10);
sphere(5);
popMatrix();
}
}
//determine the state of the cell
void live() {
int lifes = 0;
for(int i=0; i<neighbors.length; i++) {
if(neighbors[i] != null) {
if(neighbors[i].alive) {
lifes++;
}
}
}
if(lifes > 5 && lifes < 10) {
alive = true;
} else {
alive = false;
}
}
}

Thanks for any advice.

Replies(4)

jbum

Re: declare neighbors in 3D Game Of Life

1 year ago

I think your knock() function is fine. If you add the following line to the end of your knock your function:

println("count = " + count);

You'll see you always get 26 numbers. So, what is going on that made you believe you were getting a random number of numbers?

jbum

Re: declare neighbors in 3D Game Of Life

1 year ago

I think I see the problem.

You are computing your neighbors in the cell's constructor. Your neighbor array points to other neighbors. In your initial loop that makes the cells, the neighbors have not yet been constructed yet (because you are still constructing cells).

You need to take the call to knock() out of the constructor. Then, after you've created all the cells, make another loop that calls knock for each cell.

Like so:

(and remember, remove your current call to knock() which is at the end of your constructor).

for(int x=0; x<dim; x++) {
for(int y=0; y<dim; y++) {
for(int z=0; z<dim; z++) {
cells[x][y][z] = new Cell(x, y, z);
}
}
}
for(int x=0; x<dim; x++) {
for(int y=0; y<dim; y++) {
for(int z=0; z<dim; z++) {
cells[x][y][z].knock();
}
}
}

jbum

Re: declare neighbors in 3D Game Of Life

1 year ago

Also, one other problem you're going to have: As you update the state of all your cells, it has an effect on future cells whose state you are checking. Typically Conway life simulations are done with twin buffers to prevent this problem. You compute the state of each cell based on the results of the previous pass only, but don't allow the current state changes to effect the neighbors. Hope that makes sense.

eiswolf

Re: declare neighbors in 3D Game Of Life

1 year ago

You're totally right! Haven't thought about this at all. So I'm going to add a method to the cells that determines the follow up state and one to actually change to that state to avoid that interference. Thanks so much!

Top Reply