The folder structure you currently have is incorrect. As mentioned multiple times in the article, here are instructions on how to install contributed libraries:

http://wiki.processing.org/w/How_to_Install_a_Contributed_Library

thanks. Here is the problem I had.

wiki:The top folder of a library must have the same name as the .jar file located inside a library's library folder (minus the .jar extension)

I didn't rename the folder name as the .jar 's. But here is my other issue, since the library has two jar, and I can't create two folders with respective jar, cause P would warn me for duplicate library folders, so what about the other jar ?

fyi, the Augmented Reality library has NyAR4psg.jar and NyARToolkit.jar, I created NyAR4psg folder to put all the stuffs inside, and it works, but I  didn't create NyARToolkit folder, would it be a problem ? So far when I run the samples, it can run but give me a blank canvas.

appreciate for any more advice. ;)
pop

ps.
Amnon, just realized it is your tutorials, great to learn Augmented Reality with processin.

The first sample shows same error messages so none is working here,

1. // Augmented Reality Basic Example by Amnon Owed (21/12/11)
2. // Processing 1.5.1 + NyARToolkit 1.1.6
3. import java.io.*; // for the loadPatternFilenames() function
4. import processing.opengl.*; // for OPENGL rendering
5. import jp.nyatla.nyar4psg.*; // the NyARToolkit Processing library
6. // a central location is used for the camera_para.dat and pattern files, so you don't have to copy them to each individual sketch
7. // Make sure to change both the camPara and the patternPath String to where the files are on YOUR computer
8. // the full path to the camera_para.dat file
9. String camPara = "C:\Users\Gulianno\Documents\processing-2.0a8\my sketch folders\libraries\NyAR4psg\data\camera_para.dat";
10. // the full path to the .patt pattern files
11. String patternPath = "C:\Users\Gulianno\Documents\processing-2.0a8\my sketch folders\libraries\NyAR4psg\data\hiro.patt";
12. // the dimensions at which the AR will take place. with the current library 1280x720 is about the highest possible resolution.
13. // it will work just as well at a lower resolution such 640x360, in some case a lower resolution even seems to work better.
14. int arWidth = 1280;
15. int arHeight = 720;
16. // the number of pattern markers (from the complete list of .patt files) that will be detected, here the first 10 from the list.
17. int numMarkers = 10;
18. MultiMarker nya;
19. float displayScale;
20. color[] colors = new color[numMarkers];
21. float[] scaler = new float[numMarkers];
22. PImage input, inputSmall;
23. void setup() {
24.   size(1280, 720, OPENGL); // the sketch will resize correctly, so for example setting it to 1920 x 1080 will work as well
25.   // create a text font for the coordinates and numbers on the boxes at a decent (80) resolution
26.   textFont(createFont("Arial", 80));
27.   // load the input image and create a copy at the resolution of the AR detection (otherwise nya.detect will throw an assertion error!)
28.   input = loadImage("input.jpg");
29.   inputSmall = input.get();
30.   inputSmall.resize(arWidth, arHeight);
31.   // to correct for the scale difference between the AR detection coordinates and the size at which the result is displayed
32.   displayScale = (float) width / arWidth;
33.   // create a new MultiMarker at a specific resolution (arWidth x arHeight), with the default camera calibration and coordinate system
34.   nya = new MultiMarker(this, arWidth, arHeight, camPara, NyAR4PsgConfig.CONFIG_DEFAULT);
35.   // set the delay after which a lost marker is no longer displayed. by default set to something higher, but here manually set to immediate.
36.   nya.setLostDelay(1);
37.   String[] patterns = loadPatternFilenames(patternPath);
38.   // for the selected number of markers, add the marker for detection
39.   // create an individual color and scale for that marker (= box)
40.   for (int i=0; i<numMarkers; i++) {
41.     nya.addARMarker(patternPath + "/" + patterns[i], 80);
42.     colors[i] = color(random(255), random(255), random(255), 160); // random color, always at a transparency of 160
43.     scaler[i] = random(0.5, 1.9); // scaled at half to double size
44.   }
45. }
46. void draw() {
47.   background(0); // a background call is needed for correct display of the marker results
48.   image(input, 0, 0, width, height); // display the image at the width and height of the sketch window
49.   nya.detect(inputSmall); // detect markers in the input image at the correct resolution (incorrect resolution will give assertion error)
50.   drawMarkers(); // draw the coordinates of the detected markers (2D)
51.   drawBoxes(); // draw boxes on the detected markers (3D)
52. }
53. // this function draws the marker coordinates, note that this is completely 2D and based on the AR dimensions (not the final display size)
54. void drawMarkers() {
55.   // set the text alignment (to the left) and size (small)
56.   textAlign(LEFT, TOP);
57.   textSize(10);
58.   noStroke();
59.   // scale from AR detection size to sketch display size (changes the display of the coordinates, not the values)
60.   scale(displayScale);
61.   // for all the markers...
62.   for (int i=0; i<numMarkers; i++) {
63.     // if the marker does NOT exist (the ! exlamation mark negates it) continue to the next marker, aka do nothing
64.     if ((!nya.isExistMarker(i))) { continue; }
65.     // the following code is only reached and run if the marker DOES EXIST
66.     // get the four marker coordinates into an array of 2D PVectors
67.     PVector[] pos2d = nya.getMarkerVertex2D(i);
68.     // draw each vector both textually and with a red dot
69.     for (int j=0; j<pos2d.length; j++) {
70.       String s = "(" + int(pos2d[j].x) + "," + int(pos2d[j].y) + ")";
71.       fill(255);
72.       rect(pos2d[j].x, pos2d[j].y, textWidth(s) + 3, textAscent() + textDescent() + 3);
73.       fill(0);
74.       text(s, pos2d[j].x + 2, pos2d[j].y + 2);
75.       fill(255, 0, 0);
76.       ellipse(pos2d[j].x, pos2d[j].y, 5, 5);
77.     }
78.   }
79. }
80. // this function draws correctly placed 3D boxes on top of detected markers
81. void drawBoxes() {
82.   // set the AR perspective uniformly, this general point-of-view is the same for all markers
83.   nya.setARPerspective();
84.   // set the text alignment (full centered) and size (big)
85.   textAlign(CENTER, CENTER);
86.   textSize(20);
87.   // for all the markers...
88.   for (int i=0; i<numMarkers; i++) {
89.     // if the marker does NOT exist (the ! exlamation mark negates it) continue to the next marker, aka do nothing
90.     if ((!nya.isExistMarker(i))) { continue; }
91.     // the following code is only reached and run if the marker DOES EXIST
92.     // get the Matrix for this marker and use it (through setMatrix)
93.     setMatrix(nya.getMarkerMatrix(i));
94.     scale(1, -1); // turn things upside down to work intuitively for Processing users
95.     scale(scaler[i]); // scale the box by it's individual scaler
96.     translate(0, 0, 20); // translate the box by half (20) of it's size (40)
97.     lights(); // turn on some lights
98.     stroke(0); // give the box a black stroke
99.     fill(colors[i]); // fill the box by it's individual color
100.     box(40); // the BOX! ;-)
101.     noLights(); // turn off the lights
102.     translate(0, 0, 20.1); // translate to just slightly above the box (to prevent OPENGL uglyness)
103.     noStroke();
104.     fill(255, 50);
105.     rect(-20, -20, 40, 40); // display a transparent white rectangle right above the box
106.     translate(0, 0, 0.1); // translate to just slightly above the rectangle (to prevent OPENGL uglyness)
107.     fill(0);
108.     text("" + i, -20, -20, 40, 40); // display the ID of the box in black text centered in the rectangle
109.   }
110.   // reset to the default perspective
111.   perspective();
112. }
113. // this function loads .patt filenames into a list of Strings based on a full path to a directory (relies on java.io)
114. String[] loadPatternFilenames(String path) {
115.   File folder = new File(path);
116.   FilenameFilter pattFilter = new FilenameFilter() {
117.     public boolean accept(File dir, String name) {
118.       return name.toLowerCase().endsWith(".patt");
119.     }
120.   };
121.   return folder.list(pattFilter);
122. }

