This is what I've come up with. Any doubts just ask:

/** 
 * BreakArrayIntoChunks (v2.16)
 * by GoToLoop (2013/Aug)
 * 
 * http://forum.processing.org/topic/break-arraylist-into-chunk
 */

import java.util.List;

final static short  CHUNK = 16, BOLD = 4;
final static color  FG = #308080, BG = -1;
final static String NAME = "curveData.txt", DELIM = ",";

void setup() {
  size(800, 600, P3D);
  noLoop();

  background(BG);
  stroke(FG);
  strokeWeight(BOLD);

  final List<PVector> vectors = new ArrayList();
  final Spline3D[] splines = loadData(vectors, CHUNK, NAME, DELIM);

  initSpline(splines, CHUNK);
  clusterData(splines, vectors, CHUNK);

  println(splines);
}

Spline3D[] loadData(List vecList, int chunk, String path, String delim) {
  final String[] lines = loadStrings(path);

  for (String row: lines) {
    final PVector p = new PVector();
    p.set( float(split(row, delim)) );
    vecList.add(p);
  }

  return new Spline3D[vecList.size()/chunk];
}

void initSpline(Spline3D[] splineArray, int chunk) {
  for (int i = 0, ii = splineArray.length; i != ii; 
  splineArray[i++] = new Spline3D(chunk));
}

void clusterData(Spline3D[] splineArray, List<PVector> vecList, int chunk) {
  final int num = vecList.size()/chunk * chunk;

  println("dim: " + vecList.size() + "\t num: " + num + "\n");

  for (int i = 0; i != num; ++i) {
    final PVector p = vecList.get(i);
    point(p.x, p.y, p.z);
    splineArray[i/chunk].setSpline(i%chunk, p);
  }
}

class Spline3D {
  final PVector[] vecs;

  Spline3D(int dim) {
    vecs = new PVector[dim];
    for (int i = 0; i != dim; vecs[i++] = new PVector());
  }

  boolean setSpline(int idx, PVector p) {
    if (idx >= 0 & idx < vecs.length)   vecs[idx].set(p);
    else                                return false;

    return true;
  }

  PVector getSpline(int idx) {
    return vecs[idx];
  }

  int getChunkSize() {
    return vecs.length;
  }

  String toString() {
    final StringBuilder sb = new StringBuilder(01200).append("\n");

    for (int i = 0, v = vecs.length; i != v; ++i) {
      final PVector p = vecs[i];
      sb.append("[").append(i).append("]\t x: ").append(p.x)
        .append("\t y: ").append(p.y).append("\t z: ").append(p.z).append("\n");
    }

    return sb.append("\n").toString();
  }
}

You mean these lines?

final List<PVector> vectors = new ArrayList();

Spline3D[] loadData(List<PVector> vecList, int chunk, String path, String delim) {}

void clusterData(Spline3D[] splineArray, List<PVector> vecList, int chunk) {}

I've declared vectors as a List b/c it's a shorter word than ArrayList!
It's still an ArrayList being instantiated anyways. As you can see after keyword new.

And for explanations, you have to tell us which part you don't get it!
I don't even know whether it's working for you there!