The method is sound but there are some rules to be followed when using arc().

There are a several things that might cause the arc not to be drawn

• the angles must be specified in a clockwise direction (i.e. start --> end)
• the start angle must be numerically less than the end angle
• atan2() does not map 0-360 degrees to 0-TWO_PI so can't use this value to compare angles
• there are problems when the segement crosses over the 0 degree position

Rather that use arc() directly it is better to create your own method that resolves all these issues before calling arc. I have modified your code to demonstrate what I mean.

1. int xa = 200;
2. int ya = 200;
3. int xb = 300;
4. int yb = 200;
5. int xc = 200;
6. int yc = 300;
7. float angle_ab, angle_ac, rad;
8. 
   
9. void setup() {
10.   size(600, 600);
11.   angle_ab = atan2(yb - ya, xb - xa);
12.   angle_ac = atan2(yc - ya, xc - xa);
13.   rad = dist(xa, ya, xb, yb);
14. }
15. void draw() {
16.   ellipse(xa, ya, 5, 5);
17.   ellipse(xb, yb, 5, 5);
18.   ellipse(xc, yc, 5, 5);
19.   drawArc(xa, ya, rad, angle_ac, angle_ab);
20. }
21. 
    
22. /**
23.  Draws an arc centered about [centerX, centerY] with the specified
24.  radius between the angles sAng and eAng in a clockwise direction.
25.  Note that 0 (zero) degrees corresponds to the direction east,
26.  90 degrees = south and so on.
27.  */
28. void drawArc(float centerX, float centerY, float radius, float sAng, float eAng) {
29.   // First map the angles to 0 - 2PI
30.   if (sAng < 0) sAng += TWO_PI;
31.   if (eAng < 0) eAng += TWO_PI;
32.   // Now make sure start < end
33.   if (eAng < sAng) eAng += TWO_PI;
34.   arc(centerX, centerY, 2 * radius, 2 * radius, sAng, eAng);
35. }