boxes perlin rotation

Programming Questions

stephanie..

in Programming Questions • 2 years ago

hi! i want to have this box rotation different like a 2d perlin field. what am i doing wrong? ...please. thank you!

import processing.opengl.*;

int distance = 25;
float h = 0;
float v = 0;
float perli = 0.0;

void setup () {
size (500, 500, OPENGL);
smooth ();
frameRate (30);
//ellipseMode (CENTER);
noStroke();
}

void draw () {
lights();
translate(50,50);
background(111);
for (float y = 0; y <= height-100; y = y + distance) {
    for (float x = 0; x <= width-100; x = x + distance) {
      pushMatrix();
      translate(x, y, 0);
      rotateY(h);
      rotateX(v);
      box(30);
      popMatrix();
      perli = perli + .1;
      float n = noise(perli) * 0.001;
      h = h + n;
      v = v + n;
    }
}
}

Replies(4)

nardove

Re: boxes perlin rotation

2 years ago

You are using the same rotation increment value for both axis h and v, not sure if this is what your after but give it a try

perli = perli + .1;
float n = noise(x, y, perli) * 0.0001;
float angle = n * TWO_PI;
h = h + cos(angle);
v = v + sin(angle);

stephanie..

thank you so much! ...not quite what i'm looking for but this effect is not bad either!
yes for what i want - a 2d noisefield like structure ( http://processing.org/learning/basics/noise2d.html) but simply visualized with the horz/vert rotation value of the cubes...
..i'll give it another try..

nardove

Re: boxes perlin rotation

2 years ago

How about this one:

import processing.opengl.*;
int distance = 25;
float increment = 0.01;
Cube[] cubes;
int numCubesX, numCubesY, totalCubes;
void setup () {
size (500, 500, OPENGL);
smooth ();
frameRate (30);
noStroke();
numCubesX = (width - 100) / distance;
numCubesY = (height - 100) / distance;
totalCubes = numCubesX * numCubesY;
cubes = new Cube[totalCubes];
for (int y = 0; y < numCubesY; y++) {
for (int x = 0; x < numCubesX; x ++) {
float posX = x * distance;
float posY = y * distance;
int i = y + x * numCubesY;
cubes[i] = new Cube( posX, posY, 30 );
}
}
}
void draw () {
background(111);
lights();
translate(50, 50);
for (int y = 0; y < numCubesY; y++) {
for (int x = 0; x < numCubesX; x ++) {
int i = y + x * numCubesY;
float n = noise( x, y, frameCount*increment );
cubes[i].rotX = n;
cubes[i].rotY = n;
cubes[i].display();
}
}
}
class Cube {
float x, y;
float dim;
float rotX = 0;
float rotY = 0;
Cube( float _x, float _y, float _dim ) {
x = _x;
y = _y;
dim = _dim;
}
void display() {
pushMatrix();
translate( x, y, 0 );
rotateY( rotX );
rotateX( rotY );
box( dim );
popMatrix();
}
}

stephanie..

Re: boxes perlin rotation

2 years ago

this is awesome! thank you very much!!! ...i played a bit around with different values and tried to understand what's going on. one thing i could not figure out yet; why the lower left cube barely moves, but the upper right at most...?

Top Reply