ball grids and class setup questions

Programming Questions

peeya89

ball grids and class setup questions

in Programming Questions • 2 years ago

guys im new to processing..so i need ur help!! :)

what i intend to do is to create a grid with ball class, i manage to get it to draw an ellipse, however when i did it with my ball class it does not seem to work.

moreover after the grid by the ball is done, thinking of moving the ball on Z-axis, but i dont know where is that applied, does it have to be included in the ball class? or do i have to do something else

thanks heres my code

import peasy.*;
PeasyCam cam;
// decade class ball is myBall
Ball[] balls;
//int ballAmount = 125;
//int distance = 100;
//int space = 30;
////int radius = 15;
void setup (){
size(600,600,P3D);
noStroke ();
////// this is for the camera settings
cam = new PeasyCam(this,450);
cam.rotateX(PI*0.3);
cam.rotateZ(PI*0.3);
for (int i = 0; i < balls.length; i++) {
balls[i] = new Ball(random(-1,1), random(-1,1));
}
}
void draw (){
background (0);
int stepsize = 10;
for (int i = stepsize; i <height; i+= stepsize){
for (int j = stepsize; j <width; j+= stepsize){
balls[i]. display();
//what i want to draw /add class ball in
}
}
}
class Ball {

float xpos;

float ypos;

float zpos;

float speed;

Ball(float tempYpos, float tempZpos) {

//// preping info about the circle ready to be drawn

xpos = int(random(0, 899));

//// x coordinate of the center of the circle randoming number between 0 to the width of screen

ypos = int(random(0, 899));

//// y coordinate of the center of the circle

zpos = int(random(0, 899));

}

void display() {

//// setup for the sketch. ie colors and draw the circle

fill(255);

ellipse(xpos, ypos, 5, 5);

PVector linep = new PVector (xpos,ypos,zpos);

// point(linep.x, linep.y, linep.z);

stroke(255);

strokeWeight(4);

//// drawing the circles up each time the script runs

}

}

Replies(11)

allonestr..

Re: ball grids and class setup questions

2 years ago

Post your ball class too.

peeya89

Re: Re: ball grids and class setup questions

2 years ago

ball class added

allonestr..

Re: ball grids and class setup questions

2 years ago

There's a subtle change of mindset needed to move from drawing ellipses at particular co-ordinates to creating an instance of a ball and passing it co-ordinates (telling it what co-ordinates it has).

I've reduced this to just two dimensions to simplify it.

Then there are two ways of refering to the co-ordinates of the points (in this case the balls) that define the grid:

- use some maths and logic to specify the points in the first row, then the next row, then the next

- or use a 2D array to store them as pairs, (row2, column3) for example

I've gone with the first here, but the 2D array is a logical extension especially when you include the third dimension (then you'll have a 3D array)

I've left some so-called magic numbers in here; that is the spacing (100) and its offset (50).

int numRows = 3;
int numColumns = 3;
int numBalls = numRows * numColumns;
Ball[] balls;
int spacing = 100;
void setup()
{
size(300, 300);
background (0);

balls = new Ball[numBalls];
for(int b = 0; b < numBalls; b++)
{
    float ballxpos = 50 + (b % numColumns) * 100;
    float ballypos = 50 + int(b / numColumns) * 100;
    balls[b] = new Ball(ballxpos, ballypos);
}
}
void draw()
{
for(int b = 0; b < numBalls; b++)
{
balls[b]. display();
}
}
class Ball
{
float xpos, ypos;

Ball(float xpos, float ypos)
{
    this.xpos = xpos;
    this.ypos = ypos;
}

void display()
{
    fill(255);
    ellipse(xpos, ypos, 5, 5);
}
}

Have a play with this and say if you'd like help extending into the 2D (3D) array.

peeya89

Re: Re: ball grids and class setup questions

2 years ago

thank you... i'll play around with it

peeya89

Re: Re: ball grids and class setup questions

2 years ago

thank you very much allonestring, i've been playing the script for a while.

and now i want to extend it on to 3D.

I want to be able to move the ball/dots on the z axis by using the translate method,

by using the strings from the minim sound library. I'm sort of familiar with the minim library however,

how do i import the library in to ball class?

Re: ball grids and class setup questions

2 years ago

I'm going to answer the question that you haven't (yet) asked.

How do I know which ball is which and where it is in the grid?

I think that you will be able to do the movement in the z-axis and the join the balls with lines when you have them in a 2D (or 3D) array.

Can you see that to join the balls into rows, you draw a line from balls[0][0] to balls[1][0] to balls[2][0]?

That is from balls[i][0] to balls[i+1][0].

Can you see that to join the balls in columns, you draw a line from balls[0][0], to balls[0][1] to balls[0][2] to balls[0][3]?

That is from balls[0][j] to balls[0][j+1].

When you draw the lines like this, you will have to make sure that i+1 doesn't get bigger than numColumns, and that j+1 doesn't get bigger than numRows.

The code for putting the balls into a 2D array is below. I'll leave you to add the lines and to put the balls into a 3D array. (Use k for the layers in 3D.)

int numRows = 3;
int numColumns = 3;
Ball[][] balls;
int spacing = 100;
void setup()
{
size(300, 300);
background (0);

balls = new Ball[numRows][numColumns];
for(int i = 0; i < numRows; i++)
{
    for(int j = 0; j < numColumns; j++)
    {
      float ballxpos = 50 + i * 100;
      float ballypos = 50 + j * 100;
      balls[i][j] = new Ball(ballxpos, ballypos);
    }
}
}
void draw()
{
for(int i = 0; i < numRows; i++)
{
    for(int j = 0; j < numColumns; j++)
    {
      balls[i][j]. display();
    }
}
}
class Ball
{
float xpos, ypos;

Ball(float xpos, float ypos)
{
    this.xpos = xpos;
    this.ypos = ypos;
}

void display()
{
    fill(255);
    ellipse(xpos, ypos, 5, 5);
}
}

peeya89

Re: ball grids and class setup questions

2 years ago

thank you and thank you very much!!!!

this is what i have been looking for!!!!!

btw do have any good website that can help me with processing?

peeya89

Re: ball grids and class setup questions

2 years ago

ive been trying to draw the line but it didnt work..

sorry to be asking alot but where and how do i draw the line?

this is what i have been trying

void draw() {
for(int i = 0; i < numRows; i++) {
for(int j = 0; j < numColumns; j++) {
balls[i] = 8;
balls[j] = 8;
line(i, ball[i],i+1, ball[i+1]);
line(j, ball[j],j+1, ball[j+1]);
balls[i][j]. display();
}
}
}

allonestr..

Re: ball grids and class setup questions

2 years ago

OK. Here's how to draw the line when there's one dimension of balls

line(balls[i].x, balls[i].y, balls[i+1].x, balls[i+1].y);

In two dimensions the balls in the array now have two parts to their "address". They should always be balls[i][j].

In my diagram balls[2][3] is the "address" for the ball at that point in the array.

Can you work out how to draw the line now using the info in my last post?

peeya89

Re: ball grids and class setup questions

2 years ago

still trying to be honest..

allonestr..

Re: ball grids and class setup questions

2 years ago

line(balls[i][j].x, balls[i][j].y, balls[i+1][j].x, balls[i+1][j].y);

Top Reply