Creating a graph from data

General Discussion Other

alexa_nic..

in General Discussion • Other • 1 year ago

I have a data set that I am looking to put into a graph format. I have absolutely no idea how to even set up the coding in processing or where to begin!

My data is based on the number of times a person says a certain word over a week period, and it is over a period of 20 weeks. I have put my data into a Notepad document as follows:

1, 40

2, 55

3, 56

4, 39

etc. etc....

I don't know how to link my data with processing or how to make a graph... I'm just learning processing!!

Any help would be GREATLY appreciated! Thank You!

Replies(9)

Chrisir

Re: Creating a graph from data

1 year ago

it's been here on the forum

you use loadStrings() first

look it up in the reference
http://www.processing.org/reference/

you can copy paste Code from the help to loadStrings

then you have a list (called an array) of lines (called lines in the example):

1, 40

2, 55

3, 56

4, 39

then you go through it with a for-loop (like in the example for loadStrings)
then inside this loop you use the command split() to split each line at the comma ","

look split up in the reference
http://www.processing.org/reference/

String[] oneLine= split(lines[i], ',');

now you have a 2nd array with weeks in the 1st column (oneLine[0]), how many times in the 2nd one (oneLine[1]).

then still inside this loop (before the closing } )

use trim() and convert to an integer with int

then draw the graph

point (intWeek*10, height - intHowManyTimes*10);

look point up in the reference
http://www.processing.org/reference/

Greetings, Chrisir

amnon.owed

Re: Creating a graph from data

1 year ago

alexa_nicole.123 aka sarah_eliz.123

Some friendly do's and don'ts:

Don't create a new user name for every post.
Don't delete threads with answers.
Do follow the advices that have been given to you both here and in the other thread.
Do show your code, even if it's a failed attempt.

alexa_nic..

Re: Creating a graph from data

1 year ago

I did not mean to delete my last post, I apologize.

I am confused about the "i" in the code and what that means? Do I need to specify at the top what this stands for?

alexa_nic..

Re: Creating a graph from data

1 year ago

Ok I have gotten to this point and nothing seems to be showing up. Anything apparent that seems to be wrong?

String loadDataOne[];

String myDataOne[][];

float xPosDataOne;

float yPosDataOne;

int fieldNum = 2;

int margin = 100;

float rectX = 1;

int xMin = 050111; // min of date

int xMax = 050112; // max of date

int yMin = 0; // min number

int yMax = 110; // max number

color c1 = color(226, 229, 100);

