controlp5 and perspective()

mrweix

in Contributed Library Questions • 2 years ago

Hi I am using the controlp5 GUI in the same window as my graphics. With the help of the controlp5 with Peasycam I could figure out how to make the GUI inresponsive to my Peasycam actions.

Now I want to do the same with perspective().

From what I understand perspective() has nothing to do with peasycam, but does anybody know a similar way to use perspective() (for example change the field of view) only on the graphics part and not on the GUI?

Thanks!

Replies(7)

jeff_g

Re: controlp5 and perspective()

2 years ago

Have you tried setting the perspective twice. Set it one way before your scene, then change it before the GUI. You may need to wrap it in a push / pop matrix with the GUI.

mrweix

Re: Re: controlp5 and perspective()

2 years ago

Yes I tried calling it again once I call my GUI, which reset the whole perspective.

How exactly do I wrap it in a push/pop matrix?

void GUI()
{
currCameraMatrix = new PMatrix3D(g3.camera);
perspective();
camera();
controlP5.draw();
g3.camera = currCameraMatrix;

}

mrweix

Re: controlp5 and perspective()

2 years ago

Alright I understood now how to use pushMatrix and popMatrix, but it doesn't do it. It just resets the whole perspective.

I tried:

void GUI()
{
currCameraMatrix = new PMatrix3D(g3.camera);
pushMatrix();
perspective();
popMatrix();
camera();
controlP5.draw();
g3.camera = currCameraMatrix;

}

jeff_g

Re: controlp5 and perspective()

2 years ago

I'm not sure I understand. Are you trying to change the perspective of the GUI or the scene? I think the perspective gets dropped when you switch to a GUI - perspective applies to size in 3d based on camera distance. Also, I'd use the built in functions cam.beginHUD() & cam.endHUD(), unless you have a particular reason to reset the matrix. This example sets a perspective on the scene, while drawing a gui.

import peasy.*;
PeasyCam cam;
void setup() {
size(200, 200, P3D);
cam = new PeasyCam(this, 100);
cam.setMinimumDistance(50);
cam.setMaximumDistance(500);
}
void draw() {
perspective();
rotateX(-.5);
rotateY(-.5);
background(0);
fill(255, 0, 0);
box(30);
pushMatrix();
translate(0, 0, 20);
fill(0, 0, 255);
box(5);
popMatrix();
cam.beginHUD();
fill(150,150,150,150);
rect(50,50,100,100);
fill(255);
text("GUI", 100,100);
cam.endHUD();
}

mrweix

Re: Re: controlp5 and perspective()

2 years ago

Dear Jeff, thanks alot for your example. There I get it to work, but I am working with ControlP5 and Peasycam.

http://www.sojamo.de/libraries/controlP5/examples/ControlP5withPeasyCam/ControlP5withPeasyCam.pde

To be clear again. I want to change the perspectivity in the scene, and not in the controlp5 GUI as follows

float cameraY = height/2.0;
float fov = PI*(1./2.);
float cameraZ = cameraY / tan(fov / 2.0);
float aspect = float(width)/float(height);   //ratio of width to height
perspective(fov, aspect, cameraZ/100.0, cameraZ*10.0);

If you have any idea how this could work that would be greatly appreciated, but I am guessing it's a too far shot.

Thanks anyways!

jeff_g

Re: controlp5 and perspective()

2 years ago

ControlP5 can work the same way. That example was written before PeasyCam added Hud features. Should work with something like this.

import peasy.*;
import controlP5.*;
import processing.opengl.*;
PeasyCam cam;
ControlP5 controlP5;
int buttonValue = 1;
int myColor = color(255, 0, 0);
void setup() {
size(400, 400, OPENGL);
cam = new PeasyCam(this, 100);
controlP5 = new ControlP5(this);
controlP5.addButton("button", 10, 100, 60, 80, 20).setId(1);
controlP5.addButton("buttonValue", 4, 100, 90, 80, 20).setId(2);
controlP5.setAutoDraw(false);
cam.setMinimumDistance(50);
// cam.setMaximumDistance(500);
}
void draw() {
float cameraY = height/2.0;
float fov = PI*(1./2.);
float cameraZ = cameraY / tan(fov / 2.0);
float aspect = float(width)/float(height); //ratio of width to height
perspective(fov, aspect, cameraZ/100.0, cameraZ*10.0);
rotateX(-.5);
rotateY(-.5);
background(0);
stroke(0);
fill(255, 0, 0);
box(30);
pushMatrix();
translate(0, 0, 20);
fill(0, 0, 255);
box(5);
popMatrix();
gui();
}
void gui() {
float fov = PI/3.0;
float cameraZ = (height/2.0) / tan(fov/2.0);
perspective(fov, float(width)/float(height),
cameraZ/10.0, cameraZ*10.0);
cam.beginHUD();
rectMode(CORNER);
fill(150, 150, 150, 150);
rect(0, 0, 200, 200);
fill(255);
text("GUI", 100, 100);
controlP5.draw();
cam.endHUD();
}
void controlEvent(ControlEvent theEvent) {
println(theEvent.controller().id());
}
void button(float theValue) {
myColor = color(random(255), random(255), random(255));
println("a button event. "+theValue);
}

mrweix

Re: Re: controlp5 and perspective()

2 years ago

Thanks Jeff!

That does the Job perfectly! I actually realized that your previous ideas would have also worked if I had written the perspective() into the draw() not the setup()..... still a newbie at this ;) Thanks alot for your help!

Top Reply