/** 
 * Color String (v1.61)
 * by GoToLoop (2013/Sep)
 * 
 * http://forum.processing.org/topic/
 * changing-color-of-the-next-character-in-a-string-typewritter-stuff
 */

final class ColorString {
  final StringBuilder chars = new StringBuilder();
  final IntList colors = new IntList();

  private int size;
  color ink;

  /////////// append \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  ColorString append(char ch) {
    chars.append(ch);
    colors.append(ink);

    ++size;
    return this;
  }

  ColorString append(char ch, color c) {
    ink = c;
    return append(ch);
  }

  ColorString append(String str) {
    final int len = str.length();
    if (len == 0)   return null;

    chars.append(str);
    colors.append(oneColorArray(len, ink));

    size += len;
    return this;
  }

  ColorString append(String str, color c) {
    ink = c;
    return append(str);
  }

  /////////// insert \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  ColorString insert(int idx, char ch) {
    chars.insert(idx, ch);
    insertColor(idx, ink);

    ++size;
    return this;
  }

  ColorString insert(int idx, char ch, color c) {
    ink = c;
    return insert(idx, ch);
  }

  ColorString insert(int idx, String str) {
    final int len = str.length();
    if (len == 0)   return null;

    chars.insert(idx, str);
    insertColor(idx, oneColorArray(len, ink));

    size += len;
    return this;
  }

  ColorString insert(int idx, String str, color c) {
    ink = c;
    return insert(idx, str);
  }

  //////////// insertColor \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  private void insertColor(int idx, color c) {
    insertColor(idx, oneColorArray(1, c));
  }

  private void insertColor(int idx, color[] c) {
    final color[] arr = splice(colors.array(), c, idx);

    colors.clear();
    colors.append(arr);
  }

  /////// oneColorArray \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  color[] oneColorArray(int elems, color c) {
    final color[] arr = new color[elems];

    for (int i = 0; i != elems; arr[i++] = c);

    return arr;
  }

  /////////// set \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  ColorString set(int idx, char ch) {
    chars.setCharAt(idx, ch);

    return this;
  }

  ColorString set(int idx, color c) {
    colors.set(idx, ink = c);

    return this;
  }

  ColorString set(int idx, char ch, color c) {
    return set(idx, ch).set(idx, c);
  }

  /////////// remove \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  ColorString remove() {
    return remove(size - 1);
  }

  ColorString remove(int idx) {
    if (size == 0)   return null;

    chars.deleteCharAt(idx);
    colors.remove(idx);

    --size;
    return this;
  }

  //// charAt \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  char charAt(int idx) {
    return chars.charAt(idx);
  }

  ///// colorAt \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  color colorAt(int idx) {
    return colors.get(idx);
  }

  //// clear \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  void clear() {
    chars.setLength(size = 0);
    colors.clear();
  }

  /// size \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  int size() {
    return size;
  }

  ////// toString \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

  String toString() {
    return chars.toString();
  }
}