better way to write this code

Programming Questions

clankill3r

better way to write this code

in Programming Questions • 3 years ago

Hi, for the purpose of learning,
I made a program that random outputs one of the pre-defined available chars.
As soon as the word " waanzin" is made with it then it tells how many times a char was sended before this combination was founded. The program works so that's not the problem, but i'm just wondering how you guys would do it.
Like what names would you use, or will u use functions etc.

This because my code is confusing in my eyes for such a simple task and i think it can be done easier and i'm just wondering how.
It would be nice if some of you guys will make an example.

char[] elements = { ' ', 'w', 'a', 'n', 'z', 'i' };
String word = " waanzin";
char[] equalCheckChars;
char[] lastChars;
int end;
int count = 0;

void setup() {
equalCheckChars = word.toCharArray();
lastChars = new char[equalCheckChars.length];
end = lastChars.length-1;
frameRate(99999);
}

void draw() {
count++;

for(int i = 0; i < lastChars.length-1; i++) {//move all stored chars by 1 position
    lastChars[i] = lastChars[i+1];
}

int index = int(random(elements.length));//pick random char
lastChars[end] = elements[index];//store last added char

//print(elements[index]); //prints all chars to console

for(int i = 0; i < lastChars.length; i++){
    if(lastChars[i] == equalCheckChars[i]){
      if( i+1 == equalCheckChars.length){//last char is also equal so there is a hit
        println("\n "+count+" ticks");
        count = 0;//reset
       // exit();
      }
    }
    else{
      break; //no reason to continue check if the characters are not equal
    }
}
}

Replies(5)

amnon.owed

Re: better way to write this code

3 years ago

Cool idea!

Here is my take on it...

char[] elements = { ' ', 'w', 'a', 'n', 'z', 'i' };
String word = " waanzin";
char[] lastChars = new char[word.length()];
void setup() { frameRate(10000); }
void draw() {
for(int i=0; i<lastChars.length-1; i++) { lastChars[i] = lastChars[i+1]; } // move chars one down
lastChars[lastChars.length-1] = elements[int(random(elements.length))]; // generate new char
print(lastChars[lastChars.length-1]); // print latest char
String generatedWord = new String(lastChars); // make word from latest chars
if (generatedWord.equals(word)) {
println("\n\nWord generated! Only " + frameCount + " characters were harmed during the making of this sketch.");
exit();
}
}

quarks

Re: better way to write this code

3 years ago

Here is my take it avoids all that string handling and comparison so is quite quick after all you have 6 elements and a 7 character string to match so the average number of ticks would be
6x6x6x6x6x6x6 = 279936

char[] elements = {
' ', 'w', 'a', 'n', 'z', 'i'
};
String word = " waazin";
char[] wordLetters;
int wordLength, wordPos;
char rndLetter;
boolean quit = false;
int count = 0;
void setup() {
wordLetters = word.toCharArray();
wordLength = word.length();
wordPos = 0;
println("Start");
while(wordPos < wordLength) {
rndLetter = elements[int(random(elements.length))];
if(wordLetters[wordPos] == rndLetter)
wordPos++;
else
wordPos = 0;
print(rndLetter);
if(++count % 90 == 0)
println();
}
println("\n\n##############################################################");
println(" Found "+ word + " after " + count + " ticks");
println("##############################################################");
count = 0;
wordPos = 0;
}

clankill3r

Re: better way to write this code

3 years ago

Thx both,

quark i just saw your version, i will look into it later.

Amnon.owed thx, that was really helpfull, specially making a String of a char array, never knew that.
I made it sow now that the results get shown. For the word ' waanzin' it will take days for now i use ' w' :D

char[] elements = { ' ', 'w', 'a', 'n', 'z', 'i' };
String word = " w";
char[] lastChars = new char[word.length()];
int count = 0;
int[] ticks = new int[0];
int maxData = MIN_INT;

void setup() {
size(500, 500);
frameRate(99999);
randomSeed(4);
}

void draw() {
background(255);
count++;
for(int i=0; i<lastChars.length-1; i++) {
    lastChars[i] = lastChars[i+1];
} // move chars one down
lastChars[lastChars.length-1] = elements[int(random(elements.length))]; // generate new char
//print(lastChars[lastChars.length-1]); // print latest char
String generatedWord = new String(lastChars); // make word from latest chars
if (generatedWord.equals(word)) {
    println("\n\nWord generated! Only " + count + " characters were harmed during the making of this sketch.");
    println("millis :"+millis());

    ticks = append(ticks, count);
    if(count > maxData) maxData = count;

    count = 0;
    //exit();
}

ticks = sort(ticks);
//println(ticks);

for (int i = 0; i < ticks.length; i++){

    float y = map(ticks[i], 0, maxData, 0, height);
    line(i, height, i, y);
}

if(ticks.length > width)noLoop();

}

quarks

Re: better way to write this code

3 years ago

For the word ' waanzin' it will take days

I have modified the code I posted earlier so its displays how long it took to find the word. I tried it out on my 7 year old PC looking for the word " waanzin" a with these results

Ticks            Time (seconds)
980320            25.39
594640      11.453
263395      4.547
551130      12.266
1920960     35.313
3153814     53.078

char[] elements = {
' ', 'w', 'a', 'n', 'z', 'i'
};
String word = " waanzin";
char[] wordLetters;
int wordLength, wordPos;
char rndLetter;
boolean quit = false;
int count = 0;
long time;
void setup() {
time = millis();
wordLetters = word.toCharArray();
wordLength = word.length();
wordPos = 0;
println("Start");
while(wordPos < wordLength) {
rndLetter = elements[int(random(elements.length))];
if(wordLetters[wordPos] == rndLetter)
wordPos++;
else
wordPos = 0;
print(rndLetter);
if(++count % 60 == 0)
println();
}
float t = (millis() - time)/1000.0;
println("\n\n##############################################################");
println(" Found '"+ word + "' after " + count + " ticks ");
println(" Took "+ t + " seconds");
println("##############################################################");
count = 0;
wordPos = 0;
exit();
}
void draw(){
}

clankill3r

Re: better way to write this code

2 years ago

Finally, i looked into it :)

Your version is nice aswell, very understandable.
Thx, this is helpfull and intresting since there are so many ways to come to such a thing.

Top Reply