beginner code trouble (if statement in draw)

Programming Questions

mgushanas..

beginner code trouble (if statement in draw)

in Programming Questions • 2 years ago

So basically this code is meant to draw a vertical and horizontal line and when they intersect draw a diagonal like off of that.

It's nothing fancy, I'm just trying to learn processing and figured it would be a nice little thing to try out.

I have the vertical and horizontal lines working, and the if statement recognizes the collision (but only if I set x1 and y1 to a constant instead of a random).

so...

1) what do I have to do to lines 14 & 17 to get them to recognize in the collision?

2) what do I have to do to get my diagonal line to grow from that collision point?

Any help would be appreciated.

int w = 450;
int h = 450;
void setup(){
size(w,h);
background(255);
stroke(0);
strokeWeight(1);
smooth();
loop();
}
float x1 = random(w-1);
float x2 = x1;
float y1 = random(h-1);
float y2 = y1;
int grow_vert = h;
int grow_hor = w;
int speed = -1;
void draw(){
grow_vert = grow_vert+speed;
grow_hor = grow_hor+speed;
line (x1,h,x2,grow_vert);
line (w,y1,grow_hor,y2);
if (x2==grow_hor || grow_vert==y2){
int grow_dia = 1;
grow_dia = grow_dia+(speed/2);
float x3 = x2;
float y3 = y2;
line(x3,y3,x3-grow_dia,y3-grow_dia);
}
}

Replies(4)

tfguy44

Re: beginner code trouble (if statement in draw)

2 years ago

Like this?

// h for horizontal line.
// v for verticle line.
// x for x position.
// y for y position.
// i for initial position.
// s for speed.
// d for diagonal.
int hx, hy, hxi, hxs;
int vx, vy, vyi, vys;
float dx, dy, ds;
boolean d;
void setup() {
size(450, 450);
stroke(0);
strokeWeight(1);
smooth();
reset();
}
void reset() {
hxi=hx=width;
hy=int(random(height-1));
vx=int(random(width-1));
vyi=vy=height;
hxs=-1;
vys=-1;
ds=-1;
dx=dy=-1;
d=false;
}
void draw() {
simulate();
render();
}
void simulate() {
hx=constrain(hx+hxs, 0, width);
vy=constrain(vy+vys, 0, height);
if (!d) {
if (hx<=vx && vy<=hy) {
d=true;
dx=vx;
dy=hy;
}
}
else {
if (dx>ds || dy>ds) {
dx=dx+ds;
dy=dy+ds;
}
}
}
void render() {
background(255);
line(hxi, hy, hx, hy);
line(vx, vyi, vx, vy);
if (d) {
line(dx, dy, vx, hy);
}
}
void mousePressed() {
reset();
}

mgushanas..

Re: beginner code trouble (if statement in draw)

2 years ago

Yep. just like that. There is so much in that code I have never seen before =\.

I'm going to take a look into this but...

Care to explain why this works but mine doesn't? I'm not looking to salvage what I've done, I just want to know the better ways to do things and why.

Thanks for your help by the way :). Much appreciated.

tfguy44

Re: beginner code trouble (if statement in draw)

2 years ago

Well, the first thing to point out is that I fixed a few things with your code...
- You don't really need separate variables for the sketch width and hight; just set them with size and you can use width and height to access them.
- There's no need to call loop(), as this is the default behavior.
- I couldn't keep track of which of your variables did what, so I renamed them. Granted, my naming convention isn't that much better...

Then I fixed the structure a bit, by separating out the code that actually simulates the changes from the code that actually draws what you see. I also added a reset function so that you can start your sketch over without having to stop and start it again (and made it activate by a mouse press). I moved all the global variables to the top, so they're not mixed in with the functions.

I made sure that the reset function would change all the variables back to what they started at.
I made sure that the draw function would draw the correct lines based on the state of the variables. Notice that the diagonal line is only drawn if boolean d is true - this is the boolean that tracks if the diagonal line should be drawn.

The simulate function is where the real magic happens. First of all, it updates the horizontal and vertical lines' variables (which render will use later), and then it checks to see what's up with the diagonal line. If we're not drawing the diagonal line yet, it checks to see if it should start drawing it and, if so, sets the diagonal line's variables. If we are drawing it, it simply updates its variables if updating it's variables would make any difference.

Line 42 is the most important - it's the check to see if it is time to start drawing the diagonal line. In English, it says "If the horizontal line has past the point where the vertical line is, and the vertical line has past the point where the horizontal line is, then..."

Lines 43 to 45: "... remember that we need to draw the diagonal line now, and remember where it's supposed to start."

mgushanas..

Re: beginner code trouble (if statement in draw)

2 years ago

thanks a lot. this was very helpful. I learned a lot :)

Top Reply