class not working as intended

Programming Questions

rhnorskov

class not working as intended

in Programming Questions • 8 months ago

Hello I am trying to create this class, that creates a button and when clicked changes the color of it. But the way I am doing it is not working, can you tell me what is wrong og tell me another way to achieve the same?

Thanks in advance

Button b1 = new Button(1, "Grayscale");
Button b2 = new Button(2, "Grayscale");
void setup()
{
size(500, 350);
textAlign(CENTER, CENTER);
}
void draw() {
b1.display();
b2.display();
}
class Button {
boolean selected = false;
int nr, x, y, w, h;
String name;
Button (int nr, String inName) {
name = inName;
w = 70;
h = 20;
x = nr*(w+10)-w;
y = 350-(h+10);
}
void display() {
if (selected) fill(255, 0, 0);
else fill(150);
rect(x, y, w, h);
fill(0);
text(name, x+(w/2), y+(h/2));
}
void mousePressed() {
if (mouseX > x && mouseX < x+w && mouseY > y && mouseY < y+h && selected == false) {
selected = true;
}
else if (mouseX > x && mouseX < x+w && mouseY > y && mouseY < y+h && selected == true) {
selected = false;
}
}
}

Replies(3)

quarks

Re: class not working as intended

8 months ago

The mousePressed method must outside of any class you create i.e. same as setup and draw. I have done this in the code below and added a method to test whether a point is over the button

Button b1 = new Button(1, "Grayscale");
Button b2 = new Button(2, "Grayscale");
void setup() {
size(500, 350);
textAlign(CENTER, CENTER);
}
void draw() {
b1.display();
b2.display();
}
void mouseClicked() {
b1.overButton(mouseX, mouseY);
b2.overButton(mouseX, mouseY);
}
class Button {
boolean selected = false;
int nr, x, y, w, h;
String name;
Button (int nr, String inName) {
name = inName;
w = 70;
h = 20;
x = nr*(w+10)-w;
y = 350-(h+10);
}
void display() {
if (selected)
fill(255, 0, 0);
else
fill(150);
rect(x, y, w, h);
fill(0);
text(name, x+(w/2), y+(h/2));
}
void overButton(int mx, int my) {
if (mx > x && mx < x+w && my > y && my < y+h)
selected = !selected;
}
}

GoToLoop

Re: class not working as intended

8 months ago

A little late for mine. But here it is anyways:

P.S.: There is some kinda hack to register a callback function inside your own classes!

Button b1, b2;

void setup() {

  size(500, 350);
  noLoop();
  textAlign(CENTER, CENTER);

  b1 = new Button(1, "Btn 1");
  b2 = new Button(2, "Btn 2");
}

void draw() {

  b1.display();
  b2.display();
} 

void mousePressed() {

  if ( b1.clickCheck() || b2.clickCheck() )    redraw();
}

class Button {
  final  int x, y;

  static final short w = 70, ww = w>>1;
  static final short h = 25, hh = h>>1;
  static final short offset = 10;

  static final color colOn  = #FF0000;
  static final color colOff = 150;

  final  String name;
  boolean isSelected;

  Button (int nr, String inName) {
    name = inName;
    x = nr*(w + offset) - w;
    y = height - h - offset;
  }

  void display() {

    fill(isSelected? colOn:colOff);
    rect(x, y, w, h);
    
    fill(0);
    text(name, x+ww, y+hh);
  }

  boolean clickCheck() {

    if (mouseX > x && mouseX < x+w && mouseY > y && mouseY < y+h) {
      isSelected = !isSelected;
      return true;
    }

    return false;
  }
}

rhnorskov

Re: class not working as intended

8 months ago

Thank you very much both of you :)

Top Reply