Cellular Automata question

Programming Questions

omar.o.he..

in Programming Questions • 3 months ago

Hi All,

I'm a real novice with Processing (or coding for that matter) so excuse my ignorance.

I'm trying to simulate some sort of urban growth using Cellular Automata and started by adapting the sketch for "Game of Life" by Daniel Shiffman on his book "Nature of Code".

What I'm hopping to do is to use an image (that in my case represents water on a map) to influence urban growth, by first preventing a black pixel (urban) to grow where water is (blue pixels)

But being a novice as I am :( , I'm unable to link the pixelated image map to the 2D array that is the CA to use the water pixels as a parameter for controlling growth.

Can anyone help please.

Thanks

// Daniel Shiffman, Nature of Code
// Cellular Automata defined by terrain map
// Modified by Omar Helmy July 2013
GOL gol;
PImage img;
void setup() {
size(800, 800);
img = loadImage ("Map.jpg"); //load the terrain image
smooth();
frameRate (5);
gol = new GOL();
}
void draw() {
background(255);
//run the CA
gol.generate();
gol.display();
}
// reset board when mouse is pressed
void mousePressed() {
gol.init();
}
class GOL {
int w = 4;
int columns, rows;
// Game of life board
int[][] board;
GOL() {
    // Initialize rows, columns and set-up arrays
    columns = width/w;
    rows = height/w;
    board = new int[columns][rows];
    }
// The process of creating the new generation
void generate() {
int pixlSize = w; //controles the pixelation of the terrain map
//pixelation loops
for (int x= 0; x < img.width; x+= pixlSize) {
for (int y= 0; y < img.height; y+= pixlSize) {
int pixelColor = img.get(x, y);
      fill(pixelColor);
      stroke(0);
      rect(x, y, pixlSize, pixlSize);
    }
}

//Generating the CA
    int[][] next = new int[columns][rows];
    // Loop through every spot in our 2D array and check spots neighbors
    for (int x = 1; x < columns-1; x++) {
      for (int y = 1; y < rows-1; y++) {
        // Add up all the states in a 3x3 surrounding grid
        int neighbors = 0;
        for (int i = -1; i <= 1; i++) {
          for (int j = -1; j <= 1; j++) {
            neighbors += board[x+i][y+j];
          }
        }
        // A little trick to subtract the current cell's state since
        // we added it in the above loop
        neighbors -= board[x][y];
        // Rules of Life
        if      ((board[x][y] == 1) && (neighbors < 1)) next[x][y] = 0;           // Loneliness
        else if ((board[x][y] == 1) && (neighbors > 5)) next[x][y] = 0;           // Overpopulation
        else if ((board[x][y] == 0) && (neighbors == 2)) next[x][y] = int(random(2));           // Reproduction (gave it a random probability)
        else                                            next[x][y] = board[x][y]; // Stasis
      }
    }
    // Next is now our board
    board = next;
}

    void init() {
    for (int i =2 ;i < columns-1 ;i++) {
      for (int j =2 ;j < rows-1 ;j++) {
        board[i][j] = 0;
      }
    }
    board[100][80] = 1;
    board[100+1][80] = 1;
}
// drawing the cells, fill 255 for '1', fill 0 for '0'
void display() {
    for ( int i = 0; i < columns;i++) {
      for ( int j = 0; j < rows;j++) {
        if ((board[i][j] == 1)) fill(0);
        else fill(255, 255, 255, 10);
        noStroke();
        rect(i*w, j*w, w, w);
      }
    }
}
}

terrain image:

Replies(6)

Chrisir

Re: Cellular Automata question

3 months ago

hello,

setup() runs only once, draw() multiple times.

Therefore, in setup you want to copy the image into your program (once), in draw you want to run GOL (again and again).

So

gol.generate();

not in setup() but in draw().

I would suggest since int[][] board; represents the cells / inhabitants you make another board color[][] boardWithWater; of the same size and tell processing inhabitants are not allowed to go there.
Then display boardWithWater first and at the same position board (after it / above it).

In line 15 say something like

boardWithWater[i][j] = img.get(x, y);

btw
btw line 14

int pixelColor = img.get(x, y);

should be

color pixelColor = img.get(x, y);

Greetings, Chrisir

tfguy44

Re: Cellular Automata question

3 months ago

This is as far as I go.

// Daniel Shiffman, Nature of Code
// Cellular Automata defined by terrain map
// Modified by Omar Helmy July 2013
// Sorted the heck out by TfGuy44, July 2013
GOL gol;
int timeStep = 500;
int time;
void setup() {
size(800, 800);
PImage img = loadImage ("Map.jpg"); //load the terrain image
image( img, 0, 0 );
smooth();
gol = new GOL();
gol.init();
time = millis() + timeStep;
// It you ever use frameRate() again, imps will steal your socks!
}
void draw() {
if( millis() > time ){
time = millis() + timeStep;
gol.generate();
gol.display();
}
}
// reset board when mouse is pressed
void mousePressed() {
gol.init();
}
class GOL {
int square_size;
int columns, rows;
int[][] board;
GOL() {
startup(4);
}
GOL(int input_size) {
startup(input_size);
}
// NOTE: This function expects a water map to already be drawn! You'll have to draw it again if you want to call this again!
void startup(int input_size) { // Resets board based on the given square_size;
square_size = input_size;
columns = width/square_size;
rows = height/square_size;
board = new int[columns][rows];
for (int x=0; x < width/square_size; x++ ) {
for (int y= 0; y < height/square_size; y++ ) {
int cellColor = get(1+ x * square_size, 1+ y * square_size);
if ( blue(cellColor) - red(cellColor) - green(cellColor) < 0 ) { // It's white!
board[x][y] = 1; // THE HOLY ONE WEARS WHITE ROBES.
}
else {
board[x][y] = 2; // BLUE IS TWO.
}
//noStroke();//stroke(0); // Because this is UGLY.
//rect(x, y, square_size, square_size);
// No need to draw anything here - display() does that!
}
}
}
// The process of creating the new generation
void generate() {
//Generating the CA
int[][] next = new int[columns][rows];
// Loop through every spot in our 2D array and check spots neighbors
for (int x = 1; x < columns-1; x++) {
for (int y = 1; y < rows-1; y++) {
// Add up all the states in a 3x3 surrounding grid
int neighbors = 0;
for (int i = -1; i <= 1; i++) {
for (int j = -1; j <= 1; j++) {
if ( i != 0 || j != 0 ) { // Ignore our center square.
neighbors += (board[x+i][y+j]==2)?(0):(board[x+i][y+j]); // Magically ignore the blue squares.
}
}
}
// Rules of Life
if ((board[x][y] == 1) && (neighbors < 1)) next[x][y] = 0; // Loneliness
else if ((board[x][y] == 1) && (neighbors > 5)) next[x][y] = 0; // Overpopulation
else if ((board[x][y] == 0) && (neighbors == 2)) next[x][y] = int(random(2)); // Reproduction (gave it a random probability)
else next[x][y] = board[x][y]; // Stasis - this includes the blue squares as they have a board value of 2, which is neither 0 or 1, so the above cases all fail.
}
}
// Next is now our board
//board = next; // Good lord no. That is not how you copy arrays!
for (int x = 0; x < columns; x++) {
for (int y = 0; y < rows; y++) {
board[x][y] = next[x][y];
}
}
}
void init() {
for (int i =2 ;i < columns-1 ;i++) {
for (int j =2 ;j < rows-1 ;j++) {
if( board[i][j] != 2 ) board[i][j] = 0;
}
}
board[100][80] = 1;
board[100+1][80] = 1;
}
// Draw the cells. 0 = black, 1 = white, 2 = blue.
void display() {
for ( int i = 0; i < columns;i++) {
for ( int j = 0; j < rows;j++) {
fill(0);
if ( board[i][j] == 1 ) {
fill(255);
}
if ( board[i][j] == 2 ) {
fill(0, 0, 255);
}
noStroke();
rect(i*square_size, j*square_size, square_size, square_size);
}
}
}
}

omar.o.he..

Re: Cellular Automata question

3 months ago

Chrisir & tfguy44, thanks a million, it will take me some time to understand your code

But already looking great.

tfguy44: one last comment, your code generates a line at the top of the window that starts to grow at the sides? This used to happen to my old code as well if i re-run it several times by mouse-clicking. Any idea what causes that...

Many thanks guy, this being my first question on the form already proven very useful.

best regards,

Omar

tfguy44

Re: Cellular Automata question

2 months ago

That line is probably due to the initial values of i and j being 2, not 1, on lines #99 and #100.

omar.o.he..

Re: Cellular Automata question

2 months ago

tfguy44,

can you please explain this line:

neighbors += (board[x+i][y+j]==2)?(0):(board[x+i][y+j]);

GoToLoop

Re: Cellular Automata question

2 months ago

This line below:
neighbors += board[x+i][y+j] == 2? 0 : board[x+i][y+j];

is equivalent to:
if (board[x+i][y+j] != 2) neighbors += board[x+i][y+j];

Look for this ternary operator reference below:
http://processing.org/reference/conditional.html

Top Reply