ControlP5 disable boradcasting (broad)

Contributed Library Questions

clankill3r

ControlP5 disable boradcasting (broad)

in Contributed Library Questions • 1 year ago

In controlP5range.pde there is this part:

// disable boradcasting since setRange and setRangeValues will trigger an event
.setBroadcast(false)

I don't understand why it's set to false, i disabled it and it doesn't harm.

Could someone explain?

all code from controlP5range.pde:

import controlP5.*;
ControlP5 cp5;
int myColorBackground = color(0,0,0);
int colorMin = 100;
int colorMax = 100;
Range range;
void setup() {
size(700,400);
cp5 = new ControlP5(this);
range = cp5.addRange("rangeController")
// disable boradcasting since setRange and setRangeValues will trigger an event
.setBroadcast(false)
.setPosition(50,50)
.setSize(400,40)
.setHandleSize(20)
.setRange(0,255)
.setRangeValues(50,100)
// after the initialization we turn broadcast back on again
.setBroadcast(true)
.setColorForeground(color(255,40))
.setColorBackground(color(255,40))
;
noStroke();
}
void draw() {
background(colorMax);
fill(colorMin);
rect(0,0,width,height/2);
}
void controlEvent(ControlEvent theControlEvent) {
if(theControlEvent.isFrom("rangeController")) {
// min and max values are stored in an array.
// access this array with controller().arrayValue().
// min is at index 0, max is at index 1.
colorMin = int(theControlEvent.getController().getArrayValue(0));
colorMax = int(theControlEvent.getController().getArrayValue(1));
println("range update, done.");
}
}
void keyPressed() {
switch(key) {
case('1'):range.setLowValue(0);break;
case('2'):range.setLowValue(100);break;
case('3'):range.setHighValue(120);break;
case('4'):range.setHighValue(200);break;
case('5'):range.setRangeValues(40,60);break;
}
}

Replies(2)

amnon.owed

Re: ControlP5 disable boradcasting (broad)

1 year ago

Just as the comments say, if broadcasting is true the lines setRange and setRangeValues with send an event to the controlEvent function in line 40. If you remove the broadcasting lines you will notice the difference, because the text from line 47 is printed to your console a few times. If the broadcasting lines are there, you will notice nothing being printed to your console (aka no events are sent).

Now in this sketch this may or may not be a problem, but when working on bigger projects you don't want to trigger events when setting the range at initialization. You only want events when you actually click on the slider. Hence the option and in this example the lines to temporarily turn of broadcasting.

clankill3r

Re: ControlP5 disable boradcasting (broad)

1 year ago

thanks, that explains well.

Top Reply