Calculating angles

Programming Questions

doodle

Answered

Need more info
Answered
Working on it

in Programming Questions • 3 years ago

I tried using PVectors angleBetween but I was not getting what I expected and feel that I am missing something very basic.

Replies(9)

PhiLho

Re: Calculating angles

3 years ago

angleBetween should to the trick, perhaps it is an init thing. Show a simple sketch with your attempt.
The magic behind angleBetween relies on atan2() function, so maybe you can use this one instead.

doodle

Re: Calculating angles

3 years ago

Copied right from the example angleBetween I wasn't even getting the out put the comment says I should. When I looked at the source it looked ok to me. I can't figure out whats going on.

Using the atan2() function worked perfectly. Thank you. I am still curious why I can't get angleBetween to work!

PhiLho

Don't show a screenshot for a few lines of code! It is longer to load, and we cannot copy/paste the content...
And don't forget to mark a question as answered (I did that for you, but you can change the best answer, I think).

guy_yitzh..

Re: Calculating angles

3 years ago

The output is different than what you expect since you are missing the conversion to degrees from radians.

angleBetween returns the angle in radians.

println(degrees(a)); // Prints "10.304827"

really prints "10.304827"

guy_yitzh..

Re: Calculating angles

3 years ago

actually prints 10.304846 but I guess that's close enough

blindfish

Re: Calculating angles

3 years ago

Notice that the example in the Reference converts the returned value to degrees in the println statement. You don't; so you're seeing the angle in radians.

adamcsmit..

Re: Calculating angles

3 years ago

The reason angleBetween() doesn't work is because it's not actually what you're after. angleBetween() calculates the angle between the v1 and v2 vectors; that is, the angle between a line from the origin to v1 and a line from the origin to v2.

What you want is simply the heading angle of the vector from v2 to v1, which is what you get from atan2(y1-y2, x1-x2). If you want to do this with methods from the PVector class, you would do a vector subtraction and then use the heading2D() method. Something like this:

// assuming v1, v2 have already been set
PVector v3 = new PVector();
v3.set(v1);
v3.sub(v2); // v3 is now the vector from v2 to v1
float a = v3.heading2D();

Jack Kern

Re: Calculating angles

3 years ago

PVector to = new PVector();
PVector from = new PVector();
final float pointSize = 15;
final float margin = 20;
final color fromColor = #931333;
final color toColor = #34AAE8;
final color lineColor = #54A243;
// ------------------------------------------------------------------------------------------- //
void setup()
{
size(400,400);
from.set( width/2, height/2, 0 );
textFont( createFont( "Arial", 14 ) );
smooth();
}
// ------------------------------------------------------------------------------------------- //
void draw()
{
background(255);
to.set(mouseX, mouseY, 0);
float angle = seg_angle( to, from );
drawAngle( angle, height*0.4 );
drawFrom();
drawTo();
}
// ------------------------------------------------------------------------------------------- //
void drawFrom() { noStroke(); fill( fromColor ); ellipse( from.x, from.y, 15, 15 ); }
void drawTo() { noStroke(); fill( toColor ); ellipse( to.x, to.y, 15, 15 ); }
// ------------------------------------------------------------------------------------------- //
void drawAngle( float angle, float seg_length )
{
noFill();
stroke( lineColor );
strokeWeight(1.5);
// Draw the line segments
line( seg_x( angle, margin ), seg_y( angle, margin )
, seg_x( angle, seg_length ), seg_y( angle, seg_length ) );
line( seg_x( -PI, margin ), seg_y( -PI, margin )
, seg_x( -PI, seg_length ), seg_y( -PI, seg_length ) );
// Draw the arc
strokeWeight(3);
arc( from.x, from.y, 3*margin, 3*margin, -PI -.2, angle + .2 );
// Draw the text for the angle
float text_angle = ( -PI + angle ) * 0.5f;
noStroke();
fill(0);
text( degrees(PI + angle), seg_x( text_angle, 2*margin ), seg_y( text_angle, 2*margin ) );
}
// ------------------------------------------------------------------------------------------- //
float seg_x ( float angle, float distance ) { return from.x + cos( angle ) * distance; }
float seg_y ( float angle, float distance ) { return from.y + sin( angle ) * distance; }
float seg_angle( PVector to, PVector from ) { return seg_angle( to.x, to.y, from.x, from.y ); }
float seg_angle( float xTo, float yTo
, float xFrom, float yFrom )
{
float dx = xTo - xFrom;
float dy = yTo - yFrom;
return atan2(dy,dx);
}

doodle

Re: Calculating angles

3 years ago

Thanks Adam that was what I was missing. Thanks Jack for the visualization.

Top Reply

Statistics

9 Replies
5289 Views
1 Followers

Actions

Permalink