Creating lines using an array - help please!

Programming Questions

maybeshew..

Creating lines using an array - help please!

in Programming Questions • 6 months ago

I'm using data that I collected using the AntiMap log application for iPhone. It collects data using Latitude, Longitude, Compass, Speed, Distance, Time. I built an array to store all of this data, but I need to plot the points and draw lines connecting the points.

This is an example of the data:

40.544951,-75.674205,310,83.18,5.37,8096,

40.544951,-75.674205,310,83.18,5.37,8129,

40.544951,-75.674205,310,83.18,5.37,8163,

40.544951,-75.674205,310,83.18,5.37,8196,

40.544999,-75.673914,310,84.24,5.40,8228,

40.544999,-75.673914,310,84.24,5.40,8262,

40.544999,-75.673914,310,84.24,5.40,8295,

40.544999,-75.673914,310,84.24,5.40,8328,

40.544999,-75.673914,310,84.24,5.40,8362,

40.544999,-75.673914,310,84.24,5.40,8395,

40.544999,-75.673914,310,84.24,5.40,8429,

40.544999,-75.673914,310,84.24,5.40,8462,

40.544999,-75.673914,310,84.24,5.40,8495,

40.544999,-75.673914,310,84.24,5.40,8529,

40.544999,-75.673914,310,84.24,5.40,8562,

This is the code that I have so far:

1. String[] lines;
2. float max1, min1, max2, min2;
4. float a, b;
7. float[] x = new float[100000];
8. float[] y = new float[100000];
10. void draw() {
11. background(255);
12. stroke(0);
14. }
16. void setup() {
18. size( 1000, 1000);
20. background( 200) ;
22. lines = loadStrings("090213_0950_29.csv");
23. // println(lines.length);
26. // this gets the values from the files & calculates the min & max
27. for (int i=0;i<lines.length;i++) {
28. a = float(split(lines[i], ',')[0]);
29. b = (float(split(lines[i], ',')[1]))*-1;
31. if (i==0) {
32. max1=min1=a;
33. max2=min2=b;
34. }
36. if ( a<min1 ) min1=a;
37. if ( a>max1) max1=a;
39. if ( b<min2 ) min2=b;
40. if ( b>max2) max2=b;
43. // println( a + " " + b );
45. //smooth();
46. // point( float(split(lines[i],',')[0])*100, (float(split(lines[i],',')[1]))*-1 );
47. }
49. // println( ">>"+max1+" " + min1 + " >>"+max2+" " +min2);
51. float newA, newB;
53. for (int i=0;i<lines.length;i++) {
55. a = float(split(lines[i], ',')[0]);
56. b = (float(split(lines[i], ',')[1]))*-1;
58. newA = (map( a, min1, max1, 0, 100))*4;
59. newB = map( b, min2, max2, 0, 10000);
61. x[i] = newA;
62. y[i] = newB;
64. // draw newA and newB
67. }
70. }
74. //println( ">>"+max1+" " + min1 + " >>"+max2+" " +min2);

Can someone please help me?

Replies(6)

quarks

Re: Creating lines using an array - help please!

6 months ago

I have modified the code so that each line of file becomes a Record object. Each record holds all the data for a log event. It also calculates the min and max longitude and latitude.

Using a class for a record means that you only need a single array which makes programming easier.

float minLat, minLon, maxLat, maxLon;
Record[] data;
void draw() {
background(255);
stroke(0);
}
void setup() {
size( 1000, 1000);
makeRecords("090213_0950_29.csv");
printRecords();
}
void printRecords(){
for(int i = 0; i < data.length; i++){
print(data[i].lat + "\t ");
print(data[i].lon + "\t ");
print(data[i].compass + "\t ");
print(data[i].speed + "\t ");
print(data[i].dist + "\t ");
print(data[i].time + "\t ");
println();
}
println("Min longitude = " + minLon);
println("Max longitude = " + maxLon);
println("Min latitude = " + minLat);
println("Max latitude = " + maxLat);
}
void makeRecords(String filename) {
String[] lines = loadStrings("090213_0950_29.csv");
data = new Record[lines.length];
minLat = minLon = Float.MAX_VALUE;
maxLat = maxLon = -Float.MAX_VALUE;
for (int i = 0; i < lines.length; i++) {
Record r = new Record(lines[i]);
if (r.lon > maxLon) maxLon = r.lon;
if (r.lon < minLon) minLon = r.lon;
if (r.lat > maxLat) maxLat = r.lat;
if (r.lat < minLat) minLat = r.lat;
data[i] = r;
}
}
class Record {
float lat;
float lon;
float compass;
float speed;
float dist;
float time;
Record(String line) {
String[] value = line.split(",");
lat = Float.parseFloat(value[0]);
lon = Float.parseFloat(value[1]);
compass = Float.parseFloat(value[2]);
speed = Float.parseFloat(value[3]);
dist = Float.parseFloat(value[4]);
time = Float.parseFloat(value[5]);
}
}

