blurred edges ellipse

Programming Questions

Per_

in Programming Questions • 1 month ago

Hi!

I made a ellipse with blurred edges. Im still learning processing and coding, my example works but wonder is there any other solution thats more "proper"? otherwise this technique would work for blurring the edges of almost anything i guess

void setup() {
size(400, 400);
background(0);
}
void draw() {
background(0);
boll();
}
void mousePressed() {
background(0);
}
void boll() {
for (int i = 0; i < 85; i++) {
int d = 1 + (i*2);
int alpha = 255 - (i*3);
noStroke();
fill(255, alpha);
// print("d:" + d + " ");
// print("alpha:" + alpha + " ");
ellipse(mouseX, mouseY, d, d);
}
}

Replies(4)

tfguy44

Re: blurred edges ellipse

1 month ago

Your solution isn't bad, but is rather chunky.

This is better:

void setup() {
size(400, 400);
}
void draw() {
background(0);
ellipse(mouseX, mouseY, 160,160);
filter(BLUR, 4);
}

This is even better:

PImage cir;
void setup() {
size(400, 400);
PGraphics pg = createGraphics(200,200,P2D);
pg.beginDraw();
pg.background(0,0,0,0);
pg.fill(255);
pg.noStroke();
pg.ellipse(100,100,160,160);
pg.filter(BLUR,5);
pg.endDraw();
cir = pg.get();
imageMode(CENTER);
}
void draw() {
background(0);
image( cir, mouseX, mouseY);
}

That last one even runs nice and quickly on my slow machine.

Per_

Re: blurred edges ellipse

1 month ago

Thanks!

Sometimes when Im using the filter(); its pretty slow. its okej this time but imagine i would put 5 ellipses with filter BLUR or maybe 100 getting blurred in realtime at the same time. in my experience most of the time the result isnt very good.

I havnt tried this with my solution above either but most of the time Im trying to avoid using the filter for this reason.

any thoughts?

tfguy44

Re: blurred edges ellipse

1 month ago

Indeed, it is the call to filter() that is slowing it down for you. It's not a fast function.
This is why the second of my solutions is preferred. It only does the blur once, in setup, and saves the resulting blurry circle as an image for later, quick, use.

Per_

Re: blurred edges ellipse

1 month ago

okej. thanks! I understand.

So it could be a good option to use PGraphics if I want to blur something that stays the same "blur" amount all the time. but for example if I want to use blur to make a "smoke effect", something that changes over time and takes different shapes, not only a ellipse with a fixed size I might be better using something else? since I in that case cant use a fixed graphic. Maybe better with the modifiyng alpha channel different ways?

thanks

Top Reply