Coding OpenGL & Sunflow

velvetkev..

Re: Coding OpenGL & Sunflow

2 years ago

Hi,

The way I've been doing this is to have the sketch running with the Processing OpenGL renderer as a kind of preview, then when you want to render with SunflowAPIAPI have a separate function to translate it to code that Sunflow understands (using ToxicLibs' TriangleMesh). This is the method suggested by Amnon in the comments of his post. You could comment out the SunflowAPIAPI bits and it would run as a normal Processing sketch.

The main issue I'm having is that the camera doesn't match up correctly- it's flipped horizontally for some reason, and the distance never seems quite right.

Here's a code example: obviously you need to have the sunflowAPIAPI files set up as per Amnon's advice. Also uses PeasyCam and ToxicLibs libraries. Hope that helps.

/*SunflowAPIAPI and OpenGL
Press s to subdivide mesh, r to render through SunflowAPIAPI
*/
import peasy.*;
import processing.opengl.*;
import toxi.geom.*;
import toxi.geom.mesh.subdiv.*;
import toxi.geom.mesh.*;
import toxi.processing.*;
import java.awt.Color;
import com.briansteen.SunflowAPIAPI;
SunflowAPIAPI sunflow ;
ToxiclibsSupport tox;
PeasyCam cam;
float[] vertices;
int[] triangles;
int rad=250;
WETriangleMesh mesh;
void setup() {
size(700, 700, OPENGL);
tox= new ToxiclibsSupport(this);
cam= new PeasyCam(this, 500);
buildMesh();
}
void draw() {
background(255);
fill(255);
strokeWeight(0.5);
stroke(0);
lights();
tox.mesh(mesh, true, 0);
}
void buildMesh() {
mesh=new WETriangleMesh();
toxi.geom.Sphere s;
s=new toxi.geom.Sphere(rad);
s.toMesh(mesh, 15);
}
void render() { //converts the TriangleMesh to the arrays required by SunflowAPIAPI
vertices = mesh.getUniqueVerticesAsArray();
triangles = mesh.getFacesAsArray();
}
void keyPressed() {
if(key=='s') {
SubdivisionStrategy subdiv=new NormalDisplacementSubdivision(0.45f);
mesh.subdivide(subdiv,10);
println("done");
}
if(key=='r') {
render();
rayTrace();
}
}
void rayTrace() {
sunflow = new SunflowAPIAPI();
sunflow.setWidth(width);
sunflow.setHeight(height);
sunflow.setPointLight("myPointLight", new Point3(0, 0, 0), new Color(255, 255, 255));
float[] lookAt= cam.getLookAt();
float[] pos=cam.getPosition();
sunflow.setCameraTarget(lookAt[0], lookAt[1], lookAt[2]);
sunflow.setCameraPosition(pos[0], pos[1], pos[2]);
sunflow.setCameraUp(0, -1, 0);
sunflow.setThinlensCamera("thinLensCamera", 50f, (float)width/height);
sunflow.drawPlane("sky", new Point3(0,-rad*2,0), new Vector3(0,-1,0));
sunflow.setAmbientOcclusionShader("occlusion", new Color(1f, 1f, 1f), new Color(0, 0, 0), 32, 500);
sunflow.drawPlane("ground", new Point3(0,rad,0), new Vector3(0,1,0));
sunflow.drawMesh("myMesh", vertices, triangles);
sunflow.setPathTracingGIEngine(32);
sunflow.render(false, sketchPath + "/"+frameCount+".png");
}

ventai

Re: Coding OpenGL & Sunflow

2 years ago

Hi velvetkevorkian,

Great, thanks a lot for sharing - it's a real help . .

When you say the camera doesn't match up, do you mean with PeasyCam? As I understand it rotates around the object, and the light wouldn't follow the camera.
Also, I noticed that it doesn't really seem to pick up the cam positions properly.

I have got it to render the object though :)

I'd like to work with some primitive objects too - I tried doing the above with a box but it's coming up with a black screen.

Any idea why?

