ControlP5 - ScrollList on controlWindow in a tab?

zumbaree

ControlP5 - ScrollList on controlWindow in a tab?

in Contributed Library Questions • 2 years ago

Hi.

I'm trying to display a ScrollList in a secondary controlWindow (to have minim input device selection in the setup tab in controlwindow)

For most controllers I don't need to do anything special, once the first tab is assigned to controlWindow

controlP5.tab("camera").moveTo(controlWindow);

all controllers appear nicely on the second screen in the right tab if I invoke moveTo.

Is that a correct way to create tabs in the controlwindow? (question 1)

controlP5.addSlider("cam_X_Pos",-500,500,10,100,300,20).moveTo("camera");

which I believe is pretty amazing so many many thanks for writing such a great library Andreas!

However I can't find a way to do the same for ScrollList

ScrollList mixers = controlP5.addScrollList("Mixers", 10, 30, 475, 280);

because if I just do

mixers.moveTo("camera") -> it doesn't show.

It does show when I do

mixers.moveTo(controlWindow);

but then it's not in the right tab, so I've tried to move it to a secondary window in a different way

mixers.setWindow(controlWindow); - > returns "function does not exist", fair enough

than

controlP5.controller("Mixers").moveTo(controlWindow); -> returns NullPointerException

It it possible to have scrollList in an arbitrary tab in the controlWindow (question 2)

Does it mean I cannot access ScrollLists via controller()? (question 3)

and If i try:

Controller mixers = controlP5.addScrollList("Mixers", 10, 30, 475, 280); - > i get "cannot convert from ScrollList to Controller".

Which is a bit inconsistent as you can do exactly that with sliders

on a side note I was getting also "Controller is ambiguous" when using it with minim.fft but that seems solvable by invoking "controlP5.Controller" instead. Is that a correct ? (question 4)

For the moment I shall proceed having scrollist stuck in the first tab and please let me know if I'm just doing it wrong.

And here's a minimal code showing the issue:

import controlP5.*;
ControlP5 controlP5;
ControlWindow controlWindow;
void setup() {
size(400,400);
frameRate(25);
controlP5 = new ControlP5(this);
controlWindow = controlP5.addControlWindow("controlP5window",100,100,400,200);
controlP5.tab("tab1").moveTo(controlWindow);
controlP5.tab("tab2").moveTo(controlWindow);
Controller mySlider = controlP5.addSlider("sliderValue",0,255,40,40,100,10);
ScrollList mixers = controlP5.addScrollList("Mixers", 10, 30, 475, 280);
mixers.moveTo(controlWindow);
// this doesnt work, is there a different way?
// mixers.moveTo("tab2");
mySlider.moveTo("tab1");
}

Thanks!

Replies(4)

zumbaree

Re: ControlP5 - ScrollList on controlWindow in a tab?

2 years ago

Also, I just tried to run the code from

http://code.compartmental.net/tools/minim/manual-minim/

It throws some red errors

Jan 23, 2011 1:52:57 AM controlP5.ControlBroadcaster printMethodError

SEVERE: An error occured while forwarding a Controller value

to a method in your program. Please check your code for any

possible errors that might occur in this method .

e.g. check for casting errors, possible nullpointers, array overflows ... .

method: controlEvent

exception: java.lang.reflect.InvocationTargetException

                
                 /**
                  * This sketch demonstrates how to use the <code>setOutputMixer</code>
                  * method of <code>Minim</code> in conjunction with the <code>getLineOut</code>
                  * method. By accessing the Mixer objects of Javasound, you can find one that
                  * corresponds to the output mixer of the sound device of your choice. You can
                  * then set this Mixer as the one that should use when creating an AudioOutput for you.
                  * This Mixer will also be used when obtaining outputs for AudioPlayers, AudioSamples,
                  * and any other classes that result in sound being ouput to your speakers.
                  * <p>
                  * This sketch uses controlP5 for the GUI, a user-contributed Processing library.
                  */
                  
                 import ddf.minim.*;
                 // need signals package for SineWave
                 import ddf.minim.signals.*;
                 import controlP5.*;
                 // need to import this so we can use Mixer and Mixer.Info objects
                 import javax.sound.sampled.*;
                  
                 Minim minim;
                 AudioOutput out;
                 // an array of info objects describing all of 
                 // the mixers the AudioSystem has. we'll use
                 // this to populate our gui scroll list and
                 // also to obtain an actual Mixer when the
                 // user clicks on an item in the list.
                 Mixer.Info[] mixerInfo;
                  
                 // a signal for our output
                 SineWave sine;
                  
                 ControlP5 gui;
                  
                 void setup()
                 {
                  size(512, 275);
                  
                  minim = new Minim(this);
                  gui = new ControlP5(this);
                  
                  ScrollList mixers = gui.addScrollList("Mixers", 10, 10, 475, 280);
                  mixers.setLabel("Choose A Mixer");
                  
                  mixerInfo = AudioSystem.getMixerInfo();
                  
                  for(int i = 0; i < mixerInfo.length; i++)
                  {
                  controlP5.Button b = mixers.addItem("item"+i, i);
                  b.setLabel(mixerInfo[i].getName());
                  }
                  
                  sine = new SineWave(220, 0.3, 44100);
                  
                 }
                  
                 void draw()
                 {
                  background(0);
                  
                  //gui.draw();
                  
                  if ( out != null )
                  {
                  stroke(255);
                  // draw the waveforms
                  for(int i = 0; i < out.bufferSize() - 1; i++)
                  {
                  line(i, 50 + out.left.get(i)*50, i+1, 50 + out.left.get(i+1)*50);
                  line(i, 150 + out.right.get(i)*50, i+1, 150 + out.right.get(i+1)*50);
                  }
                  }
                 }
                  
                 public void controlEvent(ControlEvent theEvent)
                 {
                  int mixerIndex = (int)theEvent.controller().value();
                  
                  println("User chose " + theEvent.controller().label());
                  println("Using mixer info " + mixerInfo[mixerIndex].getName());
                  
                  Mixer mixer = AudioSystem.getMixer(mixerInfo[mixerIndex]);
                  
                  minim.setOutputMixer(mixer);
                  
                  if ( out != null )
                  {
                  out.close();
                  }
                  
                  out = minim.getLineOut(Minim.STEREO);
                  
                  if ( out != null )
                  {
                  out.addSignal(sine);
                  }
                 }
                  
                  
                 void stop()
                 {
                  // always close Minim audio classes when you are done with them
                  if ( out != null )
                  {
                  out.close();
                  }
                  minim.stop();
                  
                  super.stop();
                 }

