Coordinates out of bounds! ERROR ... with pics on grow

Programming Questions

anorak

Coordinates out of bounds! ERROR ... with pics on grow

in Programming Questions • 6 months ago

Hey people!

I'm trying to draw pictures in a canvas. The pics should grow according to the position of the mouse. When i do this I'm getting an "ArrayIndexOutOfBoundsException: Coordinate out of bounds!" in line 51. If i draw a rectangle instead of a picture it works just fine. I'm new to Processing and i think there is something wrong with my class.
Looking forward to some answers and wish u happy coding!

THX,
Anorak

int a = 3,index,z, Xstart, Ystart;
Pictures[] myArray;
void setup( ) {
size(400, 400);
myArray = new Pictures[a];
PImage img = loadImage("lordhelmchen.jpg");
for (int i = 0; i < 3; i++) {
myArray[index++] = new Pictures(img);
}
}
void draw( ) {
background( 0 );
if(mousePressed == true) {
myArray[z].update(Xstart, Ystart);
myArray[z].draw(Xstart, Ystart);
}
}
void mousePressed( ) {
Xstart = mouseX;
Ystart = mouseY;
}
void mouseReleased( ) {
z++;
}
class Pictures {
PImage img;
int Xstart, Ystart, Xend, Yend, Xb, Yb;
Pictures(PImage pic) {
img = pic;
}
void update(int Xstart, int Ystart) {
Xend = mouseX;
Yend = mouseY;
println("Start " + Xstart + "," + Ystart);
println("End " + Xend + "," + Yend);
}
void draw(int Xstart, int Ystart) {
Xb = (Xstart < Xend)? Xstart : Xend;
Yb = (Ystart < Yend)? Ystart : Yend;
img.resize(abs(Xend - Xstart), abs(Yend - Ystart));
println("BBB " + Xb + "," + Yb);
if (Xstart != Xend && Ystart != Yend) {
image(img, Xb, Yb);
}
//rect(Xstart, Ystart, Xend-Xstart, Yend-Ystart);
}
}

Replies(2)

GoToLoop

Re: Coordinates out of bounds! ERROR ... with pics on grow

6 months ago

Took a lot but spotted the problem!

Method resize() modifies not only the image, but also pixels[] from a PImage!

Seems like Process got some problems w/ drastic fast re-sizings!

My fix was to keep the original PImage and use resize() from a get() of that!

Check it out:

// http://forum.processing.org/topic/coordinates-out-of-bounds-error-with-pics-on-grow

final static byte PICTURES = 3, FPS = 20;
final static Pictures[] myPics = new Pictures[PICTURES];

final static String FILE_NAME = "lordhelmchen.jpg";
final static String ENGINE = P2D; // Use JAVA2D for Processing 2+

int idx;

void setup() {
  size(1280, 800, ENGINE);
  frameRate(FPS);
  noLoop();

  PImage img = loadImage(FILE_NAME);

  for ( int i = 0; i != PICTURES; 
  myPics[i++] = new Pictures(img) );
}

void draw() {
  background(0);
  myPics[idx].redimension();
  for (Pictures pic: myPics)    pic.display();
}

void mousePressed() {
  myPics[idx].update();
}

void mouseDragged() {
  redraw();
}

void mouseReleased() {
  idx = (idx + 1) % PICTURES;
}

final class Pictures {
  final PImage img;
  PImage resized;
  int px, py, mx, my;

  Pictures(PImage pic) {
    img = pic.get();

    update();
    redimension();
  }

  void update() {
    px = mouseX;
    py = mouseY;
  }

  void redimension() {
    mx = mouseX;
    my = mouseY;

    int dx = abs(mx - px), dy = abs(my - py);

    ( resized = img.get() ).resize(dx, dy);
  }

  void display() {
    image( resized, min(mx, px), min(my, py) );
  }
}

anorak

Re: Coordinates out of bounds! ERROR ... with pics on grow

6 months ago

It works very well, you pushed it even further with the nice structure of your code. Thanks a lot! So i can try now to use the Kinect instead of an mouse ;)

Top Reply