controlling the length of line from x,y to a point which is randomly chosen

cageehv

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

You have to 'normalize' the vector between point A and B...

See:
http://processing.org/tutorials/pvector/

Good luck!

Rolf

amnon.owed

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Processing 2.0 also has methods that return random unit length vectors that can then be multiplied by the range.

Snippet

float range = 50;
PVector e = PVector.random2D();
e.mult(range);
println(e);
println(e.mag());

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Okay!Thanks! I will study up on Pvector. And come back later to report.

Many thanks to both of you.
Clair

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

All right. I'm back. With the good, the bad, and the weird.

Understanding the vector idea was pretty straightforward. I now have exactly what was running before, except that now my coordinates are PVectors. And I learned a lot. BUT, when I tried to exercise any control over what were now obviously vector variables I was thoroughly stumped. I figure 9 hours work on one thing with no glimmer of success, it's time to ask for help again. Here's the code which works as you can see from the screen shot. And problem is described below that.

float x = random(300.0);
float y = random(240.0);
float ex;
float ey;
PVector startline;
PVector endline;
int width = 600;
int height = 480;
float m;
//******************
void setup() {
size(width, height);
randomSeed(0);
background(0);
stroke(255);
frameRate(1);
startline=new PVector(x,y);
}
void draw() {
ex = random(width);
ey = random(height);
endline=new PVector(ex,ey);
println("startline magnitude = " + m);
if ((startline.x > width) || (startline.x < 0)) {
endline.x = endline.x * -1;
}
if ((startline.y > height) || (startline.y < 0)) {
endline.y = endline.y * -1;
}
println("startline.x = " + startline.x + " startline.y = " + startline.y);
println("endline.x = " + endline.x + " endline.y = " + endline.y);
//////////////////////**********************//////////////////////////////////
// m=startline.mag();
// endline.normalize();
// endline.mult(120);
//---------------------------------------------------------------------------
// m=startline.mag();
// startline.normalize();
// startline.mult(120);
//////////////////////**********************//////////////////////////////////
ellipse(startline.x,startline.y,8,8);
line(startline.x,startline.y, endline.x,endline.y);
startline=new PVector(endline.x,endline.y);
}

Whenever I tried to insert any of the functions which I think I need, and want to test, lines are no longer connected or they are connected but bunched along a partial diameter of a circle with the dots seeming to appear in correct spots elsewhere in the box, etc. I simply cannot figure out where these statements should be used. (You can see them in the big commented section.)

