Create reader/writer- pause on mouseRelease

Programming Questions

carabt

Create reader/writer- pause on mouseRelease

in Programming Questions • 6 months ago

I'm trying to make a reader/writer that records what is drawn in one program and plays it back in the next. No problem, except I can't figure out how to pause the output to text file when the mouse is not being pressed. This causes really ugly jumps in the drawing on playback. What piece of the puzzle am I missing here?

Copy code

void mouseDragged(){
output.println(mouseX + "$" + mouseY); // Write the coordinate to the file
line(mouseX-lRectX,mouseY-rectRy,pmouseX-lRectX,pmouseY-rectRy);
}
void mouseReleased(){
output.println(pmouseX + "$" + pmouseY);
//this didn't work
}

Replies(9)

GoToLoop

Re: Create reader/writer- pause on mouseRelease

6 months ago

You can stop the draw() continuous callback by issuing -> noLoop();

And re-activate it again w/ loop()!

Take a look at this post to see an example of it:

http://forum.processing.org/topic/start-stop-pause-processing

PhiLho

Re: Create reader/writer- pause on mouseRelease

6 months ago

I don't understand your problem: when you release the mouse button, mouseDragged is no longer called, no?
If your problem is that your disconnected lines are connected, you should write something different, indicating a mouse release, that you must interpret when playing back the record.

carabt

Re: Create reader/writer- pause on mouseRelease

6 months ago

Yes, that's the problem- and the question. How to write that break and have the reader then interpret it. Right now, the reader reads this:

Copy code

String[] pieces = split(line,"$");
int x = int(pieces[0]);
int y = int(pieces[1]);
line(x,y,px,py);
px=x;
py=y;

I can't quite get my head around how to make it interpret the break so that it does not connect the lines.

PhiLho

Re: Create reader/writer- pause on mouseRelease

6 months ago

Copy code

void mouseDragged(){
output.println(mouseX + "$" + mouseY); // Write the coordinate to the file
line(mouseX-lRectX,mouseY-rectRy,pmouseX-lRectX,pmouseY-rectRy);
}
void mouseReleased(){
output.println(pmouseX + "#" + pmouseY);
}
// Usage
if (line.contains("#")) {
String[] pieces = split(line,"#");
int x = int(pieces[0]);
int y = int(pieces[1]);
// Memorize but don't draw the line
px=x;
py=y;
} else {
String[] pieces = split(line,"$");
int x = int(pieces[0]);
int y = int(pieces[1]);
line(x,y,px,py);
px=x;
py=y;
}

Actually, you can put the px=x lines after the condition, since they are common to both branches. I leave them as is for better understanding...

carabt

Re: Re: Create reader/writer- pause on mouseRelease

6 months ago

I appreciate the help, and it made sense, but I'm getting the same problem still.

PhiLho

Re: Create reader/writer- pause on mouseRelease

6 months ago

I suggest to show your full code, or, if too long, to make a simplified version of it, illustrating the issue, so we can run it and see what goes wrong.

carabt

Re: Create reader/writer- pause on mouseRelease

6 months ago

I feel like I'm overlooking something obvious here. Help greatly appreciated! The reader is still connecting lines from the last x and y- even when the mouse if not being dragged. That's what I don't want. I think you will see if you run it. Here are the simplified files:

testWriter.pde:

Copy code

PrintWriter output;
void setup(){
size(600,400);
background(255);
output=createWriter("../testData/test.txt");
}
void draw(){
smooth();
}
void mouseDragged(){
output.println(mouseX + "$" + mouseY); // Write the coordinate to the file
line(mouseX,mouseY,pmouseX, pmouseY);
}
void mouseReleased(){
output.println(mouseX + "#" + mouseY);
}
void keyPressed() {
println("output");
output.flush(); // Writes the remaining data to the file
output.close(); // Finishes the file
exit(); // Stops the program
}

testReader:

Copy code

BufferedReader reader;
String line;
int px,py;
void setup(){
size(600,400);
background(255);
reader = createReader("../testData/test.txt");
}
void draw(){
try {
line = reader.readLine();
} catch (IOException e) {
e.printStackTrace();
line = null;
}
if (line == null) {
noLoop();
} else {
if (line.contains("#")){
String[] pieces = split(line,"#");
int x = int(pieces[0]);
int y = int(pieces[1]);
println("Splitting at #");
px=x;
py=y;
//tried deleting, making other way around
}
else{
///problem here. Still draws from the last location
String[] pieces = split(line,"$");
int x = int(pieces[0]);
int y = int(pieces[1]);
line(x,y,px,py);
px=x;
py=y;
}
}
}

PhiLho

Re: Create reader/writer- pause on mouseRelease

6 months ago

OK, I see the problem... Replace mouseReleased() by mousePressed() in the writer.

carabt

Re: Create reader/writer- pause on mouseRelease

6 months ago

AWESOME! THANKS! So simple.

Top Reply