Can not track any clicked color ?

creativen

Can not track any clicked color ?

in Contributed Library Questions • 9 months ago

This code I get from http://www.learningprocessing.com/examples/chapter-16/example-16-11/, and it works to activate my webcam then track anycolor that I click, here is the image:

Here is the code:

// Learning Processing
// Daniel Shiffman
// http://www.learningprocessing.com
// Example 16-11: Simple color tracking
import processing.video.*;
// Variable for capture device
Capture video;
// A variable for the color we are searching for.
color trackColor;
void setup() {
size(320,240);
video = new Capture(this,width,height,15);
// Start off tracking for red
trackColor = color(255,0,0);
smooth();
}
void draw() {
// Capture and display the video
if (video.available()) {
video.read();
}
video.loadPixels();
image(video,0,0);
// Before we begin searching, the "world record" for closest color is set to a high number that is easy for the first pixel to beat.
float worldRecord = 500;
// XY coordinate of closest color
int closestX = 0;
int closestY = 0;
// Begin loop to walk through every pixel
for (int x = 0; x < video.width; x ++ ) {
for (int y = 0; y < video.height; y ++ ) {
int loc = x + y*video.width;
// What is current color
color currentColor = video.pixels[loc];
float r1 = red(currentColor);
float g1 = green(currentColor);
float b1 = blue(currentColor);
float r2 = red(trackColor);
float g2 = green(trackColor);
float b2 = blue(trackColor);
// Using euclidean distance to compare colors
float d = dist(r1,g1,b1,r2,g2,b2); // We are using the dist( ) function to compare the current color with the color we are tracking.
// If current color is more similar to tracked color than
// closest color, save current location and current difference
if (d < worldRecord) {
worldRecord = d;
closestX = x;
closestY = y;
}
}
}
// We only consider the color found if its color distance is less than 10.
// This threshold of 10 is arbitrary and you can adjust this number depending on how accurate you require the tracking to be.
if (worldRecord < 10) {
// Draw a circle at the tracked pixel
fill(trackColor);
strokeWeight(4.0);
stroke(0);
ellipse(closestX,closestY,16,16);
}
}
void mousePressed() {
color c = get(mouseX, mouseY);
println("r: " + red(c) + " g: " + green(c) + " b: " + blue(c));
// Save color where the mouse is clicked in trackColor variable
int loc = mouseX + mouseY*video.width;
trackColor = video.pixels[loc];
}

After I modify it, It success to display image/video from Kinect, like this:

But it can not track any color if I click the mouse.

Here is the code modification:

import SimpleOpenNI.*;
SimpleOpenNI kinect;
color trackColor;
// Frame
PImage currentFrame;
void setup()
{
size(640, 480);
kinect = new SimpleOpenNI(this);
kinect.enableRGB();
trackColor = color (255,0,0);
smooth ();
currentFrame = createImage (640,480, RGB);
}
void draw()
{
kinect.update();
currentFrame.loadPixels();
PImage depthImage = kinect.depthImage();
PImage currentFrame = kinect.rgbImage ();
image(currentFrame,0,0);
// Before we begin searching, the "world record" for closest color is set to a high number that is easy for the first pixel to beat.
float worldRecord = 500;
// XY coordinate of closest color
int closestX = 0;
int closestY = 0;
// Begin loop to walk through every pixel
for (int x = 0; x < currentFrame.width; x ++ ) {
for (int y = 0; y < currentFrame.height; y ++ ) {
int loc = x + y*currentFrame.width;
// What is current color
color currentColor = currentFrame.pixels[loc];
float r1 = red(currentColor);
float g1 = green(currentColor);
float b1 = blue(currentColor);
float r2 = red(trackColor);
float g2 = green(trackColor);
float b2 = blue(trackColor);
// Using euclidean distance to compare colors
float d = dist(r1,g1,b1,r2,g2,b2); // We are using the dist( ) function to compare the current color with the color we are tracking.
// If current color is more similar to tracked color than
// closest color, save current location and current difference
if (d < worldRecord) {
worldRecord = d;
closestX = x;
closestY = y;
}
}
}
// We only consider the color found if its color distance is less than 10.
// This threshold of 10 is arbitrary and you can adjust this number depending on how accurate you require the tracking to be.
if (worldRecord < 10) {
// Draw a circle at the tracked pixel
fill(trackColor);
strokeWeight(4.0);
stroke(0);
ellipse(closestX,closestY,16,16);
}
}
void mousePressed(){
color c = get(mouseX, mouseY);
println("r: " + red(c) + " g: " + green(c) + " b: " + blue(c));
// Save color where the mouse is clicked in trackColor variable
int loc = mouseX + mouseY*currentFrame.width;
println(loc);
trackColor = currentFrame.pixels[loc];
}

Anyone can help me to find which code I make error so it can not track any color?

I really need to track color but using Kinect cam and processing not webcam.

Thank you very much.

Replies(2)

benja

Re: Can not track any clicked color ?

9 months ago

Line 29 could be the problem

PImage currentFrame = kinect.rgbImage ();

You declare a new local variable 'currentFrame' on which the kinect-image is drawn. When you pick a color inside of mousePressed() it uses the global 'currentFrame' which is a different PImage. Try to change the line to:

currentFrame = kinect.rgbImage ();

That could fix the problem, but i am not sure, I can't test your code without kinect.

creativen

Re: Can not track any clicked color ?

9 months ago

Wow you are so brilliant!

It is fixed now! Thank you so much!

Top Reply