Choosing a random integer, but not the same as previous

General Discussion Other

kingdrago..

Choosing a random integer, but not the same as previous

in General Discussion • Other • 8 months ago

Hi there,

I am trying to work out a way I can choose a random integer between 0 and 10, but not roll the same number as the previous roll. So:

the first roll, it would choose any number between the specified range - say I roll a 5.

the second time, it would choose an integer within the boundaries, but excluding the previous number - say I roll a 9.

the next roll, again it would be within 0 and 10, but only 9 is now excluded, 5 is put back in the available numbers - and for example purposes, I roll a 5.

and so on...

Any help would be greatly appreciated :)

KingD.

Also, if I'm being a bit vague, ask and I'll explain further :)

Replies(5)

GoToLoop

Re: Choosing a random integer, but not the same as previous

8 months ago

So, why don't you create a variable to store the previous picked number?
And keep re-rolling until the result is different from that variable?

Here's an example for ya:

final byte numRolls = 10, numMax = 10;

for (int i=0, newPick, oldPick=-1; i!=numRolls; ++i) {

  do    newPick = round( random(numMax) );
  while (newPick == oldPick);

  print( (oldPick = newPick) + "\t" );
}

exit();

GoToLoop

Re: Choosing a random integer, but not the same as previous

8 months ago

An alternative version using an array to store all picked up rolls:

P.S.: This version has no curly brackets!

final byte numRolls = 10, numMax = 10;
final int[] rolls = new int[numRolls];

rolls[0] = round( random(numMax) );

for (int i=1; i!=numRolls; ++i)
  do    rolls[i] = round( random(numMax) );
  while ( rolls[i] == rolls[i-1] );

println(rolls);
exit();

GoToLoop

Re: Choosing a random integer, but not the same as previous

8 months ago

On 3rd thought, same as previous 1, but instead of do-while block, using just while:

final byte numRolls = 10, numMax = 10;
final int[] rolls = new int[numRolls];

rolls[0] = round( random(numMax) );

for (int i=1; i!=numRolls; ++i)
  while ( ( rolls[i] = round(random(numMax)) ) == rolls[i-1] );

println(rolls);
exit();

asimes

Re: Choosing a random integer, but not the same as previous

8 months ago

Here is a method with no loop, the idea is to move the most recently picked number to the end of the array and only randomly choose among the other numbers. That way the same number cannot be picked:

int[] numbers = new int[10];
void setup() {
size(100, 100);
for (int i = 0; i < numbers.length; i++) numbers[i] = i;
// Call this once so that 9 can be an option the first time
int rand = (int)random(numbers.length-1);
randomSwap(rand);
println("Random number moved to last position "+rand);
println(numbers);
}
void draw() {
}
void mousePressed() {
int rand = (int)random(numbers.length-1);
println("Picked "+numbers[rand]);
randomSwap(rand);
}
void randomSwap(int in) {
int nMinusOne = numbers.length-1;
// Move some number to position n-1, away from random choice
int swap = numbers[in];
numbers[in] = numbers[nMinusOne];
numbers[nMinusOne] = swap;
}

kingdrago..

Re: Choosing a random integer, but not the same as previous

8 months ago

Thank-you very much for your help you two.

I'll experiment now with each of the examples to see which one offers more flexibility for if I need to add anything else at a later date.

Thanks again,

KingD.

Top Reply