Damping the input of my processing sketch

Core Library Questions

njitram

Damping the input of my processing sketch

in Core Library Questions • 2 years ago

Hi there,

I'm working on a FFT Audio Analyzer via Internal Routing that can send OSC Data.

So I'm getting data from say Windows Media Player to my processing in three bands, High, Mid and Low.

What I want to know is if there is a way to smooth these data inputs. Is there a way to dampen the data so that it doesnt immediatley jump to high peaks?

I used alot of search terms like easing, damping, smoothin, etc... but couldnt find anything.

VVVV has a really simple solution that is called damping but i don't think processing has that.

Someone got a hint in wich direction i need to look for?

Replies(7)

njitram

Re: Damping the input of my processing sketch

2 years ago

No one?

Is my question not clear enough?

I'm trying to smooth out the FFT Analyser, so that for example a bassdrum in a song doesnt immediately peak.

kooogy

Re: Damping the input of my processing sketch

2 years ago

lerp() perhaps.

store the current position and the new position and linearly interpolate between them over, say, 10 steps. i'm guessing you'll be updating the screen faster than you'll be sampling the data.

njitram

Re: Damping the input of my processing sketch

2 years ago

Wow that doesnt seem like an easy funtion, how do you refer to current position en new position. And i dont know if i'm updating my screen faster then sampling my data.

If you you're willing, would you want to look at my code?

The code (I have no idea if the code is some what orderly, kind of a noob programmer here :) ):

import ddf.minim.*;
import ddf.minim.analysis.*;

Minim minim;
AudioInput in;
FFT fft;

int w;
// how many bands per octave
int q = 4;

void setup() {
size(600, 300);
minim = new Minim(this);
in = minim.getLineIn(Minim.STEREO, 512);
fft = new FFT(in.bufferSize(), in.sampleRate());
fft.logAverages(60, q);
stroke(255);
w = width/fft.avgSize();
strokeWeight(w-4);
strokeCap(SQUARE);
}

void draw() {
background(0);
fft.forward(in.mix);
//lower frequencies
for(int j = 0; j < 7; j++){
//mid frequencies
for(int k = 7; k < 14; k++){
//high frequencies
for(int l = 14; l < 28; l++){
//to damnnn high frequencies
for(int m = 28; m < 36; m++){
stroke(255,255,0);
line((m*w), height, (m*w),height - fft.getAvg(m) * 4);
}
stroke(0,255,0);
line((l*w), height, (l*w),height - fft.getAvg(l) * 4);
line(0, 20, fft.getAvg(l) * 17, 20);
}
stroke(0,0,255);
line((k*w), height, (k*w),height - fft.getAvg(k) * 4);
line(0, 80, fft.getAvg(k) * 5, 80);

}
stroke(255,0,0);
line((j*w), height, (j*w),height - fft.getAvg(j) * 4);
line(0, 120, fft.getAvg(j) * 4, 120);
}

}

njitram

Re: Damping the input of my processing sketch

2 years ago

Allright I looked a bit around, and it seems very hard to acces the previous frame and it's data. Can someone help me out here?

I have absolutely no idea how and where to begin with this.

amnon.owed

Re: Damping the input of my processing sketch

2 years ago

Some suggestions:

Press CTRL-T (autoformat) to make your code more readable.
Then it will become clear that you have several nested for loops, which you don't need. The for loops are all seperate, so nesting them will make your program do a lot of unnecessary calculations.
You have 4 similar for loops to distinguish only between colors. All other things are the same. So instead of repeating code, use 1 for loop and some if-else statements to change the color.
You have 36 incoming values. To dampen them have an array of 36 floats and ease with a certain speed from the old value to the new value. In the code below a dampen value of zero is equal to your old code. I've set it to a dampen value of 0.85. You can increase it up to 1. For example 0.99 will really dampen changes.
I've also removed the horizontal bars, they seemed out of place, but of course it's the same for them.

Adapted Code

import ddf.minim.*;
import ddf.minim.analysis.*;
Minim minim;
AudioInput in;
FFT fft;
int w;
int q = 4;
float h[] = new float[36];
float dampen = 0.85; // between 0 and 1
void setup() {
size(620, 300);
minim = new Minim(this);
in = minim.getLineIn(Minim.STEREO, 512);
fft = new FFT(in.bufferSize(), in.sampleRate());
fft.logAverages(60, q);
w = width/fft.avgSize();
strokeWeight(w-4);
strokeCap(SQUARE);
}
void draw() {
background(0);
fft.forward(in.mix);
for (int i=0; i<36; i++) {
if (i < 7) { stroke(255, 0, 0); }
else if (i < 14) { stroke(0, 0, 255); }
else if (i < 28) { stroke(0, 255, 0); }
else { stroke(255, 255, 0); }
int x = 12 + i * w;
h[i] = h[i] * dampen + fft.getAvg(i) * 4 * (1-dampen);
line(x, height, x, height - h[i]);
}
}

njitram

Re: Damping the input of my processing sketch

2 years ago

Holy shit dude!

Thanks!! :)

I'm still new in programming so dont know the proper use of syntax, but combining 'for' and 'if' is really smart :)

I still dont really understand how you did it, but i'll figure it out :)

njitram

Re: Damping the input of my processing sketch

2 years ago

If I were to send the data of every colored bar via OSC, could i do this also whit the code you gave me?

I'm looking into arrays and how to refer to only a piece of an array, but really can't figure it out how to do it.

So for example if i wanted to send the average of the values of the red bars to, for example Unity, via OSC.

Thanks for helping me so far btw! :)

Top Reply