Collision Detection?

Programming Questions

cron12

in Programming Questions • 5 months ago

Hello!

I'm quite new to Processing and i'm just trying to get my head around a few things

Fairly simple question i'm hoping, this is some collision code made by Keith Peters and it's included in the examples under 'bouncing bubbles'. Can anybody simply explain to me in Layman's terms how the collision method works?

class Ball { // creates ball class

float x, y;

float diameter;

float vx = 0; // sets starting velocity of x position of moving ball

float vy = 0; // sets starting velocity of y position of moving ball

int id;

Ball[] others; // stores balls in an array

Ball(float xin, float yin, float din, int idin, Ball[] oin) {

x = xin;

y = yin;

diameter = din;

id = idin;

others = oin;

}

void collide() {

for (int i = id + 1; i < numBalls; i++) {

float dx = others[i].x - x;

float dy = others[i].y - y;

float distance = sqrt(dx*dx + dy*dy);

float minDist = others[i].diameter/2 + diameter/2;

if (distance < minDist) {

float angle = atan2 (dy, dx);

float targetX = x + cos(angle) * minDist;

float targetY = y + sin(angle) * minDist;

float ax = (targetX - others[i].x) * spring;

float ay = (targetY - others[i].y) * spring;

vx -= ax;

vy -= ay;

others[i].vx += ax;

others[i].vy += ay;

}

Any help would be amazing thank you!

Replies(2)

tfguy44

Re: Collision Detection?

5 months ago

void collide() { // Does collisions.
for (int i = id + 1; i < numBalls; i++) { // For all the balls that come after me in the list of balls...
float dx = others[i].x - x; // Determine the change in our x positions.
float dy = others[i].y - y; // Determine the change in our Y positions.
float distance = sqrt(dx*dx + dy*dy); // Find the total distance between our positions.
// The above three lines can be replaced with: "float distance = dist( x, y, others[i].x, others[i].y);", which I think is more readable anyway. dx and dy are used later, however, so determining them now might be alright.
float minDist = others[i].diameter/2 + diameter/2; // Determine how far apart we would have to be to not be colliding, based on our respective radii.
if (distance < minDist) { // If we are closer together that the sum of our radii, we have collided.
float angle = atan2 (dy, dx); // Determine the angle of the vector between our positions.
float targetX = x + cos(angle) * minDist; // Determine the point of collision(?)
float targetY = y + sin(angle) * minDist;
float ax = (targetX - others[i].x) * spring; // Determine the adjustment that this collision will make to our speeds.
float ay = (targetY - others[i].y) * spring;
// The rest is just updating our speeds.
vx -= ax;
vy -= ay;
others[i].vx += ax;
others[i].vy += ay;
}
}

GoToLoop

Re: Collision Detection?

5 months ago

There was a thread about bumping balls very recently:

http://forum.processing.org/topic/bouncing-ball-app-can-anyone-help-me-implement-vectors

And you can play it online too:

http://studio.processingtogether.com/sp/pad/export/ro.91xkuWl51J$Vp/latest

Here's that code:

[EDIT] -> Oh, that was from you too, cron12 !

// http://forum.processing.org/topic/bouncing-ball-app-can-anyone-help-me-implement-vectors
// http://forum.processing.org/topic/collision-detection-29-4-2013

// http://studio.processingtogether.com/sp/pad/export/ro.91xkuWl51J$Vp/latest

final static short NUM_BALLS = 4, DIM = 0200, FPS = 50;
final static Ball[] balls = new Ball[NUM_BALLS];

final static String ENGINE = P2D; // use JAVA2D on Processing 2+

void setup() {
  size (800, 600, ENGINE);
  frameRate(FPS);
  smooth();
  noCursor();
  noStroke();
  fill(Ball.COLOUR);

  balls[0] = new Ball(DIM >> 1, 0);

  for ( int i=1; i!=NUM_BALLS; balls[i] = new Ball(DIM, i++) );
}

void draw() {
  background(0);
  for (Ball b: balls)  b.script();
}

final class Ball {
  float x, y, vx, vy;
  final int diam, rad, id;

  final static float SPRING = .2, FRICTION = -.4;

  final static color TRANSLUCENT = 0xCC << 030;
  final static color COLOUR = 0xFFFFFF | TRANSLUCENT;

  Ball(int d, int ident) {
    diam = d;
    rad  = d >> 1;
    id   = ident;
  }

  void script() {
    update();
    collide();
    display();
  }

  void display() {
    ellipse(x, y, diam, diam);
  }

  void collide() {
    int i = id;
    while (++i != NUM_BALLS) {
      final Ball b = balls[i];

      final float xx = b.x, yy = b.y;
      final float dx = xx - x, dy = yy - y;

      final float distance = sqrt(dx*dx + dy*dy);
      final float minDist  = b.rad + rad;

      if (distance >= minDist)    continue;
      
      final float ang = atan2(dy, dx);
      final float tx = x + cos(ang)*minDist;
      final float ty = y + sin(ang)*minDist;
      final float ax = (tx - xx)*SPRING, ay = (ty - yy)*SPRING;

      vx -= ax;
      vy -= ay;

      b.vx += ax;
      b.vy += ay;
    }
  }

  void update() {
    if (id == 0) {
      x = mouseX;
      y = mouseY;
      return;
    }

    if ( (x += vx) + rad > width ) {
      x = width - rad;
      vx *= FRICTION;
    }
    else if (x - rad < 0) {
      x = rad;
      vx *= FRICTION;
    }

    if ( (y += vy) + rad > height ) {
      y = height - rad;
      vy *= FRICTION;
    }
    else if (y - rad < 0) {
      y = rad;
      vy *= FRICTION;
    }
  }
}

Top Reply