connect end to start with interpolation

Programming Questions

clankill3r

connect end to start with interpolation

in Programming Questions • 3 months ago

I would like to connect the start to the end:

There is a center ellipse which is a bit smaller. By me it goes the wrong way around when i try to connect the first to the last.

check void advancedDraw2, it happens there.

For now i just return, disable that.

can someone help?

float centerX, centerY;
ArrayList<Tangible> tangibles = new ArrayList<Tangible>();
void setup() {
size(700, 700);
smooth();
centerX = width/2;
centerY = height/2;
}
// . . . . . . . . . . . . . . . . . . .
void draw() {
background(0);
fill(255);
noStroke();
ellipse(centerX, centerY, 10, 10);
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
ellipse(t.centerX, t.centerY, 15, 15);
}
// simpleDraw();
// advancedDraw();
advancedDraw2();
}
// . . . . . . . . . . . . . . . . . . .
void advancedDraw() {
stroke(255);
if (tangibles.size() >= 2) {
Tangible t1 = null;
Tangible t2 = null;
for (int i = 0; i < tangibles.size()-1; i++) {
t1 = tangibles.get(i);
t2 = tangibles.get(i+1);
//line(t1.centerX, t1.centerY, t2.centerX, t2.centerY);
// radius
float r1 = dist(t1.centerX, t1.centerY, centerX, centerY);
float r2 = dist(t2.centerX, t2.centerY, centerX, centerY);
// steps can be based on difference in angle and radius
// for now use a fixed value
//float angleDifference = t2.angle - t1.angle;
int steps = (int) max(r1, r2);
for(int s = 0; s < steps; s++) {
float t = norm(s, 0, steps);
float r = map(t, 0, 1, r1, r2);
float a = map(t, 0, 1, t1.angle, t2.angle);
float x = cos(a) * r;
float y = sin(a) * r;
ellipse(centerX+x, centerY+y, 3, 3);
//println(y);
}
}
// connect first to last
t1 = tangibles.get(0);
//line(t1.centerX, t1.centerY, t2.centerX, t2.centerY);
}
}
// . . . . . . . . . . . . . . . . . . .
void advancedDraw2() {
stroke(255, 200);
println("----");
if (tangibles.size() >= 2) {
Tangible t1 = null;
Tangible t2 = null;
for (int i = 0; i < tangibles.size(); i++) {
if(i == tangibles.size()-1) {
println("help!");
t1 = tangibles.get(0);
t2 = tangibles.get(i);
// disable for now
return;
}
else {
t1 = tangibles.get(i);
t2 = tangibles.get(i+1);
}
// radius
float r1 = dist(t1.centerX, t1.centerY, centerX, centerY);
float r2 = dist(t2.centerX, t2.centerY, centerX, centerY);
float rDifference = r2 - r1;
float aDifference = t2.angle - t1.angle;
// the larger the radius the more steps we use
int steps = (int) max(r1, r2);
// steps /= 2;
//println("steps: "+steps);
// previous
float px = cos(t1.angle) * r1;
float py = sin(t1.angle) * r1;
for(int s = 0; s <= steps; s++) {
float t = norm(s, 0, steps);
//float r = map(t, 0, 1, r1, r2);
float r = r1 + rDifference * t;
//float a = map(t, 0, 1, t1.angle, t2.angle);
float a = t1.angle + aDifference * t;
float x = cos(a) * r;
float y = sin(a) * r;
line(px + centerX, py + centerY, x + centerX, y + centerY);
px = x;
py = y;
}
}
}
}
// . . . . . . . . . . . . . . . . . . .
void simpleDraw() {
stroke(255);
if (tangibles.size() >= 2) {
Tangible t1 = null;
Tangible t2 = null;
for (int i = 0; i < tangibles.size()-1; i++) {
t1 = tangibles.get(i);
t2 = tangibles.get(i+1);
line(t1.centerX, t1.centerY, t2.centerX, t2.centerY);
}
// connect first to last
t1 = tangibles.get(0);
line(t1.centerX, t1.centerY, t2.centerX, t2.centerY);
}
}
// . . . . . . . . . . . . . . . . . . .
boolean mouseDragged;
void mouseDragged() {
mouseDragged = true;
Tangible closest = closestTangible(mouseX, mouseY);
if (closest != null) {
float d = dist(mouseX, mouseY, closest.centerX, closest.centerY);
if (d < 20) {
closest.centerX = mouseX;
closest.centerY = mouseY;
closest.calculateAngle(centerX, centerY);
sortTangibles();
}
}
}
// . . . . . . . . . . . . . . . . . . .
void mouseReleased() {
if (mouseDragged) {
mouseDragged = false;
return;
}
Tangible closest = closestTangible(mouseX, mouseY);
if (closest == null) {
Tangible t = new Tangible(mouseX, mouseY);
t.calculateAngle(centerX, centerY);
tangibles.add(t);
}
else {
float d = dist(mouseX, mouseY, closest.centerX, closest.centerY);
if (d < 20) {
tangibles.remove(closest);
}
else {
Tangible t = new Tangible(mouseX, mouseY);
t.calculateAngle(centerX, centerY);
tangibles.add(t);
}
}
sortTangibles();
}
// . . . . . . . . . . . . . . . . . . .
void sortTangibles() {
Collections.sort(tangibles, new TangibleComparator());
println();
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
println(t.angle);
}
}
// . . . . . . . . . . . . . . . . . . .
Tangible closestTangible(float x, float y) {
Tangible closest = null;
float closestDist = MAX_FLOAT;
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
float d = dist(t.centerX, t.centerY, x, y);
if (d < closestDist) {
closestDist = d;
closest = t;
}
}
return closest;
}
// . . . . . . . . . . . . . . . . . . .
class Tangible {
float centerX, centerY;
float angle;
Tangible(float centerX, float centerY) {
this.centerX = centerX;
this.centerY = centerY;
}
void calculateAngle(float x, float y) {
angle = atan2(centerY -y, centerX-x);
//angle = atan2(y-centerY, x-centerX);
if (angle < 0) angle += TWO_PI;
}
}
// . . . . . . . . . . . . . . . . . . .
class TangibleComparator implements Comparator<Tangible> {
int compare(Tangible t1, Tangible t2) {
if (t1.angle > t2.angle) {
return 1;
}
else if (t1.angle > t2.angle) {
return -1;
}
return 0;
}
}

