constantly resizing ellipse based on distance

Programming Questions

clausneer..

constantly resizing ellipse based on distance

in Programming Questions • 2 years ago

I am trying to write a code that draws an ellipse wherever I click on the screen. This is not a problem. Then I want to add some new functionality to that code.

1. Loop through all pts - if distance is less than x, then connect with line.
2. Loop through all pts - draw ellipse at pts based on closest pt (meaning if new pt inserted rescale already drawn ellipses).

Now, I believe that the issue with function 2 is that I don't know how to make it not measure on itself (making shortest distance = 0.0) ... any ideas? I think it might be the structure that isn't really working.

Thanks in advance,

/Claus

float[] mPosX = new float[0];     // declare array for x pos
float[] mPosY = new float[0];     // declare array for y pos
float[] shortest = new float[0]; // declare array for shortest distance

int n = 0;

void setup() {

// general setup
size(600, 400);
background(255);
smooth();
fill(0, 100, 200, 20);
stroke(0);
strokeWeight(0.25);
ellipseMode(CENTER);
}

void draw() {

if (n > 0) { // making sure the loop will run only when second pt has been clicked
    for (int i = 0; i < n; i++) {
      float[] distance = new float[n]; // loop through each pt
      for (int j = 0; j < n-1; j++) {        // for each pt, loop through all other pts
        distance[j] = dist(mPosX[i], mPosY[i], mPosX[j], mPosY[j]);
        if (distance[j] < 100) {
          line(mPosX[i], mPosY[i], mPosX[j], mPosY[j]);
        }
      }
      distance = sort(distance);
      shortest = append(shortest, distance[0]);
      ellipse(mPosX[i], mPosY[i], shortest[i], shortest[i]);
    }
}
}

void mousePressed() {

// write coordinates to array
mPosX = append(mPosX, mouseX);
mPosY = append(mPosY, mouseY);
//println("x" + n + ": " + mPosX[n]);
//println("y" + n + ": " + mPosY[n]);

// redim counter
n = n+1;
}

Replies(3)

quarks

Re: constantly resizing ellipse based on distance

2 years ago

It is a common problem how to compare each element in the array with every other element in the array and the code below does just that.

I also took the liberty to modify some of the other code for instance you were creating arrays distance and shortest when when all you were interested in was the distance to the nearest point for the ellipse radius. You might need to modify the code somewhat since I didn't fully understand what you meant by

Loop through all pts - draw ellipse at pts based on closest pt (meaning if new pt inserted rescale already drawn ellipses).

void draw() {
float minDist = Float.MAX_VALUE;
int nearestPoint = -1;
float distance = 0;
if (n > 0) { // making sure the loop will run only when second pt has been clicked
for (int i = 0; i < n -1; i++) {
for (int j = i + 1; j < n; j++) { // for each pt, loop through all other pts
distance = dist(mPosX[i], mPosY[i], mPosX[j], mPosY[j]);
if (distance < 100) {
line(mPosX[i], mPosY[i], mPosX[j], mPosY[j]);
if(distance < minDist) {
minDist = distance;
nearestPoint = j; // array index of the nearest point to point[i]
}
}
}
ellipse(mPosX[i], mPosY[i], minDist, minDist);
}
}
}

Hope this helps.

mbraendle

Re: constantly resizing ellipse based on distance

2 years ago

I would take an object-oriented approach and use ArrayList instead of arrays. This also eliminates to run through two nested loops. One just needs to add the edges for the newly created node.

Your problem above with shortest array is that you increase its size in every frame that is drawn.

Here is my proposal:

ArrayList nodes;
ArrayList edges;
void setup() {
// general setup
size(600, 400);
smooth();
ellipseMode(RADIUS);
nodes = new ArrayList();
edges = new ArrayList();
}
void draw() {
background(255);
// draw the nodes
for (int i = 0; i < nodes.size(); i++) {
Node currentNode = (Node) nodes.get(i);
currentNode.display();
}
// draw the edges
for (int i = 0; i < edges.size(); i++) {
Edge currentEdge = (Edge) edges.get(i);
currentEdge.display();
}
}
void mousePressed() {
nodes.add(new Node(mouseX,mouseY));
int num_nodes = nodes.size();
Node new_node = (Node) nodes.get(num_nodes-1);
if (num_nodes > 1) {
for (int i = 0; i < num_nodes - 1; i++) {
Node current_node = (Node) nodes.get(i);
float d = dist(new_node.x,new_node.y, current_node.x, current_node.y);
if (d < 100) {
edges.add(new Edge(new_node, current_node));
float d_compare = new_node.radius + current_node.radius;
if (d < d_compare) {
float r = d/2;
new_node.radius = min(r,new_node.radius);
current_node.radius = min(r,current_node.radius);
}
}
}
}
}
class Node {
float x,y;
float radius;
Node(float x_init, float y_init) {
x = x_init;
y = y_init;
radius = 99999999;
}
void display() {
fill(0, 100, 200, 20);
stroke(0);
strokeWeight(0.25);
if (radius == 99999999) {
ellipse(x,y,0.1,0.1);
} else {
ellipse(x,y,radius,radius);
}
}
}
class Edge {
Node node_start;
Node node_end;
Edge(Node node_start_init, Node node_end_init) {
node_start = node_start_init;
node_end = node_end_init;
}
void display() {
stroke(0);
strokeWeight(0.25);
line(node_start.x, node_start.y, node_end.x, node_end.y);
}
}

clausneer..

Re: constantly resizing ellipse based on distance

2 years ago

Thanks for helping out - I really appreciate it!

The issue of comparing an element in an array with all other elements in an array is something I've been running in to quite a few times, and I never did figure it out, so thank you for addressing that quarks.

And for your object-oriented approach, mbraendle, cheers for that! It is exactly what I was looking for.

This is definitely something I can continue to work on.

Best,
Claus

Top Reply