All right, there are different ways a user could draw a circle in Processing. For example, a user could click somewhere for the center and then drag out the radius. Then you would have the exact center and radius, but I'm guessing that would be to easy for your task?

I'm assuming the user draws as if she would do on paper, meaning she will draw the outline of the circle. In that case it will be a little more challenging. However, one way would be to collect all the mouse points and then average them for the center point. After that you can calculate the radius by taking the average distance from all points to the center. This of course assumes the user does the following: click, draw a circle, release. Below is a basic example of this technique.

Code Example

1. ArrayList <PVector> points = new ArrayList <PVector> ();
2.  
3. void setup() {
4.   size(500, 500);
5.   background(255);
6.   noStroke();
7.   smooth();
8. }
9.  
10. void draw() {
11.   fill(0);
12.   if (mousePressed) {
13.     ellipse(mouseX, mouseY, 5, 5);
14.     points.add(new PVector(mouseX, mouseY));
15.   }
16. }
17.  
18. void mouseReleased() {
19.   PVector center = new PVector();
20.   for (PVector p : points) {
21.     center.add(p);
22.   }
23.   center.div(points.size());
24.   float radius = 0;
25.   for (PVector p : points) {
26.     radius += center.dist(p);
27.   }
28.   radius /= points.size() * 0.5;
29.   points.clear();
30.   fill(255, 0, 0, 125);
31.   ellipse(center.x, center.y, radius, radius);
32. }