void setup(){

size(1200,600);

smooth();

loadDataOne = loadStrings("data.txt");

myDataOne = new String[loadDataOne.length][fieldNum];

for (int i=0; i < loadDataOne.length; i++){

myDataOne[i] = loadDataOne[i].split(",");

}

void draw() {

background(40);

noStroke();

for (int n=0; n < loadDataOne.length; n++){

xPosDataOne = map(int(myDataOne[n][0]), xMin, xMax, 0+margin, width-margin);

yPosDataOne = map(int(myDataOne[n][1]), yMin, yMax, 0, height-(margin+50));

fill(c1);

rectMode(CORNER);

rect(xPosDataOne, height-margin, rectX, -1*yPosDataOne);

}

amnon.owed

Re: Creating a graph from data

1 year ago

Seems you overcomplicated things. You don't need a 2-dimensional array, but you do need to turn Strings into numbers. See the commented example below.

Code Example

int[] numbers; // array to store the numbers
void setup() {
size(500, 500);
// load the lines into an array of strings
String[] lines = loadStrings("data.txt");
// set the length of the numbers array to the number of lines
numbers = new int[lines.length];
// go over each line (arrays start at zero);
for (int i=0; i<lines.length; i++) {
// split each lines into two strings (remove the space and the comma)
String[] tokens = splitTokens(lines[i], ", ");
// take the second string and put it in the int array
numbers[i] = int(tokens[1]);
}
// by this point the data processing is done
// the file has been loaded, read and parsed into the numbers array
}
void draw() {
background(50);
fill(226, 229, 100);
// calculate the width of one bar depending on the length of the array
float w = (float) width/numbers.length;
// go over all the numbers
for (int i=0; i<numbers.length; i++) {
// get the h and multiply by 4 to increase the visibility
float h = numbers[i] * 4;
// draw a rect
rect(i*w, height-h, w, h);
}
}

alexa_nic..

Re: Creating a graph from data

1 year ago

Thank You! This helps!

alexa_nic..

Re: Creating a graph from data

1 year ago

The "yPosDataOne = map(int(myDataOne[n][1]), yMin, yMax, 0, height-(margin+50));" in my code is highlighted and I am getting the error ArrayIndexOutOfBoundsException: 1

What can I do to fix this?

String loadDataOne[];

String myDataOne[][];

float xPosDataOne;

float yPosDataOne;

int fieldNum = 2;

int margin = 100;

float rectX = 1;

int xMin = 50111;

int xMax = 50612;

int yMin = 0;

int yMax = 150;

color c1 = color(226, 229, 204);

void setup(){

size(1200,600);

smooth();

loadDataOne = loadStrings("protwo.xls");

myDataOne = new String[loadDataOne.length][fieldNum];

for (int i=0; i < loadDataOne.length; i++){

myDataOne[i] = loadDataOne[i].split(",");

}

void draw() {

background(40);

noStroke();

for (int n=0; n < loadDataOne.length; n++){

xPosDataOne = map(int(myDataOne[n][0]), xMin, xMax, 0+margin, width-margin);

yPosDataOne = map(int(myDataOne[n][1]), yMin, yMax, 0, height-(margin+50));

fill(c1);

rectMode(CORNER);

rect(xPosDataOne, height-margin, rectX, -1*yPosDataOne); // draw

}

Chrisir

Re: Creating a graph from data

1 year ago

see here

String loadDataOne[];
/*
= {
"1, 40",
"2, 55",
"3, 56",
"4, 39"
};
*/
String myDataOne[][];
float xPosDataOne;
float yPosDataOne;
int fieldNum = 2;
int margin = 100;
float rectX = 1;
int xMin = 10;
int xMax = 200;
int yMin = 0;
int yMax = 150;
color c1 = color(226, 229, 204);
void setup() {
size(1200, 600);
smooth();
loadDataOne = loadStrings("protwo.xls");
myDataOne = new String[loadDataOne.length][fieldNum];
for (int i=0; i < loadDataOne.length; i++) {
myDataOne[i] = loadDataOne[i].split(",");
}
for (int n=0; n < loadDataOne.length; n++) {
myDataOne[n][0]=trim(myDataOne[n][0]);
myDataOne[n][1]=trim(myDataOne[n][1]);
println( myDataOne[n][0]);
println( myDataOne[n][1]);
}
}
void draw() {
background(40);
noStroke();
for (int n=0; n < loadDataOne.length; n++) {
xPosDataOne = map(int(myDataOne[n][0]), xMin, xMax, 0+margin, width-margin);
yPosDataOne = map(int(myDataOne[n][1]), yMin, yMax, 0, height-(margin+50));
fill(c1);
rectMode(CORNER);
rect(xPosDataOne, height-margin, rectX, -1*yPosDataOne); // draw
}
}

Chrisir

Re: Creating a graph from data

1 year ago

or like this with 0 and 1 replaced with vars with a real name...

final int indeForX=0;
final int indeForY=1;
//
String loadDataOne[] ;
/*
= {
"1, 40",
"2, 55",
"3, 56",
"4, 39"
};
*/
String myDataOne[][];
float xPosDataOne;
float yPosDataOne;
int fieldNum = 2;
//
int margin = 100;
float rectX = 1;
int xMin = 10;
int xMax = 200;
int yMin = 0;
int yMax = 150;
color c1 = color(226, 229, 204);
//
void setup() {
size(1200, 600);
smooth();
loadDataOne = loadStrings("protwo.xls");
myDataOne = new String[loadDataOne.length][fieldNum];
for (int i=0; i < loadDataOne.length; i++) {
myDataOne[i] = loadDataOne[i].split(",");
} // for
for (int n=0; n < loadDataOne.length; n++) {
myDataOne[n][indeForX]=trim(myDataOne[n][indeForX]);
myDataOne[n][indeForY]=trim(myDataOne[n][indeForY]);
print("Week " + myDataOne[n][indeForX] + ": " );
println(myDataOne[n][indeForY]);
} // for
} // func
void draw() {
background(40);
noStroke();
for (int n=0; n < loadDataOne.length; n++) {
xPosDataOne = map(int(myDataOne[n][indeForX]), xMin, xMax, 0+margin, width-margin);
yPosDataOne = map(int(myDataOne[n][indeForY]), yMin, yMax, 0, height-(margin+50));
fill(c1);
rectMode(CORNER);
rect(xPosDataOne, height-margin, rectX, -1*yPosDataOne); // draw
} // for
} // func
//

Top Reply