Can't get transparency parameter work in Processing 2

Programming Questions

Erim

Can't get transparency parameter work in Processing 2

in Programming Questions • 1 month ago

Hello the precious community of processing

I recently immigrated to processing 2 however it seems the transparency parameter doesn't work in P3D mode at all. first I though they changed the way transparency is given to graphics in Version 2 but then I realized I didn't get any errors at all. Can anyone enlighten me what seems to be the problem here?

I've been searching on internet to solve my problem but couldn't find anything even related to my problem/ So, I'm giving a try to this forum.

here is the section where I put fill with alpha parameter.

Copy code

fill(0,opacity);
strokeWeight(0,);
pushMatrix();
translate(x, y, z );
sphere(2);
popMatrix();

Replies(5)

paulr451

Re: Can't get transparency parameter work in Processing 2

1 month ago

Not sure why you didn't get an error at the strokeWeight line, there is an extra comma in there. Also, a sphere of radius 2 is awfully small to see effects. But mainly are you clearing the background in draw() before trying the fade? Otherwise you are just drawing over whatever is already there. I tried it in Procesing 2 and it works fine. Try this code to see if your render is working OK (I added a red oval under the sphere to show the transparency more clearly):

int opacity = 255;
void setup() {
size(500,500,P3D);
frameRate(20);
}

void draw() {
if(opacity < 0) opacity = 255;
translate(width/2, height/2, 0 );
background(128);
fill(255,0,0);
ellipse(0,0,400,40);
fill(0,opacity--);
strokeWeight(0);
sphere(100);
}

Also. instead of strokeWeight(0) just use noStroke();

SidT

Re: Can't get transparency parameter work in Processing 2

1 month ago

Transparency of lines does not seem to be working in Processing v2. In the code below I added a yellow stroke to the ellipse but the stroke (ellipse border) does not show up as the sphere becomes less opaque. Thanks in advance!

int opacity = 255;
void setup() {
size(500,500,P3D);
frameRate(20);
}
void draw() {
if(opacity < 0) opacity = 255;
translate(width/2, height/2, 0 );
background(128);
fill(255,0,0);
//**** Added the two lines below ***//
strokeWeight(2);
stroke(255,255,0);
//******************************//
ellipse(0,0,400,40);
fill(0,opacity--);
strokeWeight(0);
sphere(100);
}

andres

Re: Can't get transparency parameter work in Processing 2

1 month ago

Getting semi-transparent objects to look correct in 3D is not easy (see this and this for more info). In addition to that, P3D does some internal optimizations for faster rendering, in which all stroke geometry is batched together and rendered after the fill triangles. This is fine most of the time but causes problems in particular cases, like this one. The stroke optimizations are enabled by default, but can be disabled with hint(DISABLE_OPTIMIZED_STROKE):

Copy code

int opacity = 255;
void setup() {
size(500,500,P3D);
frameRate(20);
hint(DISABLE_OPTIMIZED_STROKE);
}
void draw() {
background(128);
translate(width/2, height/2);
rotateY(frameCount * 0.01);
strokeWeight(2);
stroke(255,255,0);
fill(255,0,0);
ellipse(0,0,400,40);
fill(0,opacity--);
if(opacity < 0) opacity = 255;
noStroke();
sphere(100);
}

SidT

Re: Re: Can't get transparency parameter work in Processing 2

1 month ago

Thank you; turning off optimized stroke worked. Are these nuances of Processing documented or referenced somewhere (other than in the code)?
-SidT

andres

Re: Can't get transparency parameter work in Processing 2

1 month ago

the hint() function is not in the standard reference, but it is available in the javadoc.

Top Reply