Can anyone provide tips/guidelines of optimizing this code

Processing Forum

Programming Questions

owaunandr..

Can anyone provide tips/guidelines of optimizing this code

in Programming Questions • 2 years ago

I found this sketch on openprocessing, and I want to increase the framerate

http://www.openprocessing.org/visuals/?visualID=7539

float startScale=0.005;

float octaveScaleFactor=0.2;

int octaves = 5;

float[] octaveScaleFactors = new float[octaves];

float scaleFactorPerOctave = 1.6;

float erosionStrength = 0.1;

void setup(){

  size(400, 400);

  render();

}

void draw(){

}

void keyTyped() {

  if(int(key) == 49) startScale -= 0.001;

  if(int(key) == 50) startScale += 0.001;

  if(int(key) == 51) octaveScaleFactor -= 0.05;

  if(int(key) == 52) octaveScaleFactor += 0.05;

  if(int(key) == 53) octaves--;

  if(int(key) == 54) octaves++;

  if(int(key) == 55) scaleFactorPerOctave -= 0.02;

  if(int(key) == 56) scaleFactorPerOctave += 0.02;

  if(int(key) == 57) erosionStrength -= 0.02;

  if(int(key) == 48) erosionStrength += 0.02;

  if(int(key) >= 48 && int(key) <= 57){

    print("Render... ");

    octaveScaleFactors = new float[octaves];

    render();

    print(" done\n");

  }

  println(int(key));

}

void renderHUD(){

  PFont myFont = createFont("Arial", 11);

  textFont(myFont);

  fill(255, 255, 0);

  text("(1/2) Scale of Features: " + startScale, 10, 20);

  text("(3/4) Verical Scale: " + octaveScaleFactor, 10, 30);

  text("(5/6) Octaves: " + octaves, 10, 40);

  text("(7/8) Octave Scales: " + scaleFactorPerOctave, 10, 50);

  text("(9/0) Erosion: " + erosionStrength, 10, 60);

}

void render(){

  background(0);



  float xf, yf, altitude;

  for(float x=0; x < width; x++) {

    for(float y=0; y < height; y++) {

      xf = x;

      yf = y;

      altitude = myNoise(xf, yf, 0);

      for(int oc = 1; oc < octaves; oc++){

        float[] off = getSlope(xf, yf, oc);

        xf += off[0] / scaleFactor(oc);

        yf += off[1] / scaleFactor(oc);

        float val = myNoise(xf, yf, oc);

        altitude += (val - 0.5) * octaveScaleFactor;

      }

      stroke(altitude*255);

      point(x, y);

    }

  }



  renderHUD();

}

float[] getSlope(float x, float y, int oc){

  float f = erosionStrength / scaleFactor(oc);

  float[] result = new float[2];

  result[0] = myNoise(x, y, oc) - myNoise(x + f, y, oc);

  result[1] = myNoise(x, y, oc) - myNoise(x, y + f, oc);

  return result;

}

float scaleFactor(int octave){

  if(octaveScaleFactors[octave] == 0){

    octaveScaleFactors[octave] = startScale * pow(scaleFactorPerOctave, octave);

  }

  return octaveScaleFactors[octave];

}

float myNoise(float x, float y, int octave){

  return noise(x * scaleFactor(octave) + octave * width, y * scaleFactor(octave));

}

Replies(2)

mbraendle

Re: Can anyone provide tips/guidelines of optimizing this code

2 years ago

Hi,

the framerate is already high, what you mean is the time needed to calculate the new graph after a key has been typed.

The algorithm consists of 3 nested loops. The main optimizations can be applied in the most inner loop that is run through most.

First, we see that the function scaleFactor(int octave) is called

- 2x directly

- twice per call to myNoise, which itself is called 5 times

So we have 12 calls to scaleFactor(int octave), and hence 12 times a comparison " if(octaveScaleFactors[octave] == 0)" and 12 array accesses to octaveScaleFactors[octave] which take time.

These calls are just done to see if a new value of octaveScaleFactors must be calculated or not.

