Do you already have the arduino-code to find out, which spots are free/occupied? Then i would sen serial-messages to processing whenever the state of one spot changes.
Then in processing, i would create a ParkingSpot-class, that stores the position and dimensions of the box and state of the spot(free/occupied). When a serial-message is recieved, change the state of the array-position, which belongs to the specific parking-spot. The color of the boxes could then just be a conditional fill(). Here is an example with mouseclicks, because i don't know how you send the data from arduino:

1. ParkingSpot[] spots;
   
   void setup() {
     size(400, 100);
    
     // create an array of ParkingSpot-objects
     spots = new ParkingSpot[18];
    
     // fill the array with ParkingSpots
     for (int i =0; i< spots.length; i++) {
       spots[i] = new ParkingSpot(20 + i*20, 20, 15, 20, true);
     }
   }
   
   void draw() {
     // lopp over all parking-spots and display them
     for (int i =0; i < spots.length; i++) {
       spots[i].display();
     }
   }
   
   // just an example with mouse-clicks, since i don't know, how you send the serial-data
   void mousePressed() {
     // check if mouse was over one of the spots and toggle between free and occupied
     for (int i =0; i< spots.length; i++) {
       if (mouseX> spots[i].x && mouseX<spots[i].x+spots[i].w && mouseY> spots[i].y && mouseY<spots[i].y+spots[i].h) {
         spots[i].free = !spots[i].free;
         break;
       }
     }
   }
   
   /*
   x : x-position
   y: y-position
   w: width of the rectangle
   h: height of the rectangle
   free: "true" if the spot is free
   */
   class ParkingSpot {
     float x, y, w, h;
     boolean free;
   
     ParkingSpot(float x, float y, float w, float h, boolean free) {
       this.x = x;
       this.y = y;
       this.w = w;
       this.h = h;
       this.free = free;
     }
   
     void display() {
       // green color, if box is free
       if (free)
         fill(0, 255, 0);
       // red color, if not
       else
         fill(255, 0, 0);
   
       // draw rectangle
       rect(x, y, w, h);
     }
   }
   

I think the challenging part is to find out what spots are free. I mean does motion on a certain sensor mean, that a car just left? Or did it arrive? Or did the driver forget his wallet?
The visual part of displaying the information is pretty easy compared to this. You could send a serial message whenever a spot gets free/occupied. For example two numbers where the first indicates the number of the parking-spot, and the second tells the current state. (e.g. "12 1" means spot number 12 is free).
If you need help with the arduino part, please show your arduino-code.

In processing you could just add a serialEvent() function, that handles the message, an example:

1. void serialEvent(Serial p) {
     // get message till line break (ASCII > 13)
     String message = p.readStringUntil(13);
     //check if there is a message
     if (message != null) {
       // split the message into its parts
       String[] elements = splitTokens(message);
       // check if the message has two values as expected
       if (elements.length == 2) {
         // parse the first message (spot-number)
         int spot = int(elements[0]);
         // set a parking-spot to free if the second value is "1"
         if (int(elements[1]) == 1)
           spots[spot].free = true;
         else
           spots[spot].free = false;
       }
     }
   }
   

I don't think, that it would be a problem if you use code-snippets from other people in you thesis. I would prefer to answer through the forum, so others can learn from the code.
But if your are concerned about that, you can send me a private message through the forum.