ControlP5 pop-up Dialogs

gratefulf..

in Contributed Library Questions • 7 months ago

Hi,

I've finally got my ControlP5 Gui running! Thanks to all the help I got here!

Now I'm looking at the finishing touches: I need to open, save files and was hoping to find file dialogs, or general purpose dialogs.

All I need is a standard file picker and maybe a simple text popup to do some interaction.

Anyone have a suggestion of how to do this in the ControlP5 framework?

Thanks,
Bob

Replies(3)

andreas.s..

Re: ControlP5 pop-up Dialogs

7 months ago

that was a good challenge, here a custom filechooser with controlP5 (using controlP5 2.0.4 and processing 2.0b8).

/* a custom filechooser using controlP5 */
import controlP5.*;
import java.util.*;
ControlP5 cp5;
void setup() {
size(500, 400);
// why do we need post()? see bottom of this sketch
registerMethod("post", this);
cp5 = new ControlP5(this);
addFileChooser();
}
void keyPressed() {
if(key==' ') {
addFileChooser();
}
}
void addFileChooser() {
final Group fc = cp5.addGroup("filechooser")
.setPosition(100, 50)
.setSize(300, 300)
.setBackgroundColor(color(0, 160))
.hideBar();
final Textfield tf = cp5.addTextfield("file")
.setPosition(8, 210)
.setSize(284, 20)
.setGroup("filechooser")
.setColorBackground(color(100))
.setColorForeground(color(100))
;
tf.getCaptionLabel().hide();
final ListBox lb = cp5.addListBox("selectfiles")
.setSize(300, 200)
.setPosition(0, 0)
.setColorBackground(color(120))
.hideBar()
.setStringValue( new File( sketchPath( "" ) ).toString( ) )
.setGroup("filechooser")
// what is this? see bottom of the sketch
.addListener(new ControlListener() {
public void controlEvent(final ControlEvent ev) {
runs.add(new Runnable() {
public void run() {
updateFileChooser( ((ListBox)ev.getGroup( ) ), tf, int( ev.getValue( ) ) );
}
}
);
}
}
)
;
cp5.addButton("save")
.setPosition(7, 240)
.setSize(120, 20)
.setGroup("filechooser")
.setColorBackground(color(100))
.setColorForeground(color(150))
.addListener(new ControlListener() {
public void controlEvent(ControlEvent ev) {
println("now save something to "+
new File( new File( lb.getStringValue() ),
tf.getText() ).toString()
);
}
})
;
cp5.addButton("cancel")
.setPosition(173, 240)
.setSize(120, 20)
.setGroup("filechooser")
.setColorBackground(color(100))
.setColorForeground(color(150))
.addListener(new ControlListener() {
// when cancel is triggered, add a new runnable to
// safely remove the filechooser from controlP5 in
// a post event.
public void controlEvent(ControlEvent ev) {
runs.add(new Runnable() {
public void run() {
fc.remove();
}
}
);
}
})
;
updateFileChooser( lb, tf, 0 );
}
final void updateFileChooser(ListBox lb, Textfield tf, int theValue) {
String s = (lb.getListBoxItems( ).length==0) ? "" : lb.getListBoxItems( )[theValue][0];
File f;
if (s.equals("..") ) {
f = new File( lb.getStringValue( ) ).getParentFile( );
}
else {
f = new File ( new File( lb.getStringValue( ) ), s );
}
if ( f!=null ) {
if (f.isDirectory( ) ) {
String[] strs = f.list( );
lb.clear();
lb.setColorForeground(color(0, 128, 100));
lb.setColorActive(color(0, 210, 150));
int n = 0;
lb.addItem(f.getName(), n++).setColorBackground(color(80));
lb.addItem("..", n++);
for (String s1:strs) {
ListBoxItem item = lb.addItem( s1, n++);
if (new File(f, s1).isDirectory()) {
item.setColorBackground(color(60, 90, 100));
}
}
lb.scroll(0);
lb.setStringValue( f.getAbsolutePath().toString( ) );
}
else if ( theValue != 0 ) {
println("file selected : "+f.getAbsolutePath());
tf.setText(f.getName());
}
}
}
void draw() {
background(200);
noStroke();
fill(0,200,140);
float f = sin(frameCount* 0.01) * 200;
ellipse(width/4, height/2, f , f );
}
// for some controlP5 events we need to handle events after the main draw and
// input events have been executed and completed. For this we use a list to
// store objects of type runnable. Runnable is an interface that implements
// 1 method - run() - and this suits us well here since we only need to
// execute an event once by calling run and then remove it.
// For example, whenever an event of a filechooser's listbox has been triggered, an
// anonymous class oftype Runnable will be added to List 'runs', executed
// once in post() and is then removed.
final ArrayList<Runnable> runs = new ArrayList<Runnable>();
public void post() {
Iterator<Runnable> it = runs.iterator();
while (it.hasNext ()) {
it.next().run();
it.remove();
}
}

gratefulf..

Re: ControlP5 pop-up Dialogs

7 months ago

Wow! Thanks Andreas! I'll have to study this some to understand! My java knowledge is very slim and this is much more complex than I imagined!

Thanks again for your help!

Ciao,
Bob

andreas.s..

Re: ControlP5 pop-up Dialogs

7 months ago

happy studying. In case you are working with processing 2.0b8 you can add the following function to add scroll wheel support for controlP5, thiscan be useful for the listbox here.

// works with 2.0b8 (and higher I suppose in the future)
public void mouseWheelMoved(java.awt.event.MouseWheelEvent e) {
super.mouseWheelMoved(e);
cp5.setMouseWheelRotation(e.getWheelRotation());
}

Top Reply