This can be optimized by calculating the new octaveScaleFactors after a parameter has been changed in the function keyTyped(), and then storing the specific octaveScaleFactor in a variable and passing this variable to the myNoise function.

Another optimization (not sure if really efficient) is by manipulating the display pixel array directly instead of using point().

Minor optimizations:

- move font creation from renderHUD to setup, this needs to be done only once.

- eliminate call and parameter passing to getSlope, saves a little time.

This is my proposal:

float startScale=0.005;
float octaveScaleFactor=0.2;
float scaleFactorPerOctave = 1.6;
float erosionStrength = 0.1;
int octaves = 5;
float[] octaveScaleFactors = new float[octaves];
void setup(){
size(400, 400);
updateOctaveScaleFactors();
PFont myFont = createFont("Arial", 11);
textFont(myFont);
loadPixels();
render();
}
void draw(){
}
void keyTyped() {
if(int(key) == 49) startScale -= 0.001;
if(int(key) == 50) startScale += 0.001;
if(int(key) == 51) octaveScaleFactor -= 0.05;
if(int(key) == 52) octaveScaleFactor += 0.05;
if(int(key) == 53) octaves--;
if(int(key) == 54) octaves++;
if(int(key) == 55) scaleFactorPerOctave -= 0.02;
if(int(key) == 56) scaleFactorPerOctave += 0.02;
if(int(key) == 57) erosionStrength -= 0.02;
if(int(key) == 48) erosionStrength += 0.02;
if(int(key) >= 48 && int(key) <= 57){
print("Render... ");
octaveScaleFactors = new float[octaves];
updateOctaveScaleFactors();
render();
print(" done\n");
}
println(int(key));
}
void renderHUD(){
fill(255, 255, 0);
textMode(MODEL);
text("(1/2) Scale of Features: " + startScale, 10, 20);
text("(3/4) Verical Scale: " + octaveScaleFactor, 10, 30);
text("(5/6) Octaves: " + octaves, 10, 40);
text("(7/8) Octave Scales: " + scaleFactorPerOctave, 10, 50);
text("(9/0) Erosion: " + erosionStrength, 10, 60);
}
void render(){
float xf, yf, altitude;
for(int x=0; x < width; x++) {
int row = x*width;
for(int y=0; y < height; y++) {
xf = x;
yf = y;
altitude = myNoise(xf, yf, startScale, 0);
for(int oc = 1; oc < octaves; oc++) {
float ocs = octaveScaleFactors[oc];
float f = erosionStrength / ocs;
float slope_x = myNoise(xf, yf, ocs, oc) - myNoise(xf + f, yf, ocs, oc);
float slope_y = myNoise(xf, yf, ocs, oc) - myNoise(xf, yf + f, ocs, oc);
xf += slope_x / ocs;
yf += slope_y / ocs;
float val = myNoise(xf, yf, ocs, oc);
altitude += (val - 0.5) * octaveScaleFactor;
}
float greyval = altitude*255;
color grey = color(greyval,greyval,greyval);
pixels[row + y] = grey;
}
}
updatePixels();
renderHUD();
}
float myNoise(float x, float y, float ocs, int octave) {
return noise(x * ocs + octave * width, y * ocs);
}
void updateOctaveScaleFactors() {
for (int oc = 1; oc < octaves; oc++) {
octaveScaleFactors[oc] = startScale * pow(scaleFactorPerOctave, oc);
}
}

Further optimizations can IMO just be done using parallel programming or multithreading (e.g. splitting the loops on multiple CPUs).

owaunandr..

Re: Can anyone provide tips/guidelines of optimizing this code

2 years ago

Thanks for the tips so far mbraendle. I've read some multithreading posts here on the forum.

I would love to see these transitions in real time; but like you said the framerate drop only occurs when it switches.

Top Reply

Can anyone provide tips/guidelines of optimizing this code

Replies(2)

Re: Can anyone provide tips/guidelines of optimizing this code

Re: Can anyone provide tips/guidelines of optimizing this code

Statistics

Tags

Actions

Related Posts