It wouldn't hurt if you read the article again, because it contains some instructions and tips that may help you to get things up and running. First, use forward slashes in your paths. Second, use Processing 1.5.1. Hope you're able to make it work.

Thanks for your info again.

I need to study more on GSVideo at http://gsvideo.sourceforge.net/
Also I try to get some more hints from this http://cpbotha.net/2010/06/05/processing-nyartoolkit-multiple-marker-tracking
And I have a book Prototyping Augmented Reality from T. Mulle.

I am really into Augmented Reality, so any reference will be good to start up ;)

I finally got the first Augmented Reality demo to run with the 0-7-1-3 serial transparent cubes. it is all about the file path

C:/Users/Gulianno/Documents/Processing/libraries/nyar4psg/patternMaker/examples/ARToolKit_Patterns

so I had to delete /patternMaker from the original path to fit the code so it work perfectly. I faced similar issue with AS3 week ago.

Thanks I will now see more samples and see if I can come up with mine ;)

thanks again for this great tutorials.

poserpro ;)

The 2nd sample seems a problem for me, the following line is yellow marked. Maybe it is my webcam resolution issue, but the same setting doesn't cause any trouble for sample 1. My 2 webcams ' resolution are all 640x480. But even I change the 1280 .720 to this, it still shows the same yellow line and play nothing.