UPDATE: I just removed the code I put up as saw that I was trying to translate during the draw, it's working now. .
- Also, I just did another render, and it seems to be flipping the camera vertically, so something similar to your finding.

______________________
www.systemarray.com

velvetkev..

Re: Coding OpenGL & Sunflow

2 years ago

Hi,

re: black screen when rendering, my best guess would be one of Sunflow's planes is in front of the camera, as the AABB renders fine for me- does it work if you comment out the following?

sunflow.drawPlane("sky", new Point3(0,-rad*2,0), new Vector3(0,-1,0));
sunflow.drawPlane("ground", new Point3(0,rad,0), new Vector3(0,1,0));

Re: the camera, the following should match PeasyCam's position and target with the Sunflow camera, but it's not 100% consistent and I don't know why. I've not even tried matching lighting or materials between renderers.

float[] lookAt= cam.getLookAt();
float[] pos=cam.getPosition();
sunflow.setCameraTarget(lookAt[0], lookAt[1], lookAt[2]);
sunflow.setCameraPosition(pos[0], pos[1], pos[2]);

I should stress that most of this code is basically adapted from Amnon's post, combined with ToxicLibs examples.

Cheers

K

edit to add- ah , I see you've solved the black screen. Cool.

ventai

Re: Coding OpenGL & Sunflow

2 years ago

Yeah I know you mean, it's odd. I remember in the post somewhere Amnon stating that lining up cameras was not easy. Will do further testing with this. .

Another thing I was wondering, was how lines and text get rendered in raytraced output, as with this configuration they don't show at all (via normal processing code).

Any insight(s) welcomed :)

______________________
www.systemarray.com

velvetkev..

Re: Coding OpenGL & Sunflow

2 years ago

