ControlP5 - controlWindow | controlFrame, ConcurrentModificationError

loops3n

ControlP5 - controlWindow | controlFrame, ConcurrentModificationError

in Contributed Library Questions • 11 months ago

I have a problem creating a controlWindow resp. controlFrame. I'm using controlP5 with Java (Eclipse) and have a main PAplett class where you can do stuff. At the time of creating the main window, a controlWindow is opened where I put all my controls to change the behaviour in my main window. I used controlWindow and everything works but from time to time (maybe every 1 of 10 programmstarts) I get an ConcurrentModificationError while initializing the controlWindow. But I can't explain where it comes from. Both windows open, my main window looks good, my controlWindow is either complete empty or half of the buttons are there (when it's like this, it "ends" every time at the same button!). In the other 9 of 10 starts everything really works properly.

Now I read, that controlWindow shouldn't be used anymore with ControlP5 2.0+. So I wanted to use ControlFrame but don't get the example (http://www.sojamo.de/libraries/controlP5/examples/extra/ControlP5frame/ControlP5frame.pde) working. I created a 2nd class (the ControlFrame) which extends PAplett too like my main window. In my main window I can create an instance of ControlP5 (cp5=new ControlP5(this)). At the exact same line of code in my 2nd window/class I get an NullPointerException.

As I understand controlP5 correctly I have two classes which are both extending from PAplett, both of them creating a new instance of controlP5, where I add all my buttons and stuff from each window respectively. It is possible to run the 2nd window alone (which I don't need) and everything looks/starts fine (it can't work because i need my main window). When I'm starting my program with my main window I do get this NullPointer. Why is that?

The next problem I'm not sure if that has to do with the problem above is, if i use the very new controlP5 library from october I even can't write c5 = new ControlP5(this) in my main window. I instantly get an exception and no window opens.

Replies(1)

andreas.s..

Re: ControlP5 - controlWindow | controlFrame, ConcurrentModificationError

11 months ago

hi, I assume you are using a processing 2.0b3 or higher version and the latest controlp5 (currently 2.0.3)? the example you are linking to works for me as is on osX, processing 2.0b3 and 2.0b5. What configuration are you running?

running the ControlFrame example in OPENGL/P3D mode in 2.0b5 did not run properly therefore I have made changes to the example and have included the sketch below, which I successfully tested on osX with processing 2.0b3 and 2.0b5

regarding the problem you are encountering in your last paragraph, can you confirm that you are using a processing 2.0b3 or higher version? It seems you are running a 1.5.1 or earlier version, if this is the case, do use controlp5 1.5.2 and the ControlWindow example that comes with the library example should just work fine.

// extra control window example when using processing 2.0b3 or higher
import java.awt.Frame;
import controlP5.*;
private ControlP5 cp5;
int def;
void setup() {
size(400, 400,OPENGL);
// here we register the method pre which will be
// called right after setup is finished. this is required
// especially when Working in OPENGL/P3D mode where setup needs
// to finish first before dealing with controlp5 in an extra window.
registerMethod("pre", this);
}
void pre() {
// we only need to call pre() once, so lets remove it here
unregisterMethod("pre", this);
// create a new ControlFrame, all works fine with
// processing 2.0b3 and 2.0b5 on osx
new ControlFrame(this, "extra", 200, 300);
}
void draw() {
background(def);
}
// the ControlFrame class extends PApplet, so we
// are creating a new processing applet inside a
// new frame with a controlP5 object loaded
public class ControlFrame extends PApplet {
int w, h;
int abc = 100;
public void setup() {
size(w, h);
frameRate(25);
cp5 = new ControlP5(this);
cp5.addSlider("abc").setRange(0, 255).setPosition(10, 10);
cp5.addSlider("def").plugTo(parent, "def").setRange(0, 255).setPosition(10, 30);
for(int i=0;i<10;i++) {
cp5.addButton("b"+i).setValue(i).setPosition(10, 50 + i*20);
}
}
public void draw() {
background(abc);
}
public void controlEvent(ControlEvent ce) {
println(ce);
}
private ControlFrame() {
}
public ControlFrame(Object theParent, String theName, int theWidth, int theHeight) {
parent = theParent;
w = theWidth;
h = theHeight;
Frame f = new Frame(theName);
f.add(this);
this.init();
f.setTitle(theName);
f.setSize(w, h);
f.setLocation(100, 100);
f.setResizable(false);
f.setVisible(true);
}
ControlP5 cp5;
Object parent;
}

Top Reply