Cannot invoke add(int) on the primitive type int. Whaaat???

GoToLoop

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

I tested your code on both Processing 2.0 & 1.5.1 and works alright:

final ArrayList<Integer> distance = new ArrayList();

int a=7;
distance.add(a);

println( distance.get(0) );

exit();

benj.n.su..

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

same here.

did you test your minimum working example and still get the same error or just post the mwe?

if not, then perhaps the problem is elsewhere in your code.

if so, restart? reinstall? perhaps?

lolwel21

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

I'm making a Super Hexagon type game. See if you can find an error in this WALL of code, please. I can't find it.

import ddf.minim.*;
import ddf.minim.analysis.*;
AudioPlayer player1;
Minim minim1;
BeatDetect beat;
ArrayList<Integer> distance=new ArrayList();
ArrayList<Integer> size=new ArrayList();
ArrayList<Integer> offset=new ArrayList();
int numberOfObstacles=0;
int ignoreBefore=0;
int formationOffset;
int formationID;
int turnSetting=0;
int scene=1;
int playerOffset;
int worldRotation;
boolean rotationDirection;
int scrad;
int playerPosition;
int counter;
public void setup(){
size(displayWidth, displayHeight-40);
minim1=new Minim(this);
player1=minim1.loadFile("Courtesy.mp3", 2048);
scrad=int(sqrt(width/2*width/2+height/2*height/2)*5/4);
distance.add(new Integer(20));
size.add(20);
offset.add(60);
}
public void draw(){
background(0);
if(scene==1){
//-----=#########=-----//
//-----=#SCENE 1#=-----//
//-----=#########=-----//
noStroke();
fill(255);
textSize(128);
textAlign(CENTER);
text("SUPER HEXAGON", width/2, height/4);
textAlign(LEFT);
fill(175);
if(width/2<mouseX && mouseX<width/2+150 && height/2<mouseY && mouseY<height/2+50){
if(mousePressed){
scene2();
player1.play();
}else{
fill(250);
}
}
quad(width/2-10, height/2+60, width/2+160, height/2+60, width/2+125, height/2-10, width/2+25, height/2-10);
fill(100);
quad(width/2, height/2+50, width/2+150, height/2+50, width/2+125, height/2, width/2+25, height/2);
fill(255);
textSize(40);
text("Start", width/2+35, height/2+40);
}else if(scene==2){
//-----=#########=-----//
//-----=#SCENE 2#=-----//
//-----=#########=-----//
noStroke();
float angle=360/6;
worldRotation=worldRotation+2;
if(worldRotation==360){
worldRotation=0;
}
if(counter>40){
startSpawning();
counter=1;
}else{
counter++;
}
for(int i=0;i<7;i++){
if(i==2 || i==4 || i==6){
fill(50);
}else{
fill(75);
}
beginShape();
vertex(width/2, height/2);
vertex(width/2+scrad*sin(radians(angle*i+worldRotation)), height/2+scrad*4/5*cos(radians(angle*i+worldRotation)));
vertex(width/2+scrad*sin(radians(angle*(i+1)+worldRotation)), height/2+scrad*4/5*cos(radians(angle*(i+1)+worldRotation)));
endShape(CLOSE);
}
//--------------------------=Obstacle Processing=---------------------------//
fill(255);
for(int i=ignoreBefore;i<numberOfObstacles+1;i++){
beginShape();
vertex(width/2+distance.get(i)*sin(radians(worldRotation+int(offset.get(i)))), height/2+(int(distance.get(i))*4/5)*cos(radians(worldRotation+int(offset.get(i)))));
vertex(width/2+distance.get(i)*sin(radians(worldRotation+offset.get(i)+60)), height/2+(distance.get(i)*4/5)*cos(radians(worldRotation+offset.get(i)+60)));
vertex(width/2+(distance.get(i)+size.get(i))*sin(radians(worldRotation+offset.get(i))), height/2+(distance.get(i)*4/5)*cos(radians(worldRotation+offset.get(i))));
vertex(width/2+(distance.get(i)+size.get(i))*sin(radians(worldRotation+offset.get(i)+60)), height/2+(distance.get(i)*4/5)*cos(radians(worldRotation+offset.get(i)+60)));
endShape(CLOSE);
int pdist=distance.get(i);
distance.remove(i);
distance.add(i, pdist);
if(distance.get(i)<40){
ignoreBefore++;
}else if(distance.get(i)<=80){
if(offset.get(i)<=playerOffset && offset.get(i)+60>=playerOffset){
scene=1;
player1.pause();
cursor();
}
}
}
fill(255);
text(numberOfObstacles-ignoreBefore, 20, 200);
beginShape();
for(int i=0;i<7;i++){
vertex(width/2+(player1.getVolume()+50)*sin(radians(angle*i+worldRotation)), height/2+(player1.getVolume()-10+50)*cos(radians(angle*i+worldRotation)));
}
endShape(CLOSE);
fill(75);
beginShape();
for(int i=0;i<7;i++){
vertex(width/2+(player1.getVolume()-10+50)*sin(radians(angle*i+worldRotation)), height/2+(player1.getVolume()-20+50)*cos(radians(angle*i+worldRotation)));
}
endShape(CLOSE);
if(turnSetting==1){
playerOffset=playerOffset-10;
}else if(turnSetting==2){
playerOffset=playerOffset+10;
}
playerPosition=worldRotation+playerOffset;
if(playerPosition>=360){
playerPosition=playerPosition-360;
}
fill(255);
triangle(width/2+70*sin(radians(playerPosition-10)), height/2+60*cos(radians(playerPosition-10)), width/2+70*sin(radians(playerPosition+10)), height/2+60*cos(radians(playerPosition+10)), width/2+90*sin(radians(playerPosition)), height/2+80*cos(radians(playerPosition)));
}
fill(255,0,0,50);
rect(0,0,width,height);
}
void keyPressed(){
if(key==' ' && scene==2){
scene=1;
player1.pause();
cursor();
player1.play();
}else if(keyCode==LEFT && scene==2){
turnSetting=2;
}else if(keyCode==RIGHT && scene==2){
turnSetting=1;
}else if(key==' ' && scene==1){
scene2();
}
}
void keyReleased(){
if(turnSetting>0){
if(keyPressed==false){
turnSetting=0;
}
}
}
void stop(){
player1.close();
minim1.stop();
}
public void startSpawning(){
formationID=int(random(1, 11));
formationOffset=int(random(0, 7));
if(formationID==1){
spawn(1, formationOffset, 1);
}else if(formationID==2){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 2);
}else if(formationID==3){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 3);
}else if(formationID==4){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 4);
}else if(formationID==5){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 2);
spawn(1, formationOffset, 3);
}else if(formationID==6){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 2);
spawn(1, formationOffset, 4);
}else if(formationID==7){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 5);
spawn(1, formationOffset, 3);
}else if(formationID==8){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 2);
spawn(1, formationOffset, 3);
spawn(1, formationOffset, 4);
}else if(formationID==9){
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 6);
spawn(1, formationOffset, 3);
spawn(1, formationOffset, 4);
}else if(formationID==10){
spawn(1, formationOffset, 2);
spawn(1, formationOffset, 4);
spawn(1, formationOffset, 5);
spawn(1, formationOffset, 6);
}else{
spawn(1, formationOffset, 1);
spawn(1, formationOffset, 2);
spawn(1, formationOffset, 4);
spawn(1, formationOffset, 5);
spawn(1, formationOffset, 6);
}
}
public void spawn(int size, int offset, int id){
numberOfObstacles++;
size=size*20+20;
offset=(id+offset)*60;
if(offset>=360){
offset=offset-360;
}
distance.add(scrad);
size.add(size);
offset.add(offset);
}
public void scene2(){
numberOfObstacles=0;
scene=2;
noCursor();
startSpawning();
}

