An array is just like a container with a certain number of cells that you can put things in. But when you declare the array you must declare what type of things it will contain. In your case float ball[] - you are stating that it will store floats, it could be Int ball[] to store integers etc. You then give it a length of 12 here  ball = new float[12]; so you are saying it can hold 12 things. You can access each of those things by the arrays index so ball[3] will be the third item in the array or if you say ball[3] = 1 that will store the value 1 as float as the third item in your array.You do this here

I get what you want to do, but you want to learn right? So lets start simple, I'll repeat my question. What are you currently storing in your array?

Thats right, they are each holding a float with the value of 1. You want them to hold Balls. So the first thing you have to do is create a class that will hold your ball code, then you can create multiple instances of them and store them in your array. Check out   http://processing.org/learning/objects/

Hello SnoozerGuy, it looks to me that you do not fully understand the principles of object oriented programming yet - Ball[1] refers to a Ball object but it doesn't do anything, you need to specify Ball[1].display() or Ball[1].update();

Anyway, I wrote a program for you that does as you want - it creates a ball when you click a mouse.

1. int maxBalls = 10;
   Ball[] ballArray;
   int ballCount; // No of balls being created
   
   void setup() {
     size(200, 200);
     smooth();
     // Create an array of balls
     ballArray = new Ball[maxBalls];
   }
   
   void draw() {
     background(204);
     // Display the balls and update the positions
     for (int i = 0; i < ballCount; i++) {
       ballArray[i].display();
       ballArray[i].update();
     }
    
   }
   
   void mousePressed() {
     if (ballCount < maxBalls) {
       ballArray[ballCount] = new Ball(mouseX, mouseY, random(-2, 2), random(-2, 2), 10.0);
       ballCount++;
     }
   }

1. class Ball {
     float x, y; // Position of the ball
     float speedX, speedY; // Speed of the ball
     float radius; // Radius of the ball
     color ball_color = color(33, 75, 106); // Color of the ball
    
     // Constructor
     Ball(float x_, float y_, float speedX_, float speedY_, float radius_) {
      x = x_;
      y = y_ ;
      speedX = speedX_;
      speedY = speedY_;
      radius = radius_;
     }
    
     // Draws the ball
     void display() {
       fill(ball_color, 100);
       ellipse(x, y, radius * 2, radius * 2);
     }
    
     // Updates the ball's position, and reverses speed if it hits the wall
     void update() {
       x = x + speedX;
       y = y + speedY;
      
       // Reverse speed if it hits the wall
       if (x + radius > width || x - radius < 0) {
         speedX = - speedX;
       }
       if (y + radius > height || y - radius < 0) {
         speedY = - speedY;
       }
     }
   
    
   }
   

OK, so I have incorporated what I have learnt from this question into this new code which now works... so I'll post it for those needing an example of where i wanted to go.

So this is the main code:

int maxBalls = 20;
Ball[] ballArray;
int ballCount; // No of balls being created

//Background colour variables
float a = 0;
float b = 0;
float c = 0;
float d = 102;
float e = 204;
float f = 255;

//controls
int edge = 56;
int radius = 0;
int radicont = 1;

void setup() {
  size(750, 750);
  smooth();
  // Create an array of balls
  ballArray = new Ball[maxBalls];
}

void background1()
{
  background(color(d+a,e+b,f+c));
  //Change the background colours
  a = (random(-1,1)) + a;
  b = (random(-1,1)) + b;
  c = (random(-1,1)) + c;
  //black border
  fill(0);
  rect(0,0,edge,height);
  rect(0,0,width,edge);
  rect(0,height-edge,width,height);
  rect(width-edge,0,width,height);
  noFill();
}

void draw() {
  background1();
  // Display the balls and update the positions
  for (int i = 0; i < ballCount-1; i++) {
    if (i == 19){
      if(mouseButton == LEFT){
      i = i - ballCount+1;}}
    ballArray[i].display();
    ballArray[i].update();
    ballArray[i].mouse();
  }
}

void mousePressed() {
  if (mouseButton == LEFT) {
    if (ballCount < maxBalls) {
      ballArray[ballCount] = new Ball(mouseX, mouseY, random(-2, 2), random(-2, 2), 10.0);
      ballCount++;
    }
  }
}



And this is the Ball class:


class Ball {
  float x, y; // Position of the ball
  float speedX, speedY; // Speed of the ball
  float radius; // Radius of the ball
  color ball_color = color(0,random(0,250)); // Color of the ball
  int resizeControl = 0;

  // Constructor
  Ball(float x_, float y_, float speedX_, float speedY_, float radius_) {
    x = x_;
    y = y_ ;
    speedX = speedX_;
    speedY = speedY_;
    radius = radius_;
  }

  // Draws the ball
  void display() {
    fill(ball_color);
    stroke(ball_color);
    ellipse(x, y, radius * 2, radius * 2);
  }

  // Updates the ball's position, and reverses speed if it hits the wall
  void update() {
    x = x + speedX* mouseY/100;
    y = y + speedY* mouseY/100;
    // Reverse speed if it hits the wall
    if (x + edge + radius > width || x - edge - radius < 0) {
      speedX = - speedX;
    }
    if (y + edge + radius > height || y -  edge - radius < 0) {
      speedY = - speedY;
    }     
  }
  void mouse() {
    if (mousePressed) {
      resizeControl = 1;
      if(mouseButton == RIGHT) {

        if (resizeControl == 1) {
          if(radius<50 && radicont==1) {

            radius=radius+1;
            if(radius==49) {
              radicont=0;
            }
          }
          if(radius>10 && radicont==0) {

            radius=radius-1;
            if(radius==11) {
              radicont=1;
            }
          }
        }
      }
      else if (mouseButton == LEFT) {   
        resizeControl = 0;
      }
    }
  }
}

Congrats looks really good