Basic Programming question! keeping

baordog

Basic Programming question! keeping

in Contributed Library Questions • 1 year ago

Greeting all! I'm a processing newbie so please go easy.

I've been doing a project with the super collider library to learn some processing.
For a basic test of concept I've having rectangles spawn on click, but I'm stumped
as to how they should "stay". I imagine I insert a "delay" command somewhere,
though I would prefer it if there was just a static maximum number of rectangles
available.

Here's my code so far:

// ojective 1: make new synthes and things per click.

import supercollider.*;
import oscP5.*;
import netP5.*;

Synth synth;

void setup ()
{
    size(800, 800);

    // uses default sc server at 127.0.0.1:57110
    // does NOT create synth!
    synth = new Synth("sine");

    // set initial arguments
    synth.set("amp", 0.5);
    synth.set("freq", 80);

}

void draw ()
{
    background(0);
}

void mousePressed() {
float r = random ( 0, 800);
float s = random ( 0, 800);
float t = random ( 0, 800);
float u = random ( 0, 800);
float v = random ( 0, 10000);

rect(r,s ,t , u);

synth.create();
synth.set("freq", 40 + v);
}

at least it makes noise!

Replies(4)

amnon.owed

Re: Basic Programming question! keeping

1 year ago

There are at least three possible solutions:

Move your background call from draw() to setup(). It's the fastest and easiest solution in this case, but not very flexible in the long run, because you will have an accumulated drawing.
Store stuff in arrays/arraylists. Sometimes this works, here it seems a lot of work for little gain.
Use classes/objects. Make a small class that holds the different variables. They can be set randomly in the constructor. Then you can display the rect during draw. In this case using an ArrayList is best, cause it allows to dynamically add instances at the click of a mouse. I can imagine these terms do not make much sense to you at this time. That is why in the learning section, there is special page on OOP: http://processing.org/learning/objects/

So for the quick 1-second-solution go for option one. For the long-term, more flexible solution go for option three.

In any case, don't use delay. It's the worst possible solution and will be removed from Processing 2.0.

baordog

Re: Basic Programming question! keeping

1 year ago

That's good to know about Delay! I've been programming arduino stuff, and assumed
the delay command got thrown around just as much in processing.

That's leaving me scratching my head about another problem:
Eventually I will have an infinite number of synths.
If I call synth.free then they will free instantly and barely make
a sound. If I use delay, they will delay before they make a sound
instead of the way I want.

Best way to time the death of something?

// edit: Since I wrote this I realized there's an easy SC side
solution for synths. I'd still like to know the answer for future
reference though.

thanks for your informative reply by the way, I've
had a little experience writing classes in other environments
and doing it that way does seem natural .

local_guru

Re: Basic Programming question! keeping

1 year ago

a variant of amnon.owed 's version 1 is the following code (I left out the supercollider code to make the example
simpler )

The draw method repeatedly draws a black halve transparent rectangle. So if your mousePressed method
draws a white rectanle it will fade to black after some time (first frame its 50% gray, second frame its 25% gray .... )

how fast the fading effekt is can be adjusted by changign the alpha value of the fill command.

void setup() {
size(300,300);
background(0);
}
void draw() {
fill( 0, 10 ); // set fill to black with an alpha-value of 10
rect(0,0,width,height); // draw a rectangle
}
void mousePressed() {
fill(255); // set fill to white
float r = random ( 0, width);
float s = random ( 0, height);
float t = random ( 0, width - r);
float u = random ( 0, height - s);
float v = random ( 0, 10000);
rect(r,s ,t , u);
}

amnon.owed

Re: Basic Programming question! keeping

1 year ago

In arduino delay makes sense, but in processing it does not. It's like watching a dvd and pressing pause. If you stop the program with delay, everything stops. What you want is actually maximum smooth playback and interactivity. There are many better alternatives to do the things people usually wanted to accomplish with delay. To name a few that could be used here:

1. Have a life int in your class that starts at for example 600 and decrease it by 1 each draw . When it's lower then 0 (at 60 fps this will be about 6 seconds later), free the synth and if the object is no longer used, remove it.
2. millis() = the current time in milliseconds since the start of the sketch
3. frameCount = the number of frames since the start of the sketch (increasing by 1 each draw)

Both can be used to set a 'start time', 'end time' etc. Here is an example I gave in another context, but may still be useful to grasp the functioning of millis() and frameCount. There are many examples for both these functions in the forums.

Code Example

boolean textOn;
boolean blinker;
void setup() {
size(700,400);
textFont(createFont("Arial",30));
}
void draw() {
background(255);
fill(0);
text("you are in frame: " + frameCount,50,50);
text(millis()/1000 + " seconds have passed since the start", 50,100);
text("this text will be here forever",50,150);
if (frameCount < 500) {
text("this text will be here for 500 frames",50,200);
}
if (frameCount > 800) {
text("this text will be here from 800 frames onwards",50,200);
}
if (millis() < 8000) {
text("this text will be here the first 8 seconds",50,250);
}
if (millis() > 12000) {
text("this text will be here from 12 seconds onwards",50,250);
}
if (textOn) {
text("this text will depend on a boolean",50,300);
}
if (frameCount % 12 == 0) { blinker = !blinker; }
if (blinker) {
text("this text will blink",50,350);
}
}
void keyPressed() {
// toggle text with spacebar
if (key == ' ') { textOn = !textOn; }
}

Top Reply