o_O I just realized how much code this is...

ps. if you have any suggestions besides, please let me know. :D

quarks

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

The problem is in the spawn method below - in line 9 you have

size.add(size);

Although you have a linked list called size you also have an int parameter called size. so it is trying to add size to an int. The same applies to offset change lines 9 and 10 to

this.size.add(size);
this.offset.add(offset);

In future I suggest that you use a unique name for each variable/parameter

public void spawn(int size, int offset, int id){
numberOfObstacles++;
size=size*20+20;
offset=(id+offset)*60;
if(offset>=360){
offset=offset-360;
}
distance.add(scrad);
size.add(size);
offset.add(offset);
}

Mushussu

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

Be careful when you are naming your variables :

Try this :

public void spawn(int _size, int _offset, int id){
numberOfObstacles++;
_size=_size*20+20;
_offset=(id+_offset)*60;
if(_offset>=360){
_offset=_offset-360;
}
distance.add(scrad);
size.add(_size);
offset.add(_offset);
}

There are a confusion between "intList size" the global variable and "int size" the local variable.

lolwel21

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

Oh, thanks!.

I just realized... it still throws the same error. Darn :P

PhiLho

Re: Cannot invoke add(int) on the primitive type int. Whaaat???

4 months ago

It is also a good idea to use a plural name for lists (or collections in general): distances, sizes, etc.