Replies(4)

Mushussu

Re: connect end to start with interpolation

3 months ago

I have a solution, try this :

void advancedDraw2() {
stroke(255, 200);
println("----");
if (tangibles.size() >= 2) {
Tangible t1 = null;
Tangible t2 = null;
for (int i = 0; i < tangibles.size(); i++) {
float aDifference;
if (i == tangibles.size()-1) {
println("help!");
t1 = tangibles.get(0);
t2 = tangibles.get(i);
aDifference = t2.angle - t1.angle - TWO_PI;
}
else {
t1 = tangibles.get(i);
t2 = tangibles.get(i+1);
aDifference = t2.angle - t1.angle;
}
// radius
float r1 = dist(t1.centerX, t1.centerY, centerX, centerY);
float r2 = dist(t2.centerX, t2.centerY, centerX, centerY);
float rDifference = r2 - r1;
// the larger the radius the more steps we use
int steps = (int) max(r1, r2);
// steps /= 2;
//println("steps: "+steps);
// previous
float px = cos(t1.angle) * r1;
float py = sin(t1.angle) * r1;
for (int s = 0; s <= steps; s++) {
float t = norm(s, 0, steps);
//float r = map(t, 0, 1, r1, r2);
float r = r1 + rDifference * t;
//float a = map(t, 0, 1, t1.angle, t2.angle);
float a = t1.angle + aDifference * t;
float x = cos(a) * r;
float y = sin(a) * r;
line(px + centerX, py + centerY, x + centerX, y + centerY);
px = x;
py = y;
}
}
}
}

