I've found a post about it:
http://forum.processing.org/topic/how-do-i-make-an-object-disappear-upon-collision

Car Game.pde:

---

/**
 * Car Game {Alternative} (v1.0)
 * by Michael (mtwalworth)
 * modders Chrisir & GoToLoop
 *
 * http://forum.processing.org/topic
 * /how-do-i-make-an-object-disappear-upon-collision
 * 
 * http://www.openprocessing.org/sketch/103128
 */

final static int CAR_W = 70, CAR_H = 40, CAR_S = 10;
final static int GRAPE_W = 10, GRAPE_H = 10, GRAPE_S = 0;
final static int BANANA_W = 10, BANANA_H = 20, BANANA_S = 0;

final static color CAR_C = #0000FF;
final static color GRAPE_C = #F080F0, BANANA_C = #FFFF00;

final static float FPS = 50, BOLD = 2;
final static color BG = -1, FG = 0;

Sprite car, grape, banana;

void setup() {
  size(800, 600);
  frameRate(FPS);
  smooth();

  stroke(FG);
  strokeWeight(BOLD);

  rectMode(CENTER);
  ellipseMode(CENTER);

  car    = createCar();
  grape  = createGrape();
  banana = createBanana();
}

void draw() {
  background(BG);

  car.script();
  grape.script();
  banana.script();

  if (car.checkImmersion(grape))
    grape.resetSprite((int) random(GRAPE_W, width-GRAPE_W), 
    (int) random(GRAPE_H, height-GRAPE_H));

  if (car.checkImmersion(banana))
    banana.resetSprite((int) random(BANANA_W, width-BANANA_W), 
    (int) random(BANANA_H, height-BANANA_H));
}

void keyPressed() {
  final int k = keyCode;

  if (k == ' ' | k == ENTER)            car.setAcceleration( 1);
  else if (k == SHIFT | k == CONTROL)   car.setAcceleration(-1);

  else if (k == 'W' | k == UP)          car.setVertical(-1);
  else if (k == 'S' | k == DOWN)        car.setVertical( 1);

  else if (k == 'A' | k == LEFT)        car.setHorizontal(-1);
  else if (k == 'D' | k == RIGHT)       car.setHorizontal( 1);
}

void keyReleased() {
  final int k = keyCode;

  if (k == ' ' | k == ENTER   && car.a > 0 || 
    k == SHIFT | k == CONTROL && car.a < 0)
    car.setAcceleration(0);

  else if (k == 'W' | k == UP)     car.north = false;
  else if (k == 'S' | k == DOWN)   car.south = false;

  else if (k == 'A' | k == LEFT)   car.west  = false;
  else if (k == 'D' | k == RIGHT)  car.east  = false;
}

Sprite createCar() {
  return new Sprite(width >> 1, height >> 1, 
  CAR_W, CAR_H, CAR_S, CAR_C, false);
}

Sprite createGrape() {
  return new Sprite((int) random(GRAPE_W, width - GRAPE_W), 
  (int) random(GRAPE_H, height - GRAPE_H), 
  GRAPE_W, GRAPE_H, GRAPE_S, GRAPE_C, true);
}

Sprite createBanana() {
  return new Sprite((int) random(BANANA_W, width - BANANA_W), 
  (int) random(BANANA_H, height - BANANA_H), 
  BANANA_W, BANANA_H, BANANA_S, BANANA_C, false);
}

---

Sprite.pde:

---

class Sprite {               // requires rectMode(CENTER); \\
  final static byte ACCEL_FREQ = 20;
  final static byte SPD_MIN = 0, SPD_MAX = 50;

  int x, y;
  byte  w, h, rx, ry, s, a;
  color c;
  boolean isRounded;

  int top, bottom, left, right;
  boolean north, south, west, east;

  Sprite(int xx, int yy, int ww, int hh, 
  int ss, color cc, boolean r) {
    // invokes initialization method:
    setSprite(xx, yy, ww, hh, ss, cc, r);
  }

  void setSprite(int xx, int yy, int ww, int hh, 
  int ss, color cc, boolean r) {
    w = (byte) ww;          // diameter x \\
    h = (byte) hh;          // diameter y \\

    rx = (byte) (ww >> 1);  // radius x \\
    ry = (byte) (hh >> 1);  // radius y \\

    s = (byte) ss;          // speed \\
    c = cc;                 // color \\

    isRounded = r;          // ellipse(true) or rect(false) \\

    resetSprite(xx, yy);    // completes initialization \\
  }

