Calculating angle

General Discussion Other

maxwellts..

in General Discussion • Other • 1 year ago

Hi
I have this project in which I need to calculate the angle between 2 lines. I will need to use Sin after I get the angle. The problem is, how am I going to get the angle? Is there any way or code to get it? Thanks!

Replies(8)

maxwellts..

Re: Calculating angle

1 year ago

I have read the other "Calculating Angles" post but I don't quite get it.

amnon.owed

Re: Calculating angle

1 year ago

The PVector class has a convenient angleBetween method. atan2 is often useful as well.

Code Example

PVector a = new PVector(150, 0);
PVector b = new PVector(0, 150);
float angle, arcangle;
void setup() {
size(500, 500);
smooth();
textAlign(CENTER, CENTER);
}
void draw() {
background(255);
translate(width/2, height/2);
fill(0);
line(0, 0, a.x, a.y);
line(0, 0, b.x, b.y);
ellipse(a.x, a.y, 15, 15);
ellipse(b.x, b.y, 15, 15);
b.set(mouseX-width/2, mouseY-height/2, 0);
angle = PVector.angleBetween(a, b);
if (a.y <= b.y) { arcangle = angle; } else { arcangle = angle + 2*(PI-angle); }
arc(0, 0, 150, 150, 0, arcangle);
ellipse(0, 0, 50, 50);
fill(255);
text(int(degrees(angle)), 0, 0);
}

maleo

Re: Calculating angle

1 year ago

angleBetween() will give you the shorter angle between the two vectors. meaning you always get a value between 0-PI rad or 0-180 degrees.

with atan2() you can get a consistent angle measurement from one vector to another one, say in clockwise direction, which will get you values between 0-2*PI rad or 0-360 degrees. building on amnon.owed's code (thx!):

PVector a = new PVector(150, 0);
PVector b = new PVector(0, 150);
float angle, arcangle;
void setup() {
size(500, 500);
smooth();
textAlign(CENTER, CENTER);
}
void draw() {
background(255);
fill(0);
text("Click to set first point, mouse around to set second.", width/2, 20);
text("Angle is calculated in clockwise direction from first point to second.", width/2, 40);
translate(width/2, height/2);
line(0, 0, a.x, a.y);
line(0, 0, b.x, b.y);
ellipse(a.x, a.y, 15, 15);
ellipse(b.x, b.y, 15, 15);
b.set(mouseX-width/2, mouseY-height/2, 0);
if (mousePressed) {
a.set(mouseX-width/2, mouseY-height/2, 0);
}
angle = angle(a, b);
drawArc();
ellipse(0, 0, 50, 50);
fill(255);
text(int(degrees(angle)), 0, 0);
}
void drawArc() {
float angleStart = angle(new PVector(1, 0), a);
float angleEnd = angle(new PVector(1, 0), b);
arc(0, 0, 150, 150, angleStart, angleEnd);
if (angleEnd < angleStart) {
arc(0, 0, 150, 150, angleStart, TWO_PI);
arc(0, 0, 150, 150, 0, angleEnd);
}
}
// returns the angle from v1 to v2 in clockwise direction
// range: [0..TWO_PI]
float angle(PVector v1, PVector v2) {
float a = atan2(v2.y, v2.x) - atan2(v1.y, v1.x);
if (a < 0) a += TWO_PI;
return a;
}