Creating PDF when using copy() and multiple images

Core Library Questions

smooth_sp..

Creating PDF when using copy() and multiple images

in Core Library Questions • 5 months ago

Hi,

I've written a sketch that imports two photos and then uses the copy() and updatePixels() commands to sample parts of one picture and insert them into the other. The core of the program runs fine, except that I am having trouble getting it to generate a pdf image using the Processing.pdf library. It generates an error message saying "No copy() for PGraphicsPDF."

Does anyone know a way to make this work? I'm wondering if the issue is that PDF's need flattened images. If that's the case, is there a way to flatten multilayered images in Processing like the Flatten function in Photoshop? Or is there a better way to import the images into the sketch that would be more compatible with Processing.pdf? Or is there a way to delete an image from the sketch once you've sampled it, so that there's only one layer left? (Or is the problem is something else entirely?)

Here's the code. Advice would be most appreciated.

import processing.pdf.*;

void setup() {

size (800, 800);

smooth();

beginRecord (PDF, "filename.pdf");

}

void draw() {

//loads two images into the sketch

PImage myImage = loadImage ("Picture1.jpg");

image (myImage, 0, 0);

PImage myImage2 = loadImage ("Picture2.jpg");

image (myImage2, 0, 0);

pushMatrix();

loadPixels(); //samples the pixels

//defines parameters for pixel sampling

int w = int(random(width));

for (int i = 0; i < 300; i++) {

int x = int(random(50,100));

int y = int(random(height));

//moves the pixels around

copy (myImage2, w, y, x, x, int(random(-100,900)), y, x, x);

}

updatePixels(); //writes the new arrangement of pixels

popMatrix();

endRecord();

noLoop();

}

Replies(8)

PhiLho

Re: Creating PDF when using copy() and multiple images

5 months ago

It is part of a larger program? Because this one has some strange quirks:
- No need to load the images on each frame...
- No need to pushMatrix() if you don't do transformations.
- No need to loadPixels() if you don't use the pixels[] array.
- PDF offers no advantage over a good old bitmap format for your sketch, since you have no vectorial information there...

smooth_sp..

Re: Creating PDF when using copy() and multiple images

5 months ago

Thanks, PhiLho.

I just realized that I forgot to include an endRecord(); near the end of the sketch, which might have been part of the confusion. It's in there now. What you see is the whole sketch; it's not a part of anything else, though I've just put in "Picture 1/2" as placeholders.

Thanks for the suggestion about pushMatrix() and loadPixels(). I took them out in my local version and they don't seem to make any difference.

I tried moving the code to load images either into the setup() or the global area above setup(), and get errors. In the first case, myImage2 in the draw loop doesn't know where to find the image. In the latter, it tells me I'm mixing active and static modes.

I'm trying to get it to convert to a PDF with the idea of making physical prints. As is, this renders just fine on the screen, but Grab for Mac only gives you low-res captures that look awful when you try to blow them up. I'd love to know if it's possible to generate hi-res outputs.

PhiLho

Re: Creating PDF when using copy() and multiple images

5 months ago

You have to declare the image at the global level, and load it in setup(), because loadImage() at the global level doesn't know the data folder yet.
See, for example, the example at http://wiki.processing.org/w/I_display_images_in_sequence_but_I_see_only_the_last_one._Why%3F

Have you tried to output a simple image in PDF and see what the "blow up" gives, compared to a simple image?
Unless the PDF reader is very smart (why not?), you might see exactly the same awful result: as said, you don't save a vectorial information, the kind that can be scaled infinitely. Bitmap image, when scaled up too much, generally looks bad. The container (image format or PDF format) doesn't change much the result.

smooth_sp..

Re: Creating PDF when using copy() and multiple images

5 months ago

I think this is what you're suggesting, in terms of declaring and loading images (see below).

I compared printing one original image directly vs. running it through the sketch and printing it post-Processing. I end up with an image that's about 11x11 at 300 dpi, which is reasonable in size, although there's definitely a loss in quality in comparison with the original. A while ago I did this for a sketch that was just graphics, which looked quite good, but I see what you mean about the photo quality.

Still kinda curious, though, whether there's any way to generate a pdf in a sketch with copy(). That still seems to be the hangup. Maybe this is just a limitation in processing.pdf.

import processing.pdf.*;

PImage myImage;

PImage myImage2;

void setup() {

size (800, 800);

smooth();

myImage = loadImage ("Picture1.jpg");

myImage2 = loadImage ("Picture2.jpg");

beginRecord (PDF, "filename.pdf");

}

void draw() {

image (myImage2, 0, 0);

int w = int(random(width));

for (int i = 0; i < 300; i++) {

int x = int(random(50,100));

int y = int(random(height));

copy (myImage, w, y, x, x, int(random(-200,1200)), y, x, x);

endRecord();

}

noLoop();

}

PhiLho

Re: Creating PDF when using copy() and multiple images

5 months ago

Now that I clarified the issues, I think you can do something similar by creating a JAVA2D PGraphics, and doing the image() and copy() operations on it, then you can image() it on the PDF surface.
Because of the issues mentioned above, most of the bitmap operations (like blend and such) are deactivated in PDF.

PhiLho

Re: Creating PDF when using copy() and multiple images

5 months ago

A practical example:

import processing.pdf.*;
PImage myImage;
PImage myImage2;
void setup() {
size (800, 800);
smooth();
myImage = loadImage ("H:/Temp/Tree.jpg"); // I just use absolute paths because I don't save these small test sketches... So no data folder for me!
myImage2 = loadImage ("H:/Temp/Test.jpg");
beginRecord (PDF, "H:/Temp/filename.pdf");
}
void draw() {
PGraphics result = createGraphics(width, height, JAVA2D);
result.beginDraw();
result.image (myImage2, 0, 0);
int w = int(random(width));
for (int i = 0; i < 300; i++) {
int x = int(random(50, 100));
int y = int(random(height));
result.copy (myImage, w, y, x, x, int(random(-200, 1200)), y, x, x);
// endRecord(); // Should be after the loop, if you use this style
}
result.endDraw();
image(result, 0, 0);
endRecord();
println("Done");
noLoop();
exit();
}

smooth_sp..

Re: Creating PDF when using copy() and multiple images

5 months ago

That works! I'll have to see how it looks printed, but that does generate the pdf. I also just noticed that an alternative to using processing.pdf to generate the image is to use save(). [a version of that below] It can go directly to jpg, though it looks like that's going to be at lower resolution. I'll have to do some testing to see how they compare and how well they print.

At any rate, I think you've helped me over a hurdle, so thanks a lot for taking the time to look at this, PhiLho!

PImage myImage;

PImage myImage2;

void setup() {

size (800, 800);

myImage = loadImage ("Imagename.jpg");

myImage2 = loadImage ("Imagename2.jpg");

}

void draw() {

PGraphics result = createGraphics(width, height, JAVA2D);

result.beginDraw();

smooth();

result.image (myImage2, 0, 0);

int w = int(random(width));

for (int i = 0; i < 300; i++) {

int x = int(random(50, 100));

int y = int(random(height));

result.copy (myImage, w, y, x, x, int(random(-200, 1200)), y, x, x);

// endRecord(); // Should be after the loop, if you use this style

}

result.endDraw();

image(result, 0, 0);

save("processedimage.jpg");

println("Done");

noLoop();

exit();

}

PhiLho

Re: Creating PDF when using copy() and multiple images

5 months ago

If you use save(), use the PNG format: image file will be bigger but it will be of higher quality (no Jpeg compression artifacts).

Top Reply