To do what you want, you need to keep track of different ellipses somehow. This can be done using arrays or object-oriented programming. In this case I would go with the latter. Below is a commented code example that uses oop to draw circles and move them after a certain number of frames.

Next step:
You could elaborate on this example by for example changing both x and y positions, having different x and y moving speeds and setting different numFramesChanges for each circle. All of those changes could be written inside the class and they would then apply to all the circles that are created. A good function to use for these differences would be random().

Note that in this example circles still exist (read: are not removed from the ArrayList) after they go off the screen.

Code Example

1. // arrayList to hold a random number of CircleBrushes in memory
   
2. ArrayList <CircleBrush> circles = new ArrayList <CircleBrush> ();
3.  
4. // number of frames after which ellipses start moving
5. int numFramesChange = 120;
6.  
7. void setup() {
8.   size(500, 300);
9. }
10.  
11. void draw() {
12.   // draw the background on each draw
13.   background(#FFFFFF);
14.   // run through ALL the circles
15.   for (CircleBrush cb : circles) {
16.     // update each one
17.     cb.update();
18.     // display each one
19.     cb.display();
20.   }
21. }
22.  
23. // add a circle on mousePressed
24. void mousePressed() {
25.   circles.add(new CircleBrush(mouseX,mouseY));
26. }
27.  
28. // add circles while mouseDragging
29. void mouseDragged() {
30.   circles.add(new CircleBrush(mouseX,mouseY));
31. }
32.  
33. // class with variables and functions
34. class CircleBrush {
35.   // variables for xy position and 'frame of creation'
36.   int x, y, frame;
37.  
38.   // create the circle with an xy position
39.   CircleBrush(int x, int y) {
40.     this.x = x;
41.     this.y = y;
42.     // set the 'frame of creation' to the current frame
43.     frame = frameCount;
44.   }
45.  
46.   // update function
47.   void update() {
48.     // after numFramesChange since creation
49.     if (frameCount - frame > numFramesChange) {
50.       // decrease the y by 1
51.       y--;
52.     }
53.   }
54.   
55.   // display function
56.   void display() {
57.     // fill color
58.     fill(#000000, 70);
59.     // display circle at xy
60.     ellipse(x, y, 40, 40);
61.   }
62. }

You must think of your ellipse being an individual object - which requires a class to define it.