  void resetSprite(int xx, int yy) {
    x = xx;                 // location x \\
    y = yy;                 // location y \\

    setHorizontal(0);
    setVertical(0);
  }

  void setHorizontal(int horizontal) {
    if (horizontal < 0)        west = true;
    else if (horizontal > 0)   east = true;
    else                       west = east = false;
  }

  void setVertical(int vertical) {
    if (vertical < 0)          north = true;
    else if (vertical > 0)     south = true;
    else                       north = south = false;
  }

  void setAcceleration(int accel) {
    a = (byte) (accel == 0? 0 : accel >> 31 | 1);
  }

  void updateSpeed() {
    if (frameCount % ACCEL_FREQ != 0)  return;

    if ((s += a) == SPD_MIN)   s = SPD_MIN + 1;
    else if (s == SPD_MAX)     s = SPD_MAX - 1;
  }

  void moveSprite() {
    if (west)    x -= s;
    if (east)    x += s;
    if (north)   y -= s;
    if (south)   y += s;
  }

  void updateBorders() {
    left   = x - rx;
    right  = x + rx;

    top    = y - ry;
    bottom = y + ry;
  }

  void confineToScreen() {   // invoke updateBorders() 1st! \\
    if (left < 0)               x = rx;
    else if (right >= width)    x = width  - rx - 1;

    if (top < 0)                y = ry;
    else if (bottom >= height)  y = height - ry - 1;
  }

  void displaySprite() {
    fill(c);

    if (isRounded)  ellipse(x, y, w, h);
    else            rect(x, y, w, h);
  }

  boolean checkImmersion(Sprite other) {
    return abs(x - other.x) < abs(rx - other.rx) 
      & abs(y - other.y) < abs(ry - other.ry);
  }

  void script() {
    if (s != 0) {
      updateSpeed();
      moveSprite();
      updateBorders();
      confineToScreen();
    }

    displaySprite();
  }
}

---

Well, this code works when you have different objects in a class; in my sketch I am trying to detect collision within the array from a single object.

In the example I've posted, variables car, grape and banana store object references for the same class Sprite.
It's very easy to modify the code to use a Sprite[] or an ArrayList< Sprite> instead of 3 variables.

In your own code, you got 30 cellOne object references stored in an Array.

Take a look at the method checkImmersion() @ class Sprite.

On 2nd thought, in my example I only care if a car is immersed within a grape or a banana.
But I don't mind if a grape is colliding with a banana . 

So you're gonna need a double for loop, since you need to check 1 cellOne against the other 29.

Here's a close example doing that. Although it's 1D objects checking whether they're near each other.
But it helps to understand what's need to be done for your code. I hope so. 

/** 
 * Moving Dots (v2.25)
 * by Josem.93 (2013/Aug)
 * mod GoToLoop
 * 
 * http://forum.processing.org/topic/interaction-among-objects-in-an-array
 * http://forum.processing.org/topic/gradual-movement-within-a-for-loop
 * 
 * http://studio.processingtogether.com/sp/pad/export/ro.9Kzw4QVZGKeFZ/latest
 */

final static int NUM = 30, FPS = 60;
final static Dot[] dots = new Dot[NUM];

boolean isPaused;

void setup() {
  size(800, 600);
  frameRate(FPS);
  smooth();
  stroke(Dot.COLOUR);
  fill(Dot.COLOUR);

  for (int i = 0; i != NUM; dots[i++] = new Dot());
}

void draw() {
  background(-1);
  for (int i = 0; i != NUM; connectPoints(i++))   dots[i].script();
}

void mousePressed() {
  if (isPaused = !isPaused)   noLoop();
  else                        loop();
}

void keyTyped() {
  mousePressed();
}

final static void connectPoints(int i) {
  for (int z = i+1; z != NUM; z++)
    if ( dots[i].isNear(dots[z]) )   dots[i].drawLine(dots[z]);
}

class Dot {
  final static short DIM = 5, MIN_DIST = 30, MAX_SPD = 5;
  final static color COLOUR = 0100;

  float x, y;
  float spx = random(-MAX_SPD, MAX_SPD);
  float spy = random(-MAX_SPD, MAX_SPD);