andreas.s..

Re: ControlP5 - ScrollList on controlWindow in a tab?

2 years ago

hi, the error message occurs due to an exception thrown within the controlEvent method. here, in most cases the exception defaults back to an exception caught inside controlP5.ControlBroadcaster. if you try to replace your controlEvent method with the one below you will see the actual exception (i included a comment // added for each line i added to your code):

public void controlEvent(ControlEvent theEvent) {
if(theEvent.isController()) { // added
int mixerIndex = (int)theEvent.controller().value();
println("User chose " + theEvent.controller().label());
println("Using mixer info " + mixerInfo[mixerIndex].getName());
try { // added
Mixer mixer = AudioSystem.getMixer(mixerInfo[mixerIndex]);
minim.setOutputMixer(mixer);
if ( out != null ) {
out.close();
}
out = minim.getLineOut(Minim.STEREO);
if ( out != null ) {
out.addSignal(sine);
}
}
catch(Exception e) { // added
System.err.println(e); // added
} // added
} // added
}

andreas.s..

Re: ControlP5 - ScrollList on controlWindow in a tab?

2 years ago

ScrollList:

the scrollList has been deprecated, better use the ListBox.

ListBox mixers = gui.addListBox("Mixers", 10, 10, 475, 280);

mixers.setLabel("Choose A Mixer");

for(int i = 0; i < mixerInfo.length; i++) {

ListBoxItem b = mixers.addItem("item"+i, i);

b.setText(mixerInfo[i].getName());

}

question 1:

your solution is one way to do it, another one:

controlWindow.addTab("tabtab");

question 2:

yes.

mixers.moveTo(controlWindow, "hello");

question 3:

yes. but you can use

gui.group("Mixers")

elements such as ListBox or MultiList are of type ControlGroup instead of Controller.

question 4:

correct.

so making all these changes, i end up with this:

void setup() {
size(512, 275);
minim = new Minim(this);
gui = new ControlP5(this);
ControlWindow controlWindow = gui.addControlWindow("controlP5window",100,100,400,200);
ListBox mixers = gui.addListBox("Mixers", 10, 30, 380, 280);
mixers.setLabel("Choose A Mixer");
mixerInfo = AudioSystem.getMixerInfo();
for(int i = 0; i < mixerInfo.length; i++) {
ListBoxItem b = mixers.addItem("item"+i, i);
b.setText(mixerInfo[i].getName());
}
mixers.moveTo(controlWindow, "hello");
sine = new SineWave(220, 0.3, 44100);
}
void draw() {}
public void controlEvent(ControlEvent theEvent) {
if(theEvent.isGroup()) { // added, (ListBox is of type ControlGroup)
int mixerIndex = (int)theEvent.group().value();
// println("User chose " + theEvent.group().label()); // doesnt work
println("Using mixer info " + mixerInfo[mixerIndex].getName());
try { // added
Mixer mixer = AudioSystem.getMixer(mixerInfo[mixerIndex]);
minim.setOutputMixer(mixer);
if ( out != null ) {
out.close();
}
out = minim.getLineOut(Minim.STEREO);
if ( out != null ) {
out.addSignal(sine);
}
}
catch(Exception e) { // added
System.err.println(e); // added
} // added
} // added
}

zumbaree

Re: ControlP5 - ScrollList on controlWindow in a tab?

2 years ago

I wasn't aware moveTo accepts two parameters

Thanks a lot for your time !

Top Reply