1. cam = new GSCapture(this, 1280, 720); // initializing the webcam capture at a specific resolution (correct/possible settings depends on YOUR webcam)

Hi, Amnon
This should be my last post for this topic, cause I finally managed to get all 3 samples done with perfect results as you teach.
Happy isn't enough to describe how I feel now after hours of trials and errors, I actually did it.

The last minor issue is to let me choose which webcam I use for this purpose, I have 3 of them, I hope to use the ones not on top of the screen but portable for better position and orientation of the views.

i didn't bother to print the markers but capture them with my iPad 2 and show before my webcam, All cool to see :)

This tutorial is important to let me create Augmented Reality apps for my Augmented Reality projects. Thanks so much ;)

Gulianno ( aka poserpro )

OK.
Try to create a "NyAR4psg" folder in Processing>Libraries>
And all the NyAR4psg files should be inside this  "NyAR4psg,

The folder structure is like this :

NyAR4psg
-data
--camera_para.dat, patt.hiro.....
-library
--NyAR4psg.jar
-reference
-source
......

HTH.
poserpro

Have you read the http://wiki.processing.org/w/How_to_Install_a_Contributed_Library article?
You must not install libraries in the Processing installation folder.

Hi, I'm facing a problem with running the attached example on a windows machine under P2.0b6. Things are (mostly) fine on an MAC (pushMatrix and popMatrix seem to make the difference). However, under Windows, I get an 'Exception occurred at MultiMarker.MultiMarker' and the line 'nya = new MultiMarker(this, arWidth, arHeight, camPara, NyAR4PsgConfig.CONFIG_DEFAULT);' is highlighted. Are there any ideas how to resolve this issue?

Thanks

// Augmented Reality example based on work by Amnon Owed (21/12/11)
// Processing 2.0b6 + NyARToolkit 1.1.6

import java.io.*; // for the loadPatternFilenames() function
import processing.opengl.*; // for OPENGL rendering
import jp.nyatla.nyar4psg.*; // the NyARToolkit Processing library

// A central location is used for the camera_para.dat and pattern files, so you don't have to copy them to each individual sketch
// Make sure to change both the camPara and the patternPath String to where the files are on YOUR computer
// The full path to the camera_para.dat file
String camPara = "/Users/rgerndt/Documents/Processing/libraries/NyAR4psg/data/camera_para.dat";
// The full path to the .patt pattern files
String patternPath = "/Users/rgerndt/Documents/Processing/libraries/NyAR4psg/patternMaker/examples/ARToolKit_Patterns";
// The dimensions at which the AR will take place. with the current library 1280x720 is about the highest possible resolution.
// It will work just as well at a lower resolution such 640x360, in some case a lower resolution even seems to work better.
int arWidth = 640; //Changing the values may affect the detection capabilities
int arHeight = 480;
// The number of pattern markers (from the complete list of .patt files) that will be detected, here the first 10 from the list.
int numMarkers = 10;

MultiMarker nya;

float displayScale;
color[] colors = new color[numMarkers];
float[] scaler = new float[numMarkers];
PImage input, inputSmall;

void setup() {
  size(640, 480, OPENGL); // the sketch will resize correctly, so for example setting it to 1920 x 1080 will work as well
  frameRate(1);
  // Create a text font for the coordinates and numbers on the boxes at a decent (80) resolution
  textFont(createFont("Arial", 80));
  // Load the input image and create a copy at the resolution of the AR detection (otherwise nya.detect will throw an assertion error!)
  input = loadImage("input.jpg");
  inputSmall = input.get();
  inputSmall.resize(arWidth, arHeight);
  // To correct for the scale difference between the AR detection coordinates and the size at which the result is displayed
  displayScale = (float) width / arWidth;
  // Create a new MultiMarker at a specific resolution (arWidth x arHeight), with the default camera calibration and coordinate system
  nya = new MultiMarker(this, arWidth, arHeight, camPara, NyAR4PsgConfig.CONFIG_DEFAULT);
  String[] patterns = loadPatternFilenames(patternPath);
  // For the selected number of markers, add the marker for detection
  // Create an individual color and scale for that marker (= box)
  for (int i=0; i<numMarkers; i++) {
    nya.addARMarker(patternPath + "/" + patterns[i], 80);
    colors[i] = color(random(255), random(255), random(255), 160); // random color, always at a transparency of 160
    scaler[i] = random(0.5, 1.9); // scaled at half to double size
  }
}