I understand that normalize creates a point from which a vector can be extended. And that the mult(120) should make that one point extend along the vector for 120 more points. Nothing vaguely resembling this happens. (I've learned a lot, but obviously not enough!)

Appreciate help, very much.
Clair

asimes

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Perhaps this method of randomly placing a point would be useful: http://processing.org/tutorials/trig/

Say you have a starting point and you know where it is. Then you can use cos() and sin() to pick a direction from that point. After you have a direction you pick a length (radius) and place a point in that direction at that length.

You can use a random range of directions (angles or radians) as well as a random range of lengths if you like. In the code below, the mouse's x position is mapped to a circular motion and the length is randomized:

float initialX, initialY;
void setup() {
size(600, 600);
initialX = width/2;
initialY = height/2;
}
void draw() {
background(255);
ellipse(initialX, initialY, 10, 10);
// Interactive direction based on mouse's x position
float theta = map(mouseX, 0, width, 0, TWO_PI);
// Random length
float randomLength = random(100, 300);
// Use the direction and random length to place a point
float x = initialX+cos(theta)*randomLength;
float y = initialY+sin(theta)*randomLength;
// See it
ellipse(x, y, 10, 10);
line(initialX, initialY, x, y);
}

amnon.owed

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Another code example...

PVector p = new PVector();
void setup() {
size(600, 600);
mousePressed();
stroke(255);
}
void draw() {
if (frameCount % 4 == 0) { filter(BLUR); }
PVector n = PVector.random2D();
n.mult(25);
n.add(p);
line(p.x, p.y, n.x, n.y);
fill(255);
ellipse(n.x, n.y, 5, 5);
p = n;
}
void mousePressed() {
background(0);
p.set(width/2, height/2, 0);
}

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Hi asimes --
I ran your sketch and the one on the trig tutorial page -- and both examples are like all the other examples I've found -- they all maintain a fixed start point. I mucked about with both for the last half hour without any appreciable success. My startpoint needs to become the endpoint of a line just drawn, and once there, I start over with a new random endpoint. Each line starts from the end point of the previous line, going off in a randomly chosen direction.

And, with doing that I never did have any problems. The only problem came when I decided that I wanted my drawn line to be a fixed length each time. And all the examples I've been able find use, as I said a fixed point and they extend from that point in random directions. So, it seems that using a shifting startpoint WITH a fixed line length is nasty!!

Anyway, I will keep messing about because, for artistic reasons I really do want to solve this. Plus it would be a nice thing to know!

Thanks much for introducing me to the trig page, but right now, that is quite far beyond me (A.B.D. in British Lit.!!!)

Cheers

asimes

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

I'm not sure what you mean, you could randomly place a starting point if you wanted to and still use it to place a random endpoint in a random direction. That endpoint could be used as a starting point for the next one. All you would have to keep track of is what the current starting point is (it will be assigned to be the last endpoint every time).

This is actually the same idea as what amnon.owed did. The random2D() is the same concept as using cos() and sin() to pick a direction (but with vectors). The mult(25) is the length (radius) from the starting point. p = n is the same as making the staring point the end point.

Edit: I modified the code to do this below, if the first code made sense then hopefully doing the mental gymnastics to see how this is the same should be easy:

float initialX, initialY, endX, endY;
void setup() {
size(600, 600);
initialX = width/2;
initialY = height/2;
}
void draw() {
ellipse(initialX, initialY, 10, 10);
// Random direction
float theta = random(TWO_PI);
// Random length
float randomLength = random(10, 30);
// Use the direction and length to place a point
endX = initialX+cos(theta)*randomLength;
endY = initialY+sin(theta)*randomLength;
// See it
ellipse(endX, endY, 10, 10);
line(initialX, initialY, endX, endY);
// Set initial point as end point
initialX = endX;
initialY = endY;
}

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

WAHOOOOOOOOO amnon!!

You did it - I wil study this code until it is etched in my brain and also compare it to what I was trying to do, to see where I went wrong --

Thank you so much.

What I find interesting is that I didn't need to use magniture or normalize at all. I'm now going try to understand exactly how mult and add and random2D work. I can't tell you have relieved I am to have something concrete which works that I can break down into pieces.

And, BTW, after I quit working on all of this yesterday, I spent at least an hour on your blog. And have bookmarked it for future investigation.

amnon.owed

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Ok, great. Note for future reference that the same technique can be applied to 3D as well...

Code Example (3D brownian motion)

ArrayList <PVector> points = new ArrayList <PVector> ();
PVector c = new PVector();
void setup() {
size(1280, 720, P3D);
smooth(16);
colorMode(HSB, 500, 100, 100);
points.add( new PVector() );
strokeWeight(1.5);
noFill();
}
void draw() {
background(0);
perspective(PI/3.0, (float) width/height, 1, 1000000);
// interpolated rotating camera aimed at last point
PVector lp = points.get(points.size()-1).get();
lp.mult(0.01);
c.mult(0.99);
c.add( lp );
camera(c.x+sin(frameCount*0.01)*1500, c.y+cos(10+frameCount*0.008)*1500, c.z-1500,
c.x, c.y, c.z,
0, 1, 0);
// colored curved lines
int index=0;
beginShape();
for (PVector p : points) {
stroke((++index+frameCount)%500, 100, 100);
curveVertex(p.x, p.y, p.z);
}
endShape();
// new point at specified range
PVector n = PVector.random3D();
n.mult(100);
n.add(points.get(points.size()-1));
points.add( n );
// if too slow, start removing points
if (frameRate < 55) { points.remove(0); }
}

clair

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Yes, when I read about add it said x,y,z which I knew to be the 3D coordinates and I assumed (bad of me I know to assume anything) that this was a function which took either 2 or 3 parameters.

I'm working now on constraining the little beggars to the box because right now they sometimes go off into the void, never to return. But, this I know I can do!!!

To show you that I can actually get somewhere -- I did this one last year, if you watch it for bit, it gets quite a lot of depth to it:

http://www.vt2k.com/processing/recession.htm

clair

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

an hour later: curse you amnon --

I just wanted to take a break from working so I decided to load your Brownian 3D -- I am no longer happy with my 2D version!!!

I am going to show this to people and take the liberty of saying "my friend amnon made this!".

Processing is not only a language, in the right hands it can be an inspiration -- thank you.

This is one of the most beautiful creations I have seen in Processing.

GoToLoop

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

I've toyed w/ both of them and did some tiny tweaks while trying to study them. Here they are:

// https://forum.processing.org/topic/
// controlling-the-length-of-line-from-x-y-to-a-point-which-is-randomly-chosen

final PVector p = new PVector(), n = new PVector();
final static int DIM = 5, LEN = 30;

void setup() {
  size(1200, 800);
  stroke(-1);
  fill(-1);

  mousePressed();
}

void draw() {
  if ((frameCount & 0xF) == 0)   filter(BLUR);

  PVector.random2D(n).mult(LEN);
  n.add(p);

  line(p.x, p.y, n.x, n.y);
  ellipse(n.x, n.y, DIM, DIM);

  p.set(n);

  frame.setTitle("FPS: " + round(frameRate));
}

void mousePressed() {
  background(0);
  p.set(width>>1, height>>1);
}

/** 
 * Brownian Motion (v2.11)
 * by Ammon.Owed (2013/Aug)
 * mod GoToLoop
 * 
 * http://forum.processing.org/topic/
 * controlling-the-length-of-line-from-x-y-to-a-point-which-is-randomly-chosen
 */

import java.util.Deque;
import java.util.ArrayDeque;

final static int DIM = 100, MAX = 03000, DETAIL = 1000, DEPTH = 2000;
final static int HUE = 0x200, FPS = 60, TOLERANCE = 40, ALIASING = 2;
final static boolean HAS_MAX_LIMIT = true;

final Deque<PVector> points = new ArrayDeque(MAX);
final PVector cam = new PVector(), lp = new PVector();

float canvasRatio;

void setup() {
  size(1000, 700, P3D);
  frameRate(FPS);
  smooth(ALIASING);
  colorMode(HSB, HUE, 1, 1);
  strokeWeight(1.5);
  noFill();

  canvasRatio = (float) width/height;

  points.add(new PVector());

  frameRate = TOLERANCE<<1;
}

void draw() {
  // auxiliary local variables
  final int fc = frameCount, fr = round(frameRate);
  final PVector tmp = new PVector();

  // interpolated rotating camera aimed at last point
  lp.set(points.getLast());
  cam.mult(.99);
  cam.add(PVector.mult(lp, .01, tmp));

  background(0);
  perspective(THIRD_PI, canvasRatio, 1, 1e6);

  camera(cam.x + sin(fc*.01)*DETAIL, cam.y + cos(10 + fc*8e-3)*DETAIL, 
  cam.z - DEPTH, cam.x, cam.y, cam.z, 0, 1, 0);

  // colored curved lines
  int idx = 0;
  beginShape();

  for (PVector p: points) {
    stroke(fc + idx++ & HUE - 1, 1, 1);
    curveVertex(p.x, p.y, p.z);
  }

  endShape();

  if (HAS_MAX_LIMIT) {
    if (fc >= MAX)       points.remove();
  }

  else {
    if (fr < TOLERANCE)  points.remove();
  }

  // new point at specified range
  PVector.random3D(tmp).mult(DIM);
  tmp.add(lp);
  points.add(tmp);


  frame.setTitle("Brownian Motion\t\tFPS: " +fr+ "\t\tSize: " +points.size());
}

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

I can't wait -- I just saw that you had added these but I have to get off for supper and the night.

Will be on them first thing tomorrow -- about 4.a.m.

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Curse the forum -- or rather ZoHo -- I can't believe how long this thing was down!

Anyway -- GoToLoop -- I like the second one best. However, there is much in there which I don't understand (yet). Still, I will experiment with it.

HOWEVER -- and this to all of you -- yesterday my copy of Generative Design arrived. Just as I was thinking about how best to proceed in a directed study of where I want to work in processing. Perfect timing. This is just exactly the book I have been dreaming about.

So, I am saving GoToLoop last code and amnon's 3D for when I can better understand them (and use them!!!).

Thank you all so much!

asimes

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

I had posted some code that was an extension to my first one and does something similar to amnon.owed's 2D code. It was a comment, not a reply, was not sure if you had seen it because you said my first code was easy to follow.

If the first one was easy to follow the extension should be as well, it is just a different way to make a radius of length 1 around a point and then multiply it by a length. The only difference is that it uses cos() and sin() instead of the vector methods.

The advantage of amnon.owed's code has is that it generalizes to 3D more easily and should be a bit faster because it doesn't use trig functions.

clair

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

I have just printed out both amnon's and your second sketch. I'm going to set them aside together to look at when I am more advanced. (However, I needn't set aside their beauty. Yours happens now to be running as I type.)

I will say, at first glance there is much I don't understand. But that is because all of this 3d stuff is I know way beyond me at this point, (my initial post was a beginner's question!) as it should be -- I am right now, working with Generative Design as a program of study, for which it is exceedingly well-suited.

Thanks for jumping in and I look forward to more posts from you in the months ahead.

Cheers,
clair

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

asimes -- thank you -- It has been the weekend here and I had two lengthy appointments and have been away from the keyboard. I am back now and will be hard at it tomorrow morning--investigating everything more thoroughly.

BUT -- I realized -- rather late, that I had a mistake in my link above -- I have two servers vt2k and vt2000. I posted the wrong one. Here is the proper link to my Recession piece:

http://www.vt2k.com/processing/recession.htm

Apologies to all for the 404.

cageehv

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

The link above is still a 404...

Rolf

clair

Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Man - this is nuts! I copied that link from the URL bar.

http://www.vt2k.com/processing/recession.htm

For some reason, not understood by me -- that link tacked on (at the front) my other website -- borderlinegeek.com. I think I just didn't use the chain icon when I stuck it there.

Interesting. BUT now thanks to Rolf -- both are correct and I will go back and correct the orginal one!

Algorithm: take paper towel
                crumple up
                hold in right hand
                raise hand to face
                vigorously wipe egg off
                end

cageehv

Re: Re: controlling the length of line from x,y to a point which is randomly chosen

1 month ago

Love your algorithm! LOL!