arrays and for loops

Programming Questions

doner21

in Programming Questions • 6 months ago

HI guys im just wondering why c = a*b/2; brings up no results for println(c) but c = 100; or some whole number does work. im just playing around with arithmetic series here and wanted to know how i could construct c interms of a and b

Series series;

void setup(){

background(255);

size(500,500);

series = new Series(10,11);

}

void draw(){

series.move();

}

class Series{

int a;

int b;

int[] n;

int c=a*b/2;

Series(int a_,int b_ ){

n = new int[c];

a = a_;

b = b_;

}

void move(){

for (int c= 0;c<n.length;c++){

n[c] = n[c]+1;

println (c);

}

Replies(5)

yonahs

Re: arrays and for loops

6 months ago

import java.util.Arrays;
Series series;
void setup(){
background(255);
size(500,500);
series = new Series(10,11);
}
void draw(){
series.move();
noLoop();
}
class Series{
int a;
int b;
int[] n;
int c;
Series(int a,int b ){
this.a = a;
this.b = b;
c = (a*b)/2;
println("length of matrix is:"+c);
n = new int[c];
}
void move(){
for (int i= 0;i<n.length;i++){
n[i] = n[i]+1;
println(c);
println(Arrays.toString(n));
}
}
}

Try looking at this code, try to remember in a method your instructions execute in order they were given. This should clear things up! Still not to sure, what you actually want 'c' to do?

GoToLoop

Re: arrays and for loops

6 months ago

Dunno either. No idea at all! Come up w/ this one though:

Series series = new Series(5, 7);

void setup() {
  size(100, 100);
  frameRate(5);
  background(-1);
}

void draw() {
  series.show();
}

final class Series {
  final int[] n;

  Series(int a, int b) {
    n = new int[a*b >> 1];
  }

  void show() {
    for ( int idx = 0; idx != n.length; print(++n[idx++] + " ") );
    println();
  }
}

PhiLho

Re: arrays and for loops

6 months ago

You wrote:

class Series{
int a;
int b;
int[] n;
int c=a*b/2;
Series(int a_,int b_ ){
n = new int[c];
a = a_;
b = b_;
}

The part between the class declaration and the constructor is traditionally used for class declarations of fields (variables specific to the class). If there is an assignment there, it is done before the constructor is called, and done only once. Fields not getting a value take their default value, 0, 0.0, false or null.
So, there, c is just 0 * 0 / 2, ie. 0...
yonahs shows how to do it correctly, when you get the values.

doner21

Re: arrays and for loops

6 months ago

Hi guys thanks for this it helped alot and furthered my understanding:) i've noticed something i in yoahs statemnt called this

this.a;

this.b;

What is the "this" statement doing in this case ?

Thanks so much guys:)

PhiLho

Re: arrays and for loops

6 months ago

You can have a parameter of the constructor of the same name than a field of the class (a variable declared at the class level).
To distinguish them, you can decorate the parameters with something (an underscore in your case) or use the this. prefix to mark the fields.

Top Reply