Calculate age of agents in agent-system

Programming Questions

luki_wlod..

Calculate age of agents in agent-system

in Programming Questions • 5 months ago

Hi guys,

does anyone know what could be the function that calculates the age of the agents? ( in term of how many frame each agent exists in the ArrayList ?

Replies(3)

luki_wlod..

Re: Calculate age of agents in agent-system

5 months ago

and I attach the class code:

class agent {
PVector pos;
PVector vel;
PVector acc;
float r;
float maxforce;
float maxspeed;
int age;
float steerForce = 1;
float sepForce = 1;
float outlineForce = 5;
int ageThreshold1 = 100;
agent(PVector l, float ms, float mf)
{
pos = l.get();
r = 3.0f;
maxspeed = ms;
maxforce = mf;
acc = new PVector(0,0);
vel = new PVector(0,0);
}
public void run()
{
update();
borders();
limitToOutline();
render();
}
void follow(SuperField f)
{
int age = calculateAge();
PVector ahead = vel.get();
ahead.normalize();
ahead.mult(32);
PVector lookup = PVector.add(pos,ahead);
PVector desired = f.lookup(lookup);
desired.mult(maxspeed);
PVector steer = PVector.sub(desired, vel);
steer.limit(maxforce);
steer.mult(steerForce);
PVector sep = separate(Agents);
sep.limit(maxforce);
sep.mult(sepForce);
acc.add(sep);
if(age<ageThreshold1)
{
acc.add(steer);
}
}
void update()
{
vel.add(acc);
vel.limit(maxspeed);
pos.add(vel);
acc.mult(0);
}
void render()
{
stroke(1);
strokeWeight(3);
noFill();
point(pos.x,pos.y);
}
void borders()
{
if (pos.x <= 0)
{
pos.x = 0 - pos.x;
vel.x*=-1;
}
if (pos.y <= 0)
{
pos.y = 0 - pos.y;
vel.y*= -1;
}
if (pos.x >= width)
{
pos.x = width-(pos.x-width);
vel.x*= -1;
}
if (pos.y >= height)
{
pos.y = height-(pos.y-height);
vel.y*= -1;
}
}
void limitToOutline()
{
float distThreshold = 10;
PVector closestVertex = getClosestContourVertex(pos, ContourVectices);
PVector actualDistance = closestVertex.get();
actualDistance.sub(pos);
float distance = actualDistance.mag();
if(distance<distThreshold)
{
vel.mult(-outlineForce);
}
}
PVector separate(ArrayList<agent> agentsPop)
{
float desiredseparation = 5.0f; //25.0f
PVector steer = new PVector(0,0);
int count = 0;
for (agent other : agentsPop) {
float d = PVector.dist(pos,other.pos);
if ((d > 0) && (d < desiredseparation))
{
PVector diff = PVector.sub(pos,other.pos);
diff.normalize();
diff.div(d); // Weight by distance
steer.add(diff);
count++; // Keep track of how many
}
}
// Average -- divide by how many
if (count > 0) {
steer.div((float)count);
}
if (steer.mag() > 0) {
steer.normalize();
steer.mult(maxspeed);
steer.sub(vel);
steer.limit(maxforce);
}
return steer;
}
PVector getClosestContourVertex(PVector agentPos, PVector [] PTS) {
float distClosest = 999999;
PVector theClosestVertex = null;
for(int i = 0; i<PTS.length; i++) {
PVector VertexPos = PTS[i].get();
float d2 = PVector.dist(agentPos, VertexPos);
if(d2 < distClosest){
distClosest = d2;
theClosestVertex = VertexPos.get();
}
}
return theClosestVertex;
}
int calculateAge()
{
// ?????????????????????????????????????????????????????????????
}
}

Chrisir

Re: Calculate age of agents in agent-system

5 months ago

hi,

since each agent can be of different age, you need to store it for each.

e.g. bornAt = frameCount ;

in the constuctor.

then to check if it dies

check bornAt diff frameCount > lifeIsLong

lifeIsLong could be global same value or different for each agent

Chrisir

luki_wlod..

Re: Calculate age of agents in agent-system

5 months ago

thanks chris!

works perfectly!

agent(PVector l, float ms, float mf)
{
pos = l.get();
r = 3.0f;
maxspeed = ms;
maxforce = mf;
acc = new PVector(0,0);
vel = new PVector(0,0);
bornAt = frameCount;
}

int calculateAge()
{
int i=frameCount - bornAt;
return i;
}

Top Reply