Collision detection is acting weird in PJS

sarahgould

Collision detection is acting weird in PJS

in Processing with Other Languages • 4 months ago

I'm working on a little platformer game, and in PJS objects appear to be bouncing off of invisible walls - a behavior that does not appear in Java Mode. I suspect the problem lies in how Javascript is (mis)handling the collision code, but I'm just not seeing it:

Copy code

PVector collisions(PhysicsThing thing) {
PVector force = new PVector(0,0);
Circle c = thing.circ;
for (int i=0; i < segments.size(); i++) {
LineSegment s = (LineSegment) segments.get(i);
if (PVector.dist(s.a, thing.location) < cellSize*2) {
if (collides(c, s)) {
PVector f = normalVector(c, s);
f.mult(0.2);
PVector proj = project(thing.velocity, PVector.sub(s.a, s.b));
proj.mult(0.1);
f.add(proj);
force.add(f);
}
}
}
force.normalize();
force.mult(0.5);
return force;
}
boolean collides(Circle c, LineSegment s) {
return magSq(normalVector(c, s)) < c.radius*c.radius;
}
PVector normalVector(Circle c, LineSegment s) {
PVector seg = PVector.sub(s.b, s.a);
PVector proj = project(PVector.sub(c.location, s.a), seg);
if (PVector.angleBetween(proj, seg) >= 3.14) {
return PVector.sub(c.location, s.a);
} else if (magSq(proj) > magSq(seg)) {
return PVector.sub(c.location, s.b);
} else {
return PVector.sub(c.location, PVector.add(s.a, proj));
}
}
PVector project(PVector v, PVector onto) {
PVector proj = onto.get();
proj.normalize();
proj.mult(PVector.dot(v, proj));
return proj;
}

The full source code is here: https://dl.dropboxusercontent.com/u/61122505/sgould_moe.zip

Replies(3)

sarahgould

Re: Collision detection is acting weird in PJS

4 months ago

So... it works fine when all the line segments involved are orthogonal. When they are even slightly diagonal, however, things collide with them as if the line segments extend beyond the end points. This despite the fact that when these same line segments are drawn on the screen, they don't behave this way. Is this perhaps a problem with the conversion to Javascript or a problem with processing.js itself? (The PVector code looks okay in processing.js, but I'm not a javascript expert.)

sarahgould

Re: Collision detection is acting weird in PJS

4 months ago

I finally figured it out by rewriting each PVector function myself, one by one. The problem is with the way Processing.js handles PVector.angleBetween().

Old version:

Copy code

if (PVector.angleBetween(proj, seg) >= PI)

New version:

Copy code

if (abs(heading2D(proj) - heading2D(seg)) >= PI)

Where:

Copy code

float heading2D(PVector v) {
return atan2(v.y, v.x);
}

So that's why things collided beyond the endpoints of the line segments: angleBetween wasn't returning the value that the sketch needed to determine if the projected point vector was in the same direction or the opposite direction as the line segment vector.