clankill3r

Re: connect end to start with interpolation

3 months ago

thank you so much!

clankill3r

Re: connect end to start with interpolation

3 months ago

I continued on the code and i have a problem in a simular fashion.

I tried multiple things inspired from the solution above but it seems a bit more tricky now.

Run the code and you will get what i mean.

here a image:

float centerX, centerY;
ArrayList<Tangible> tangibles = new ArrayList<Tangible>();
void setup() {
size(700, 700);
smooth();
frameRate(60);
centerX = width/2;
centerY = height/2;
}
// . . . . . . . . . . . . . . . . . . .
void draw() {
background(0);
fill(255);
noStroke();
ellipse(centerX, centerY, 10, 10);
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
ellipse(t.centerX, t.centerY, 15, 15);
}
synthLineDraw();
float a = atan2(mouseY-centerY, mouseX - centerX);
if (a < 0) a += TWO_PI;
//println(a);
pushMatrix();
translate(centerX, centerY);
rotate(a);
line(200, 0, 0, 0);
popMatrix();
Tangible previous = previousTangibleFromAngle(a);
Tangible next = nextTangibleFromAngle(a);
if (previous != null) {
stroke(255, 0, 0);
noFill();
ellipse(previous.centerX, previous.centerY, 25, 25);
stroke(0, 255, 0);
noFill();
ellipse(next.centerX, next.centerY, 25, 25);
float t = norm(a, previous.angle, next.angle);
// radius
float r1, r2;
float rDifference;
if(previous.angle < next.angle) {
r1 = dist(previous.centerX, previous.centerY, centerX, centerY);
r2 = dist(next.centerX, next.centerY, centerX, centerY);
rDifference = r2 - r1;
}
else {
r2 = dist(previous.centerX, previous.centerY, centerX, centerY);
r1 = dist(next.centerX, next.centerY, centerX, centerY);
rDifference = r2 - r1 - TWO_PI;
}
float r = r1 + rDifference * t;
pushMatrix();
translate(centerX, centerY);
rotate(a);
ellipse(r, 0, 10, 10);
popMatrix();
}
fill(255);
text(frameRate, 50, 50);
}
// . . . . . . . . . . . . . . . . . . .
// assumes tangibles are sorted
float interpolatedTangibleRadius(float a, Tangible t1, Tangible t2) {
return -1;
}
// . . . . . . . . . . . . . . . . . . .
// assumes tangibles are sorted
Tangible previousTangibleFromAngle(float a) {
if (tangibles.size() > 0) {
Tangible t = tangibles.get(0);
if (a < t.angle) {
// last one in list
return tangibles.get(tangibles.size()-1);
}
else {
int index = tangibles.size()-1;
do {
t = tangibles.get(index);
index--;
}
while (a < t.angle);
return t;
}
}
return null;
}
// assumes tangibles are sorted
Tangible nextTangibleFromAngle(float a) {
if (tangibles.size() > 0) {
Tangible t = tangibles.get(tangibles.size()-1);
if (a > t.angle) {
// last one in list
return tangibles.get(0);
}
else {
int index = 0;
do {
t = tangibles.get(index);
index++;
}
while (a > t.angle);
return t;
}
}
return null;
}
// . . . . . . . . . . . . . . . . . . .
void synthLineDraw() {
stroke(255, 200);
if (tangibles.size() >= 2) {
Tangible t1 = null;
Tangible t2 = null;
for (int i = 0; i < tangibles.size(); i++) {
float aDifference;
if (i == tangibles.size()-1) {
t1 = tangibles.get(0);
t2 = tangibles.get(i);
aDifference = t2.angle - t1.angle - TWO_PI;
}
else {
t1 = tangibles.get(i);
t2 = tangibles.get(i+1);
aDifference = t2.angle - t1.angle;
}
// radius
float r1 = dist(t1.centerX, t1.centerY, centerX, centerY);
float r2 = dist(t2.centerX, t2.centerY, centerX, centerY);
float rDifference = r2 - r1;
// the larger the radius the more steps we use
int steps = (int) max(r1, r2);
// steps /= 2;
//println("steps: "+steps);
// previous
float px = cos(t1.angle) * r1;
float py = sin(t1.angle) * r1;
for (int s = 0; s <= steps; s++) {
float t = norm(s, 0, steps);
//float r = map(t, 0, 1, r1, r2);
float r = r1 + rDifference * t;
//float a = map(t, 0, 1, t1.angle, t2.angle);
float a = t1.angle + aDifference * t;
float x = cos(a) * r;
float y = sin(a) * r;
line(px + centerX, py + centerY, x + centerX, y + centerY);
px = x;
py = y;
}
}
}
}
boolean mouseDragged;
void mouseDragged() {
mouseDragged = true;
Tangible closest = closestTangible(mouseX, mouseY);
if (closest != null) {
float d = dist(mouseX, mouseY, closest.centerX, closest.centerY);
if (d < 40) {
closest.centerX = mouseX;
closest.centerY = mouseY;
closest.calculateAngle(centerX, centerY);
sortTangibles();
}
}
}
// . . . . . . . . . . . . . . . . . . .
void mouseReleased() {
if (mouseDragged) {
mouseDragged = false;
return;
}
Tangible closest = closestTangible(mouseX, mouseY);
if (closest == null) {
Tangible t = new Tangible(mouseX, mouseY);
t.calculateAngle(centerX, centerY);
tangibles.add(t);
}
else {
float d = dist(mouseX, mouseY, closest.centerX, closest.centerY);
if (d < 20) {
tangibles.remove(closest);
}
else {
Tangible t = new Tangible(mouseX, mouseY);
t.calculateAngle(centerX, centerY);
tangibles.add(t);
}
}
sortTangibles();
}
// . . . . . . . . . . . . . . . . . . .
void sortTangibles() {
Collections.sort(tangibles, new TangibleComparator());
println();
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
println(t.angle);
}
}
// . . . . . . . . . . . . . . . . . . .
Tangible closestTangible(float x, float y) {
Tangible closest = null;
float closestDist = MAX_FLOAT;
for (int i = 0; i < tangibles.size(); i++) {
Tangible t = tangibles.get(i);
float d = dist(t.centerX, t.centerY, x, y);
if (d < closestDist) {
closestDist = d;
closest = t;
}
}
return closest;
}
// . . . . . . . . . . . . . . . . . . .
class Tangible {
float centerX, centerY;
float angle;
Tangible(float centerX, float centerY) {
this.centerX = centerX;
this.centerY = centerY;
}
void calculateAngle(float x, float y) {
angle = atan2(centerY -y, centerX-x);
//angle = atan2(y-centerY, x-centerX);
if (angle < 0) angle += TWO_PI;
}
}
// . . . . . . . . . . . . . . . . . . .
class TangibleComparator implements Comparator<Tangible> {
int compare(Tangible t1, Tangible t2) {
if (t1.angle > t2.angle) {
return 1;
}
else if (t1.angle > t2.angle) {
return -1;
}
return 0;
}
}

clankill3r

Re: connect end to start with interpolation

3 months ago

Here's my solution. It feels a bit long but it works.

I just rotate till the previous one is at TWO_PI and then i make 0 of it.

if(previous.angle < next.angle) {
t = norm(a, previous.angle, next.angle);
}
else {
float angleTillTwoPi = TWO_PI - previous.angle;
float pa = 0;
float na = next.angle + angleTillTwoPi;
float a2;
if(a >= previous.angle) {
a2 = a - previous.angle;
}
else {
a2 = a + angleTillTwoPi;
}
t = norm(a2, pa, na);
}