void draw() {
  background(0); // a background call is needed for correct display of the marker results
  image(input, 0, 0, width, height); // display the image at the width and height of the sketch window
  nya.detect(inputSmall); // detect markers in the input image at the correct resolution (incorrect resolution will give assertion error)
  drawMarkers(); // draw the coordinates of the detected markers (2D)
  drawBoxes(); // draw boxes on the detected markers (3D)
}

// This function draws the marker coordinates, note that this is completely 2D and based on the AR dimensions (not the final display size)
void drawMarkers() {
  // set the text alignment (to the left) and size (small)
  textAlign(LEFT, TOP);
  textSize(10);
  noStroke();
  // Scale from AR detection size to sketch display size (changes the display of the coordinates, not the values)
  scale(displayScale);
  // For all the markers...
  for (int i=0; i<numMarkers; i++) {
    // If the marker does NOT exist (the ! exlamation mark negates it) continue to the next marker, aka do nothing
    if ((!nya.isExistMarker(i))) { continue; }
    // The following code is only reached and run if the marker DOES EXIST
    // Get the four marker coordinates into an array of 2D PVectors
    PVector[] pos2d = nya.getMarkerVertex2D(i);
    // Draw each vector both textually and with a red dot
    for (int j=0; j<pos2d.length; j++) {
      String s = "(" + int(pos2d[j].x) + "," + int(pos2d[j].y) + ")";
      fill(255);
      rect(pos2d[j].x, pos2d[j].y, textWidth(s) + 3, textAscent() + textDescent() + 3);
      fill(0);
      text(s, pos2d[j].x + 2, pos2d[j].y + 2);
      fill(255, 0, 0);
      ellipse(pos2d[j].x, pos2d[j].y, 5, 5);
    }
  }
}

// This function draws correctly placed 3D boxes on top of detected markers
void drawBoxes() {
  pushMatrix();
  // Set the AR perspective uniformly, this general point-of-view is the same for all markers
  nya.setARPerspective();
  // Set the text alignment (full centered) and size (big)
  textAlign(CENTER, CENTER);
  textSize(20);
  // For all the markers...
  for (int i=0; i<numMarkers; i++) {
    // If the marker does NOT exist (the ! exlamation mark negates it) continue to the next marker, aka do nothing
    if ((!nya.isExistMarker(i))) { continue; }
    // The following code is only reached and run if the marker DOES EXIST
    // Get the Matrix for this marker and use it (through setMatrix)
    setMatrix(nya.getMarkerMatrix(i));
    scale(1, -1); // turn things upside down to work intuitively for Processing users
    scale(scaler[i]); // scale the box by it's individual scaler
    translate(0, 0, 20); // translate the box by half (20) of it's size (40)
    lights(); // turn on some lights
    stroke(0); // give the box a black stroke
    fill(colors[i]); // fill the box by it's individual color
    box(40); // the BOX! ;-)
    noLights(); // turn off the lights
    translate(0, 0, 20.1); // translate to just slightly above the box (to prevent OPENGL uglyness)
    noStroke();
    fill(255, 50);
    rect(-20, -20, 40, 40); // display a transparent white rectangle right above the box
    translate(0, 0, 0.1); // translate to just slightly above the rectangle (to prevent OPENGL uglyness)
    fill(0);
    text("" + i, -20, -20, 40, 40); // display the ID of the box in black text centered in the rectangle
  }
  popMatrix();
  // Reset to the default perspective
  perspective();
}

// This function loads .patt filenames into a list of Strings based on a full path to a directory (relies on java.io)
String[] loadPatternFilenames(String path) {
  File folder = new File(path);
  FilenameFilter pattFilter = new FilenameFilter() {
    public boolean accept(File dir, String name) {
      return name.toLowerCase().endsWith(".patt");
    }
  };
  return folder.list(pattFilter);
}

Sorry - Re-installed the libraries and other stuff (again) and things are working under P2.0b6 now (probably some kind of 'user error').