Well, they would have to be converted to some kind of format that Sunflow understands (worth having a look at the SunflowAPIAPI Javadoc if you haven't. All the shapes Sunflow "knows" are listed). Lines I guess could be very thin cylinders? Text would probably have to be converted to a mesh somehow, but the technicalities of that are well beyond me at the moment!

Cheers

K

ventai

Re: Coding OpenGL & Sunflow

2 years ago

For sure - it does also seem to have inherited a bunch of text methods from processing.core.PGraphics. Will have a look into this. .

Cheers dude

______________________
www.systemarray.com

amnon.owed

Re: Coding OpenGL & Sunflow

2 years ago

I've found a way to sync up camera's pretty well between opengl and sunflow. The only thing I'm missing is a formula to go from processing's to sunflow's FOV. But it's fairly easy to manually approximate the correct value. Here's a sketch that I used to sync up both. It you actually want to run this particular code you will need to have the necessary libraries, jar's and directories set up correctly. Otherwise, just take the basic idea's from it to implement in your own project.

I'll just fully re-post the two main tabs.

Main program

import processing.opengl.*;
int sceneWidth = 1280; // sketch width
int sceneHeight = 720; // sketch height
color bgcolor = color(0,125,125); // background color
color shapecolor = color(157,200,196); // shape color
boolean saveOn; // toggle saving: globally
float aspect = (float)sceneWidth/sceneHeight;
float cameraFOV = 50; // sunflow camera
float fov = 0.517; // processing perspective
// 10 = 0.098
// 20 = 0.20
// 40 = 0.41
// 50 = 0.517
// 60 = 0.62
// 100 = 1.2
float eyeX = random(-100,100);
float eyeY = random(-100,100);
float eyeZ = random(-100,100);
float targetX = 0;
float targetY = 0;
float targetZ = 0;
float upX = 0;
float upY = 1;
float upZ = 0;
PImage render;
int transparency = 255;
void setup() {
size(sceneWidth,sceneHeight,OPENGL);
myShape = new HE_Mesh(new HEC_Dodecahedron(this).setEdge(4));
myShape.modify(new HEM_Lattice().setDepth(0.5).setWidth(0.5));
}
void draw() {
background(bgcolor);
perspective(fov, aspect, 1, 100000);
camera(eyeX,eyeY,eyeZ, targetX,targetY,targetZ, upX,upY,upZ);
noStroke();
fill(shapecolor);
myShape.drawFaces();
stroke(0);
myShape.drawEdges();
if (saveOn) {
hemeshToSunflow();
sunflow();
render = loadImage(sketchPath + "/output/render-sunflow.png");
transparency = 255;
saveOn = false;
}
if (render != null) {
perspective();
camera();
tint(255, transparency);
image(render,0,0);
}
}
void keyPressed() {
if (key == ' ') {
eyeX = random(-100,100);
eyeY = random(-100,100);
eyeZ = random(-100,100);
}
if (key == 's') { saveOn = true; }
if (key == 'z') { if (transparency > 10) { transparency -= 50; } }
if (key == 'x') { if (transparency < 200) { transparency += 50; } }
if (key == 'c') { if (transparency < 200) { transparency = 255; } else { transparency = 0; } }
}

Conversion to sunflow

import java.awt.Color;
import com.briansteen.SunflowAPIAPI;
import wblut.hemesh.creators.*;
import wblut.hemesh.modifiers.*;
import wblut.hemesh.*;
HE_Mesh myShape;
float [] verticesHemeshOneDim;
int [] facesHemeshOneDim;
void hemeshToSunflow() {
myShape.triangulateFaces();
float [][] verticesHemesh = myShape.getVerticesAsFloat();
verticesHemeshOneDim = new float[verticesHemesh.length * 3];
int [][] facesHemesh = myShape.getFacesAsInt();
facesHemeshOneDim = new int[facesHemesh.length * 3];
int hemeshCounter = 0;
for (int y=0; y<verticesHemesh.length; y++) {
for (int x=0; x<3; x++) {
if (x==0) { verticesHemeshOneDim[hemeshCounter] = verticesHemesh[y][x]; }
else if (x==1) { verticesHemeshOneDim[hemeshCounter] = -verticesHemesh[y][x]; }
else { verticesHemeshOneDim[hemeshCounter] = verticesHemesh[y][x]; }
hemeshCounter++;
}
}
hemeshCounter = 0;
for (int y=0; y<facesHemesh.length; y++) {
for (int x=0; x<3; x++) {
facesHemeshOneDim[hemeshCounter] = facesHemesh[y][x];
hemeshCounter++;
}
}
}
void sunflow() {
SunflowAPIAPI sunflow = new SunflowAPIAPI();
sunflow.setWidth(int(sceneWidth));
sunflow.setHeight(int(sceneHeight));
sunflow.setAaMin(-2); sunflow.setAaMax(0); // preview quality
sunflow.setBackground(0f, 0.5f, 0.5f);
sunflow.setCameraPosition(eyeX,-eyeY,eyeZ);
sunflow.setCameraTarget(targetX,-targetY,targetZ);
sunflow.setCameraUp(upX,upY,upZ);
sunflow.setThinlensCamera("thinLensCamera", cameraFOV, aspect);
sunflow.setAmbientOcclusionShader("myAmbientOcclusionShader", new Color(shapecolor), new Color(0,0,0), 16, 1);
sunflow.drawMesh("myHemesh", verticesHemeshOneDim, facesHemeshOneDim);
sunflow.setAmbientOcclusionEngine(new Color(255), new Color(0), 16, 7.5);
sunflow.render(sketchPath + "/output/render-sunflow.png");
}

ventai

Re: Coding OpenGL & Sunflow

2 years ago

Cheers - that should come in handy. .

It's funny, it seems that the way it's set up it flipping the x-axis with my rendering, I have some sort of system in place but will definately refer back to this.

______________________
www.systemarray.com

ventai

Re: Coding OpenGL & Sunflow

2 years ago

I keep going to design a sketch in OpenGL (P5), with a mind to implement it in Sunflow.

I wanted to be able to translate a mesh object drawn with drawMesh(). It seems that it can rotated and scaled, but not translated, as such.

Re-writing some of the code in SunflowAPIAPI.java just didn't render the shape (see below), I guess this is because the .jar associated with the system does not allow re-writing bits of the wrapper(?)

/**
   * draws a mesh primitive which can be rotated, scaled, and translated
   * @param name individual name of primitive
   * @param vertices Float array with coordinates (like [x0,y0,z0,x1,y1,z1,x2,y2,z2])
   * @param triangles int array connecting the vertices (like [0,1,2])
   * @param size size
   * @param xRotation x rotation
   * @param yRotation y rotation
   * @param zRotation z rotation
   * @param x x position
   * @param y y position
   * @param z z position
   */
public void drawMesh(String name, float[] vertices, int[] triangles, float size, float xRotation, float yRotation, float zRotation, float x, float y, float z) {
    Matrix4 translate = Matrix4.IDENTITY.multiply( Matrix4.translation(x, y, z ));
    Matrix4 scale = Matrix4.IDENTITY.multiply( Matrix4.scale(size, size, size) );
    Matrix4 rotate = Matrix4.IDENTITY
    .multiply( Matrix4.rotateZ(zRotation) )
    .multiply( Matrix4.rotateX(xRotation) )
    .multiply( Matrix4.rotateY(yRotation) );

    Matrix4 m = Matrix4.IDENTITY;
    m = scale.multiply(m);
    m = rotate.multiply(m);
    m = translate.multiply(m);

    sunflow.parameter("points", "point", "vertex", vertices);
    sunflow.parameter("triangles", triangles);

    sunflow.geometry( name, "triangle_mesh" );
    sunflow.parameter( "shaders", currShader);
    if(isModifiers) sunflow.parameter("modifiers", currModifier);
    sunflow.parameter( "transform", m );
    sunflow.instance( name + ".instance", name );
}

______________________
www.systemarray.com

amnon.owed

Re: Coding OpenGL & Sunflow

2 years ago

One of the big advantages is that you can rewrite/add to the wrapper directly from inside the processing pde.

Your code should work. In fact, I also tested it and indeed I can confirm it works. Perhaps there are other issues that make the shape move off your screen, but the translation as such works.

I'm currently working on another project, but at some point I also hope to return to all this. That is to create something in opengl (including camera movements) and then accurately render it in sunflow.

ventai

Re: Coding OpenGL & Sunflow

2 years ago

Well I'll be damned :)

Ok, will go back and have a look at that - thanks for testing!

______________________
www.systemarray.com

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

Hi Amnon & ventai,

I've spent quite some time trying to figure out how to sync the peasy cam and the sunflow cam. But i've had no success so far.

I really can't figure out how they are related.

Seeing Amnon seems to have figured it out, i'd love some insight :)

I've currently been doing it with the following code:

float[] lookAt = cam.getLookAt();

float[] pos = cam.getPosition();

float[] up = cam.getRotations();

sunflow.setCameraTarget(lookAt[0], lookAt[1], lookAt[2]);

sunflow.setCameraPosition(pos[0], pos[1], pos[2]);

sunflow.setCameraUp(up[0],up[1],-up[2]);

Also for some reason, the ground not only appears on the wrong plane (the geometry of the image i posted should be a top view), but also always appears on top of the image instead of, as the ground should be at the bottom. Here again, i copied the code of Amnon.

sunflow.drawPlane("ground", new Point3(0,rad*2,0), new Vector3(0,1,0));

but it doesn't yet give me the results i'm expecting :)

