Creating a pattern of colors from an array

Programming Questions

lfmax223

Creating a pattern of colors from an array

in Programming Questions • 2 years ago

Hi guys,

This is my first time using processing and I am still getting used to it but I'm trying to learn as much as I can. For my project I will be using OpenCV to read another computer monitor and analyze the pixel values from four quadrants of the display.

I am trying to create an array of colors that will be displayed in sequence by the four rectangular sections. For example, the first color (let's say blue) will fill the top right section, then the bottom right quadrant will change to blue as the next color in the array (red) replaces it in the top right sector. This sequence will repeat until blue has rotated into the upper right sector and is then discarded. This will continue until all colors in the array have been displayed and rotated throughout the quadrants, eventually reaching the end of the color array and displaying a blank screen.

I have been reading many examples and tutorials but I cannot seem to figure out this specific problem, any help would be greatly appreciated!

Thank you.
-Max

Replies(2)

amnon.owed

Re: Creating a pattern of colors from an array

2 years ago

You can use an array of colors and an integer to keep track of the current (top-right) color. You can use fill and rect for the four rectangles. To prevent nullpointerexceptions, you could make a function that only returns the selected colors when they are within range and otherwise (below 0 or more than the max) returns white. You can use modulo to increase the current color by one every nth frame. The example below shows all of these points implemented and includes some code to generate the necessary number of random colors.

Code Example

int numColors = 100; // the number of different random colors
color[] colors = new color[numColors];
int current;
void setup() {
size(500, 500);
noStroke();
for (int i=0; i<colors.length; i++) {
colors[i] = color(random(255), random(255), random(255));
}
}
void draw() {
background(255);
fill(getColor(current));
rect(width/2, 0, width/2, height/2);
fill(getColor(current-1));
rect(width/2, height/2, width/2, height/2);
fill(getColor(current-2));
rect(0, height/2, width/2, height/2);
fill(getColor(current-3));
rect(0, 0, width/2, height/2);
if (frameCount % 60 == 0) { current++; }
}
color getColor(int index) {
if (index >= 0 && index < colors.length) {
return colors[index];
} else {
return color(255);
}
}

lfmax223

Re: Re: Creating a pattern of colors from an array

2 years ago

That's exactly what I had in mind, thank you very much!

Top Reply