Consequent Animations

Programming Questions

djsplintz

in Programming Questions • 1 year ago

Hi all, I've been having a reaaally hard time trying to figure this out... so I'm working on a project with many different animations and I'm using the class given in the Processing examples and I've tried to modify it but failed:

boolean display(float xpos, float ypos) {
    if (firstcall == true && frame != 0)
    frame = -1;
    frame = (frame+1) % imageCount;
    if (frame == (imageCount-1))
    {
      image(images[frame], xpos, ypos);
      firstcall = true;
      return true;
    }
    image(images[frame], xpos, ypos);
    firstcall = false;

      return false;
}

The reason I made it return a boolean is to indicate the end of the animation so that I can switch from one animation to the next in my main class but it's still not working. Another issue I'm having is when I cut an animation halfway let's say and I invoke the same command again it starts off where it left last but I need it to start from the first frame again.

Someone please help =/

Replies(5)

maleo

Re: Consequent Animations

1 year ago

how do you invoke the display function? (maybe provide some more code...)

in order for an animation to start from the beginning you need to set firstcall=true; before beginning to call display().

here's a little simplification, too:

boolean display(float xpos, float ypos) {
if (firstcall == true)
frame = -1;
frame = (frame + 1) % imageCount;
image(images[frame], xpos, ypos);
if (frame == (imageCount-1))
{
firstcall = true;
return true;
}
firstcall = false;
return false;
}

djsplintz

Re: Re: Consequent Animations

1 year ago

This is some of the code in my draw() function:

if (currentAction == "pushed")
{
    pushed.display(currentx,currenty);
    if (pushed.display(currentx,currenty))
    currentAction = "getup";
}

As you can see I'm trying to display the 'getup' animation after the 'pushed' is finished.

And as for the firstcall, I already have it as a global variable in the Animation class I'm using and I've set it as true when I declared it

maleo

Re: Consequent Animations

1 year ago

looks alright, but call display() only once:

if (currentAction == "pushed") {
if (pushed.display(currentx,currenty))
currentAction = "getup";
}

please post your Animation class or better the whole sketch if you need more help...

djsplintz

Re: Re: Consequent Animations

1 year ago

EDIT: I tried your suggestion and it surprisingly worked :S Never knew evaluating a boolean that way would actually invoke the display method. Lesson learned :) thanks a ton!

Doing that won't display 'pushed' at all :P   I need it to display the whole pushed animation and then change currentAction to getup which is another animation.

Here is my whole animation class:

class Animation {
PImage[] images;
int imageCount;
int frame;
boolean firstcall = true;

Animation(String imagePrefix, int count) {
    imageCount = count;
    images = new PImage[imageCount];

    for (int i = 0; i < imageCount; i++) {
      String filename = imagePrefix + i + ".png";
      images[i] = loadImage(filename);
    }
}

      boolean display(float xpos, float ypos) {
      if (firstcall == true)
        frame = -1;
      frame = (frame + 1) % imageCount;
      image(images[frame], xpos, ypos);

      if (frame == (imageCount-1))
      {
        firstcall = true;
        return true;
      }
      firstcall = false;
      return false;
    }
}

maleo

Re: Consequent Animations

1 year ago

well you're evaluating a function which returns a boolean. how would it know what to return without actually running the function? :)

here's another more object oriented way of handling a sequence of animations. the sequence is described as an array of Animation objects. an index variable points to the current animation.

there is also a reset() function on the Animation object, in case an animation was stopped prematurely and you want it to start from the beginning.

might be of use to you:

Animation pushed, getup;
Animation[] sequence;
int index = 0;
int currentx = 0;
int currenty = 0;
void setup() {
pushed = new Animation("pushed", 2);
getup = new Animation("getup", 2);
sequence = new Animation[] {pushed, getup};
}
void draw() {
Animation current = sequence[index];
current.display(currentx, currenty);
if (current.isFinished()) index++;
if (index == sequence.length) {
// finished the sequence of animations, wrap around
index = 0;
}
}
class Animation {
PImage[] images;
int imageCount;
int frame = 0;
boolean firstcall = true;
Animation(String imagePrefix, int count) {
imageCount = count;
images = new PImage[imageCount];
for (int i = 0; i < imageCount; i++) {
String filename = imagePrefix + i + ".png";
images[i] = loadImage(filename);
}
}
void display(float xpos, float ypos) {
frame = (frame+1) % imageCount;
image(images[frame], xpos, ypos);
}
boolean isFinished() {
return (frame == imageCount-1);
}
void reset() {
frame = 0;
}
}

Top Reply