Can any of you help me out here?

amnon.owed

Re: Coding OpenGL & Sunflow

2 years ago

I never got it fully working with Peasycam. If my memory serves me well, the problem with PeasyCam is that it's designed as a camera rotated around a center. Like a camera moving on a sphere and always pointed to the center of the sphere. That might not be exactly it, but it was something like that. This is why cam.getLookAt() and cam.getPosition() do work, because for those there is no difference with Sunflow. However once you start rotating problems arise. Because the cam.getRotations() of PeasyCam is really not the same as the camera rotations of Sunflow. And the difference is not a simple matter of a minus sign, but more fundamental I believe. I could be wrong though.

For full disclosure. Here is some of my flawed PeasyCam code from a year ago...

cameraPosition = cam.getPosition();
cameraLookAt = cam.getLookAt();
cameraRotation = cam.getRotations();
// note: all of this roll stuff isn't working, apparantly I though this could lead to a solution then ;-)
roll = cameraRotation[2];
if (abs(roll) <= HALF_PI) { rollX = roll/(HALF_PI); }
else if (roll < -HALF_PI) { rollX = -2-roll/HALF_PI; }
else { rollX = 2-roll/HALF_PI; }
rollY = (HALF_PI-abs(roll))/HALF_PI;
// all of this does not work
sunflow.setCameraPosition(cameraPosition[0], -cameraPosition[1], cameraPosition[2]);
sunflow.setCameraTarget(cameraLookAt[0], -cameraLookAt[1], cameraLookAt[2]);
sunflow.setCameraUp(rollX,rollY,0); // doesn't work