  Dot() {
    x = width>>1;
    y = height>>1;
  }

  void script() {
    move();
    display();
  }

  void move() {
    if ((x += spx) > width  | x < 0)  spx *= -1;
    if ((y += spy) > height | y < 0)  spy *= -1;
  }

  void display() {
    ellipse(x, y, DIM, DIM);
  }

  boolean isNear(Dot other) {
    //return dist(x, y, other.x, other.y) < MIN_DIST;
    return sq(other.x - x) + sq(other.y - y) < MIN_DIST*MIN_DIST;
    //return abs(other.x - x) < MIN_DIST && abs(other.y - y) < MIN_DIST;
  }

  void drawLine(Dot other) {
    line(x, y, other.x, other.y);
  }
}

I am receiving a "cannot find symbol" error when trying to implement your revised variation on an object.

Well, your adapted code had some gross errors like a for loop block w/o curly braces for example! 
Also, you're using PVector class, while my example wasn't.

Anyhow, made some clean-ups and it's at least compiling and running:

Main:

---

final static int NUM = 30, FPS = 60;
final static CellOne[] movers = new CellOne[NUM];

final float n = noise(3);

boolean isPaused;

void setup() {
  size(800, 600);

  stroke(0);
  strokeWeight(2);
  fill(0200);

  for (int i = 0; i != NUM; movers[i++] = new CellOne());
}

void draw() {
  for (int i = 0; i != NUM; connectPoints(i++))   movers[i].script();
}

void mousePressed() {
  if (isPaused = !isPaused)   noLoop();
  else                        loop();
}

void keyTyped() {
  mousePressed();
}

final static void connectPoints(int i) {
  for (int z = i+1; z != NUM; z++)
    if ( movers[i].isNear(movers[z]) )   movers[i].drawLine(movers[z]);
}

---

CellOne:

---

class CellOne {
  final static float TOP_SPEED = .9;
  final static short DIM = 060, MIN_DIST = 040;

  final PVector location = new PVector(random(DIM, width-DIM), random(DIM, height-DIM));
  final PVector velocity = new PVector();
  final PVector acceleration = new PVector();

  void script() {
    update();
    checkEdges();
    display();
  }

  void update() {
    PVector.random2D(acceleration).mult(n);

    velocity.add(acceleration);
    velocity.limit(TOP_SPEED);

    location.add(velocity);
  }

  void display() {
    ellipse(location.x, location.y, DIM, DIM);
  }

  void checkEdges() {
    if (location.x > width)   location.x = 0;
    else if (location.x < 0)  location.x = width;

    if (location.y > height)  location.y = 0;
    else if (location.y < 0)  location.y = height;
  }

  boolean isNear(CellOne other) {
    //return dist(x, y, other.x, other.y) < MIN_DIST;

    return sq(other.location.x - location.x) 
      + sq(other.location.y - location.y) < MIN_DIST*MIN_DIST;

    //return abs(other.location.x - location.x) < MIN_DIST 
    //  && abs(other.location.y - location.y) < MIN_DIST;
  }

  void drawLine(CellOne other) {
    line(location.x, location.y, other.location.x, other.location.y);
  }
}

---

Ah, I should have edited the previous reply..because i was working out these kinks 

Im actually receiving an error whenever I set the array to a smaller size; the NUM variable. 

That NUM behaves as a constant literal rather than a variable.
That and the other constants are meant to parametrize the whole program.

If you wanna change the # of CellOne objects,
change the NUM constant and that will reflect throughout the program!

I had; to a value lower than 30, it gives me the error:

Re-tested here. Changed NUM to smaller values, even 1 and 0, and worked the same. No errors.
NUM is bound to movers.length, b/c it's used to determine the # of CellOnes at the Array's creation.
Every place where you have to use movers.length, you can also use NUM.

I guess my issue is when I am trying to detect intersection from two dif. class objects. Implemented a second new class object the same as your code. 

If you're comparing different classes against each other, you gotta specify its data-type in the method parameter:

 void drawLine(CellOne other) {
    line(location.x, location.y, other.location.x, other.location.y);
  }

So, instead of CellOne other, change it to the type of the class you wanna compare CellOne to.

You should post your current attempts since most has been changed for sure.

1st of all, your main tab got wrong curly brace placements. How can you expect that to compile?
2nd, where's the other CellFast class???