maybeshew..

Re: Re: Creating lines using an array - help please!

6 months ago

Thanks so much for you help!

When i use the 'run' button in processing, I would want it to show all of the coordinates that are collected in the data with a line connecting the coordinate. Something like this :

http://ars.els-cdn.com/content/image/1-s2.0-S0301462202002855-gr15.gif

But without it being on a grid, just lines connecting the coordinate points.

quarks

Re: Creating lines using an array - help please!

6 months ago

You need to be more specific about what you want plotted. This picture you supply doesn't help. For instnace what is the x axis and what is the y axis.

Looking at the data it seems that you have multiple recored for each long/lat coordinate.

maybeshew..

Re: Creating lines using an array - help please!

6 months ago

I want the latitude and longitude coordinates plotted with a line connecting the coordinates to each other.

Yes- the data has a crazy amount of lines of information. It was collected and used kind of how a gps knows where youre going. The data is based off of a car ride.

This is the app that I used - http://theantimap.com/

quarks

Re: Creating lines using an array - help please!

6 months ago

This will do it although you need more unique long/lat points to be certian.

float minLat, minLon, maxLat, maxLon;
float lon, lat;
Record[] data;
void draw() {
background(255);
stroke(0);
float lastLon = map(data[0].lon, minLon, maxLon, 0, width);
float lastLat = map(data[0].lat, minLat, maxLat, 0, height);
for (int i = 1; i < data.length; i++) {
float lon = map(data[i].lon, minLon, maxLon, 0, width);
float lat = map(data[i].lat, minLat, maxLat, 0, height);
line(lastLon, lastLat, lon, lat);
lastLon = lon;
lastLat = lat;
}
}
void setup() {
size( 1000, 1000);
makeRecords("090213_0950_29.csv");
printRecords();
}
void printRecords() {
for (int i = 0; i < data.length; i++) {
print(data[i].lat + "\t ");
print(data[i].lon + "\t ");
print(data[i].compass + "\t ");
print(data[i].speed + "\t ");
print(data[i].dist + "\t ");
print(data[i].time + "\t ");
println();
}
println("Min longitude = " + minLon);
println("Max longitude = " + maxLon);
println("Min latitude = " + minLat);
println("Max latitude = " + maxLat);
}
void makeRecords(String filename) {
String[] lines = loadStrings("090213_0950_29.csv");
data = new Record[lines.length];
minLat = minLon = Float.MAX_VALUE;
maxLat = maxLon = -Float.MAX_VALUE;
for (int i = 0; i < lines.length; i++) {
Record r = new Record(lines[i]);
if (r.lon > maxLon) maxLon = r.lon;
if (r.lon < minLon) minLon = r.lon;
if (r.lat > maxLat) maxLat = r.lat;
if (r.lat < minLat) minLat = r.lat;
data[i] = r;
}
}
class Record {
float lat;
float lon;
float compass;
float speed;
float dist;
float time;
Record(String line) {
String[] value = line.split(",");
lat = Float.parseFloat(value[0]);
lon = Float.parseFloat(value[1]);
compass = Float.parseFloat(value[2]);
speed = Float.parseFloat(value[3]);
dist = Float.parseFloat(value[4]);
time = Float.parseFloat(value[5]);
}
}

maybeshew..

Re: Creating lines using an array - help please!

6 months ago

Thank you so much for your help! I reaally appreciate it.

Top Reply

Statistics

6 Replies
501 Views
0 Followers

Actions

Permalink