Anyway, that's why for HemeshGui I moved to a custom movement system (translation, rotation, zoom) which I was able to sync with Sunflow. However I cheated, because the movement of the camera is limited. For example you can't fly through shapes.

Which is where the code example above comes in, my third attempt. Although very basic, it does allow to freely move all around and still be in sync. As mentioned above it still lacks the final formula, so initially needs some manual syncing. Perhaps it's a focal length vs field of view thing. Don't know. It's the closest I got so far.

I still hope to crack this nut one day, however I've been busy working on other things. I feel the last code is almost there but as with most attempts there always seems to be one last missing puzzle piece. One route that I haven't explored yet, but that may be a solution is the statement on the Sunflow wiki that "cameras can also use matrix transforms in place of the eye, target, and up values". There might also be some other remaining possibilities. But right now I'm working on other things.

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

thanks for the quick answer!

I did dig into it a bit deeper and eventually ended up trying to use the Proscene scene & camera library ( http://code.google.com/p/proscene/ ). However it yielded to the same issues as soon as rotations were used.

It seems like the sunflow.camera() is a 4D matrix and is relying on the "native" processing camera() http://processing.org/reference/camera_.html .

However the transformation of the Proscene or the PeasyCam and the P5.camera() have nothing in common. So what needs to be found is a way to convert the peasy/proscene camera movement to the P5 camera(). I have however never played with Matrixes yet so don't really know where to begin.

In case here's a few prints of the camera() 4D Matrix and its relation to the proscene movements. m1, m2, m3, m4 represents the 4 Vectors (?) of the camera() matrix. I'm not a math guys at all and still quite a processing and coding noob, so please excuse any confusing mathematical/coding writing.

after initialization:

SunFlow m0: -1.0; 0.0; 0.0; 0.0

SunFlow m1: 0.0; -1.0; 0.0; 0.0

SunFlow m2: 0.0; 0.0; 1.0; -261.3126

SunFlow m3: 0.0; 0.0; 0.0; 1.0

Sunflow camera:1.0

ProScene orientation: 0.0; 0.0; 0.0

ProScene position: [ 0.0, 0.0, 261.3126 ]

ProScene UpVector: [ 0.0, 1.0, 0.0 ]

After zooming out

SunFlow m0: -1.0; 0.0; 0.0; 0.0

SunFlow m1: 0.0; -1.0; 0.0; 0.0

SunFlow m2: 0.0; 0.0; 1.0; -417.42996

SunFlow m3: 0.0; 0.0; 0.0; 1.0

Sunflow camera:1.0

ProScene orientation: 0.0; 0.0; 0.0

ProScene position: [ 0.0, 0.0, 417.42996 ]

ProScene UpVector: [ 0.0, 1.0, 0.0 ]

After panning: to the left

SunFlow m0: -1.0; 0.0; 0.0; 0.0

SunFlow m1: 0.0; -1.0; 0.0; 0.0

SunFlow m2: 0.0; 0.0; 1.0; -417.42996

SunFlow m3: 0.0; 0.0; 0.0; 1.0

Sunflow camera:1.0

ProScene orientation: 0.0; 0.0; 0.0

ProScene position: [ 0.0, 0.0, 417.42996 ]

ProScene UpVector: [ 0.0, 1.0, 0.0 ]

After rolling to the right (and this is where it gets too messy for me :S ):

SunFlow m0: -0.9836142; -0.0; -0.18028614; 0.0

SunFlow m1: -0.0012854005; -0.9999746; 0.0070129526; 0.0

SunFlow m2: -0.18028156; 0.00712978; 0.98358923; -424.39462

SunFlow m3: 0.0; 0.0; 0.0; 1.0

Sunflow camera:1.0000001

ProScene orientation: 0.0; 0.0; 0.0

ProScene position: [ -76.51052, 3.02584, 417.42996 ]

ProScene UpVector: [ 0.0, 1.0, 0.0 ]

ProScene UpVector: [ 0.0, 1.0, 0.0 ]

I'm leaving for the next week to a place with no internet, but i'll try and follow up on this if time allows and i can find some mathematical help. I suspect there's something much more complex in there that what i first see and that the coders of PeasyCam and Proscene have had to face (or not :P).

amnon.owed

Re: Coding OpenGL & Sunflow

2 years ago

Could you post some runnable code to get the sunflow camera matrix. I'd like to do some matrix comparisons as well.

Also, did you find where to set (instead of get) the sunflow camera using matrices as mentioned on the wiki?

The matrix route, while somewhat unintuitive for manual camera movement seems ideal for automatic syncing.

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

Put this together after my lunch it's a basic scene setup that should help working it out. It creates a scene with a box whose face all have a different color. The key "r" renders the scene and prints the proscene camera settings, as well as the sunflow camera.

You will need the Proscene Library.

Hope this can help.

I just noticed too, that the panning does affect the ground plane position. Which hints its position is maybe absolute. Anyhow here's the code.

import java.awt.Color;
import org.sunflow.math.Point3;
import org.sunflow.math.Vector3;
import anar.Camera;
import processing.core.*;
import toxi.geom.*;
import toxi.gui.*;
import toxi.util.*;
import sunflowapiapi.P5SunflowAPIAPI;
import remixlab.proscene.*;
Scene scene; //proScene setup
P5SunflowAPIAPI sunflow ;
int rad = 250;
//box position
Vec3D loc;
//box dimensions
float boxWidth = 20;
float boxHeight = 20;
float boxDepth =20;
public void setup() {
size(1000, 800, "sunflowapiapi.P5SunflowAPIAPI");
sunflow = (P5SunflowAPIAPI) g;
loc = new Vec3D(0, 0, 0);
// camera
scene = new Scene(this);
}
public void draw() {
background(155);
// center the object
displayBox();
}
public void keyReleased() {
// render hot key // currently only prints the camera matrix and the proscene cam settings
if (key =='r' || key=='R') {
sunflow.setInstantGIEngine(16, 1, (float) 1.0, 1);
sunflow.setWidth(width);
sunflow.setHeight(height);
sunflow.setAaMin(-2); sunflow.setAaMax(0); // preview quality
sunflow.setSunSkyLight("mySunskyLight");
sunflow.resetMatrix();
sunflow.camera(scene.camera().position().x, scene.camera().position().y, scene.camera().position().z,
scene.camera().orientation().x, scene.camera().orientation().y, scene.camera().orientation().z,
scene.camera().upVector().x, -scene.camera().upVector().y, scene.camera().upVector().z); //-y to get the ground at the bottom
sunflow.setThinlensCamera("thinLensCamera", 70f, (float)width/height);
sunflow.setPathTracingGIEngine(8);
sunflow.setBackground(0f, 0.5f, 0.5f);
//environment
sunflow.setPhongShader("groundShader", new Color(240, 240, 240), new Color(255, 255, 255), 2f, 1);
sunflow.drawPlane("ground", new Point3(0, 20, 0), new Vector3(0, -1, 0));
sunflow.render("/Users/Opuswerk/Documents/Processing/SunflowCamResolving/" + "myFooRender.png"); // unComment to render
println("SunFlow m0: "+sunflow.camera.m00+"; "+sunflow.camera.m01+"; "+sunflow.camera.m02+"; "+sunflow.camera.m03);
println("SunFlow m1: "+sunflow.camera.m10+"; "+sunflow.camera.m11+"; "+sunflow.camera.m12+"; "+sunflow.camera.m13);
println("SunFlow m2: "+sunflow.camera.m20+"; "+sunflow.camera.m21+"; "+sunflow.camera.m22+"; "+sunflow.camera.m23);
println("SunFlow m3: "+sunflow.camera.m30+"; "+sunflow.camera.m31+"; "+sunflow.camera.m32+"; "+sunflow.camera.m33);
println("Sunflow camera determinant:"+ sunflow.camera.determinant());
println("ProScene orientation: "+scene.camera().orientation().x+"; "+scene.camera().orientation().y+"; "+scene.camera().orientation().z);
println("ProScene position: "+scene.camera().position());
println("ProScene UpVector: "+scene.camera().upVector());
}
}
public void displayBox() {
pushMatrix();
translate(loc.x, loc.y, loc.z);
// base
beginShape(QUADS);
fill(0,0,0);
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z); //pointb1
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z); //pointb2
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z); //pointb3
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z); //pointb4
// top
fill(0,0,255);
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt1
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt2
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt3
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt4
//front
fill(0,255,0);
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z); //pointb1
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z); //pointb2
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt2
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt1
//back
fill(255,0,0);
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z); //pointb3
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z); //pointb4
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt4
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt3
//left
fill(255,255,0);
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z); //pointb2
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z); //pointb3
vertex(loc.x-boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt3
vertex(loc.x+boxWidth, loc.y-boxDepth, loc.z+boxHeight); //pointt2
//right
fill(0,255,255);
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z); //pointb1
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z); //pointb4
vertex(loc.x-boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt4
vertex(loc.x+boxWidth, loc.y+boxDepth, loc.z+boxHeight); //pointt1
endShape();
popMatrix();
}

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

