controlP5 problem

atollax

in Contributed Library Questions • 1 year ago

hi,

I am using controlp5 library for my project to add tabs and sliders, but I confused, because it' not refreshing.

For instance if I move slider, it's previous value left on the screen. The code below it's just a part of my project code, but you clearly can see the problem.

How to solve that problem ?

Thanks for help.

import controlP5.*;
ControlP5 p5;
Slider maxVolume, s, fone_color;
RadioButton playerWave;
void setup(){
p5 = new ControlP5(this);
size(400, 300);
frameRate(30);
smooth();
fone_color = p5.addSlider("fone_color", 0, 255, 67, 200, 80, 10, 100);
playerWave = p5.addRadioButton("Wave", 80, 100);
setDefault(playerWave, "Sine", 1);
addToRadioButton( playerWave , "Triangle", 2);
s = p5.addSlider("slider1", 0, 255, 128, 30, 80, 10, 100);
maxVolume = p5.addSlider("maxVolume", 0, 10, 0.5, 150, 80, 10, 100);
p5.controller("fone_color").moveTo("references");
p5.controller("slider1").moveTo("music");
p5.trigger();
}
void draw(){
}
void addToRadioButton(RadioButton theRadioButton, String theName, int theValue ) {
Toggle t = theRadioButton.addItem(theName, theValue);
t.captionLabel().setVisible(true);
}
void setDefault(RadioButton theRadioButton, String theName, int theValue ) {
Toggle t = theRadioButton.addItem(theName, theValue);
t.captionLabel().setVisible(true);
t.toggle();
}

Replies(5)

amnon.owed

Add a background call to your draw() method to clear the screen. Currently you are not clearing the screen which means you are just aggregately drawing on top of each other. This is not so much related to controlP5, but more a general Processing principle and the way draw() works. Add something like:

background(0);

atollax

Re: controlP5 problem

1 year ago

such an easy solution, thanks :)

PhiLho

Re: controlP5 problem

1 year ago

I wanted to test your code, but my controlP5 was probably too old.
I went to http://www.sojamo.de/libraries/controlP5/ and installed the version 0.7.2 shown there. (Dated 04/09/2012. Wait, we are 27/04/2012, how it can be? Uh, American date format. Confusing...)
It went better, but complained at not being able to convert RadioButton to Toggle. Replaced the latter with the former. It complained about toggle() needing an int. I put 1 there...
It tells me:

ControlP5 0.7.2 infos, comments, questions at http://www.sojamo.de/libraries/controlP5
27 avr. 2012 11:11:12 controlP5.RadioButton toggle
INFO: toggle() not yet implemented, working on it.
java.lang.NoSuchMethodException: sketch_apr27a.Wave(int)
    at java.lang.Class.getMethod(Class.java:1605)
    at controlP5.RadioButton.controlEvent(Unknown Source)
    at controlP5.Controller.broadcast(Unknown Source)
    at controlP5.Toggle.setState(Unknown Source)
    at controlP5.Toggle.setValue(Unknown Source)
    at controlP5.Toggle.setValue(Unknown Source)
    at controlP5.Controller.trigger(Unknown Source)
    at controlP5.ControlP5.trigger(Unknown Source)
    at sketch_apr27a.setup(sketch_apr27a.java:48)
    at processing.core.PApplet.handleDraw(Unknown Source)
    at processing.core.PApplet.run(Unknown Source)
    at java.lang.Thread.run(Thread.java:662)

Looks like I cannot run your code snippet to see the issue.
That said, I have little experience to use controlP5. But I was curious why you don't have any callback for your sliders, or a binding or something. I also haven't found a controller() method in the ControlP5 class...

andreas.s..

Re: controlP5 problem

1 year ago

Hi, I have attached a modified sketch for the given example above for controlP5 0.7.2.

With 0.7.2 I introduced method chaining which I felt is much easier to write/read than having a long list of parameters when adding controllers. Since RadioButton.addItem() returned a reference of an individual toggle of a radiobutton, the return type had to change from Toggle to RadioButton to not break the method chaining.

In general I tried very hard to keep backwards compatibility but had to compromise in some cases, RadioButton.addItem() is one of them. I will prepare a more detailed writeup after I have ironed out the little hiccups that pop up here and there and which I have overseen, so anything you find, please issue here http://code.google.com/p/controlp5/issues/list

Controller Examples included inside folder examples/controllers also come with a list of methods available for each controller as a quick-reference (not including deprecated methods) if one does not feel like browsing through the reference or source code.

I also haven't found a controller() method in the ControlP5 class...

controller() has been deprecated (and is still available in the ControlP5 class) in favor of getter/setters methods, controller(String) is now available as getController(String)

import controlP5.*;
ControlP5 p5;
Slider s, fone_color;
RadioButton playerWave;
// changed type of maxVolume from Slider to float
float maxVolume;
void setup() {
size(400, 300);
p5 = new ControlP5(this);
fone_color = p5.addSlider("fone_color")
.setRange(0, 255)
.setValue(67)
.setPosition(200, 80)
.setSize(10, 100)
;
playerWave = p5.addRadioButton("Wave")
.setPosition(80, 100)
.addItem("Sine",1)
.addItem("Triangle", 2)
.activate("Sine")
;
// access individual toggles from a radiobutton use
Toggle t = playerWave.getItem("Sine");
//t.getCaptionLabel().hide();
s = p5.addSlider("slider1")
.setRange(0, 255)
.setValue(128)
.setPosition(30, 80)
.setSize(10, 100)
;
// here the value of float maxVolume will be
// linked to the value of the slider.
p5.addSlider("maxVolume")
.setRange(0, 10)
.setValue(0.5)
.setPosition(150, 80)
.setSize(10, 100)
;
p5.getController("fone_color").moveTo("references");
p5.getController("slider1").moveTo("music");
}
void draw(){
background(maxVolume*25);
}

PhiLho

Re: controlP5 problem

1 year ago

" controller() has been deprecated (and is still available in the ControlP5 class) in favor of getter/setters methods, controller(String) is now available as getController(String)"
Yes, I was suspecting that since I hadn't errors on it, and that's a good think, I think. It is more standard Java practice. But then again, common Java practice is to make deprecated methods with the @Deprecated annotation and corresponding tag in the JavaDoc, and to keep them in the JavaDoc, as long as they are still available (that's forever for Java, but can be a few versions for libraries, I think).
Just a suggestion...

I see ControlP5 evolved a lot since the last time I had a look (I don't use much GUI controls in my sketches). Good work, Andreas.

Top Reply