About setting the camera with the matrix, i'm wondering if it's not this that could do it:

sunflow.camera(eyeX, eyeY, eyeZ, centerX, centerY, centerZ, upX, upY, upZ)

but the 4th part of the 4D matrix is no use in there...

Could very well be this, but i haven't tried it yet:

sunflow.camera.apply(n00, n01, n02, n03, n10, n11, n12, n13, n20, n21, n22, n23, n30, n31, n32, n33)

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

Seems like Luigi De Aloisio figured out how to do it, and along that built a really neat rendering interface based on sunflowAPIAPI that he called easySunflow.

you can grab the early version off here: http://www.nostatic.it/test/sunflow/easySunflow_progress.zip

And here's a video showing it in action.

amnon.owed

Re: Re: Coding OpenGL & Sunflow

2 years ago

Wow this is great work!

Tested it out and it works! I really like the interface as well.

procedura..

Re: Coding OpenGL & Sunflow

2 years ago

Indeed very amazing.

Just started looking at his code as i had to leave the house just after i found about it. Very curious as to how it all works.

ventai

Re: Coding OpenGL & Sunflow

1 year ago

Hey,

Thanks for posting easysunflow - looks like it matches the cameras eh :)

However, can we use other libraries, and / or put our own meshes in there and translate them around?

It looks like the Mesh class might be incomplete. . .

______________________
www.curveaudio.com

cuginocoso

Re: Coding OpenGL & Sunflow

1 year ago

Hi,

did anyone find out yet how Luigi De Aloisio managed to match the camera?

His easySunflow is amazing, but with the lag of mesh building features, youre quite limited in what you can do …

would be very interested if someone managed to extract the camera matching hack ;)

thanks

amnon.owed

Re: Coding OpenGL & Sunflow

1 year ago

When I tested it then, I remember I was under the impression the camera's matched.

However more recently, when doing some tests, it seemed there were still problems with the camera matching.

Have you confirmed that there is in fact a 1:1 match between regular Processing and Sunflow by way of comparing both output images?

cuginocoso

Re: Coding OpenGL & Sunflow

1 year ago

Dont really know but this is looking really good to me

This is the view in easysunflow

this is the rendered image

but even if its not exactly the same, its the best if seen …

Replies(24)

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Re: Coding OpenGL & Sunflow

Statistics

Tags

Actions

Related Posts